View previous topic :: View next topic |
Author |
Message |
Mac Professional Member
Joined: 08 Jul 2000 Posts: 1585 Location: Oklahoma USA
|
Posted: Sat Aug 03, 2002 3:17 am Post subject: |
|
|
Well, that was fast...
I just finished a small prog that uses the other one...
Thanks, Mac _________________ VDSug.dll does file IO, check/disable menu items,
non-VDS dlls, draw functions and more...
Free download (30k dll size) at:
http://www.vdsworld.com/download.php?id=361
|
|
Back to top |
|
|
LiquidCode Moderator Team
Joined: 05 Dec 2000 Posts: 1751 Location: Space and Time
|
Posted: Tue Aug 06, 2002 1:00 pm Post subject: |
|
|
I have added a few more features to the checker. I have created a Icon
to use with it made from the forum logo so when the MSN type box shows up, the Icon is in the corner. [ http://cgs.vdsworld.com/ForumChkIco.zip ]
I also added to the right click menu 2 options. View last Post and
DL last file. I added these in case I was away from my desk and wanted
to check if a new file or post was available. Here is the complete code
that I have.
Code: |
rem version 1.5
rem works in VDS 4.
rem Modified by CGingerich
rem Added popup menu to RClick on task icon
rem Menu items are Check now, View Last post, DL Last File, Close
title VDSWORLD Check-Up
option scale,96
option decimalsep,.
directory change,@path(%0)
external vdsipp.dll
internet http,create,1
internet http,threads,1,off
internet http,protocol,1,1
internet http,useragent,1,"VDSWORLD Forum Check-Up"
%%launch = @regread(default,,launch,)
%%interval = @regread(default,,interval,5)
rem info "|%%interval
%%lastpost = @regread(default,,lastpost,)
%%lastfile = @regread(default,,lastfile,)
%%forumnotify = @regread(default,,forumnotify,1)
%%filenotify = @regread(default,,filenotify,)
%%icon = %0
if @equal(@ext(%%icon),dsc)
%%icon =
end
dialog CREATE,VDSWORLD Check-Up,-1,0,289,192,ontop
dialog ADD,TASKICON,taIcon,%%icon,VDSWORLD Check-Up
dialog ADD,GROUP,gSettings,4,4,280,144,Settings
dialog ADD,CHECK,chAutoLaunch,24,16,256,16,&Launch with Windows
dialog ADD,CHECK,chForumNotify,48,16,256,16,Notify on &forum updates
dialog ADD,CHECK,chFileNotify,72,16,176,16,Notify on f&ile updates
dialog ADD,TEXT,tInterval,96,16,,,Update interval:
dialog ADD,COMBO,cInterval,116,16,56,21,cInterval,,LIST
dialog ADD,TEXT,tMinutes,120,88,,,minutes
dialog ADD,BUTTON,bOK,160,96,80,24,&OK,,DEFAULT
dialog ADD,BUTTON,CANCEL,160,192,80,24,&Cancel
list loadtext,cInterval
"2
"5
"10
"30
goto timer
:CANCELbutton
:evloop
wait event,@prod(%%interval,60)
goto @event()
:timer
:Check NowMenu
internet http,get,1,http://www.vdsworld.com/data.php
%%data = @trim(@internet(http,content,1))
if %%data
parse "%%topic;%%post;%%file;%%filetitle;%%fileauthor",%%data
%%update =
if %%lastpost
if @not(@equal(%%post,%%lastpost))
if %%forumnotify
%%message = @cr()@chr(10)There's a new post on the VDSWORLD forum. Click here to view.
rem %%link = "javascript:top.location.href='http://www.vdsworld.com/forum/viewtopic.php?t="%%topic"#"%%post"';"
%%link = "http://www.vdsworld.com/forum/viewtopic.php?t="%%topic"#"%%post
gosub message
end
%%update = 1
end
else
%%update = 1
end
if %%update
%%lastpost = %%post
registry write,default,,lastpost,%%lastpost
registry write,default,,lastdata,%%data
end
%%update =
if %%lastfile
if @not(@equal(%%file,%%lastfile))
if %%filenotify
%%message = There's a new file posted on VDSWORLD. Click here to download:@cr()@chr(10)@cr()@chr(10)%%filetitle
%%link = "http://www.vdsworld.com/index.php?page=download&fileid="%%file
gosub message
end
%%update = 1
end
else
%%update = 1
end
if %%update
%%lastfile = %%file
registry write,default,,lastfile,%%lastfile
end
end
goto evloop
:taIconclick
if @equal(@click(B),left)
dialog set,chAutoLaunch,%%launch
dialog set,chForumNotify,%%forumnotify
dialog set,chFileNotify,%%filenotify
%x = @match(cInterval,%%interval)
dialog showmodal
goto evloop
else
dialog popup,Check Now|-|View Last Post|DL Last File|-|Close
goto evloop
end
:View Last PostMENU
parse "%%topic;%%post;%%file;%%filetitle;%%fileauthor",@regread(default,,lastdata,)
if @not(@regread(default,,lastdata,))
info No last topic available.
goto evloop
end
shell open,"http://www.vdsworld.com/forum/viewtopic.php?t="%%topic"#"%%post
goto evloop
:DL Last FileMENU
parse "%%topic;%%post;%%file;%%filetitle;%%fileauthor",@regread(default,,lastdata,)
if @not(@regread(default,,lastdata,))
info No last file available.
goto evloop
end
shell open,"http://www.vdsworld.com/index.php?page=download&fileid="%%file
goto evloop
:bOKbutton
%%launch = @dlgtext(chAutoLaunch)
%%forumnotify = @dlgtext(chForumNotify)
%%filenotify = @dlgtext(chFileNotify)
%%interval = @dlgtext(cInterval)
registry write,default,,launch,%%launch
registry write,default,,forumnotify,%%forumnotify
registry write,default,,filenotify,%%filenotify
registry write,default,,interval,%%interval
if %%launch
if @not(@equal(@ext(%0),dsc))
registry write,local,SOFTWARE\Microsoft\Windows\CurrentVersion\Run,VCheckUp,%0
end
else
registry delete,local,SOFTWARE\Microsoft\Windows\CurrentVersion\Run,VCheckUp
end
goto evloop
:message
dialog CREATE,Check-Up Message Window,300,300,190,86,CLASS VDSMESSAGE,NOTITLE,ONTOP
dialog ADD,STYLE,sMessage,,,BL,,0000A0
dialog ADD,SHAPE,sBackground,0,0,190,86,E1FFFF,0000A0,,RECTANGLE
dialog ADD,TEXT,tMessage,7,44,142,75,%%message,,TRANSPARENT,sMessage,CLICK,HAND
dialog ADD,SHAPE,iBack,3,3,34,34,,,,RECTANGLE
dialog ADD,BITMAP,Icon,4,4,32,32,%0
%t = @winpos(#Shell_TrayWnd,T)
%l = @winpos(#Shell_TrayWnd,L)
%h = @winpos(#Shell_TrayWnd,H)
%w = @winpos(#Shell_TrayWnd,W)
%%screenheight = @sysinfo(screenheight)
%%uppert = @diff(%%screenheight,@dlgpos(,H))
%l = @diff(@sysinfo(screenwidth),@dlgpos(,W))
if @equal(%T,0)
rem taskbar is positioned at top, left or right
if @equal(%L,0)
rem taskbar is positioned at left; no problem
else
rem taskbar is positioned at top or right
if @equal(%H,%%screenheight)
rem taskbar is positioned at right
%l = @diff(%L,%W)
else
rem taskbar is positioned at top; no problem
end
end
else
rem taskbar is positioned at bottom
%%uppert = @diff(%%upperT,%H)
end
%%lowert = %%screenheight
dialog SETPOS,,%%lowerT,%L
dialog SHOW
while @not(@equal(@dlgpos(,T),%%upperT))
dialog setpos,,@pred(@dlgpos(,T))
gosub sleep
wend
repeat
wait event,4.5
%e = @event()
until @equal(%e,timer)@equal(%e,tMessageclick)
if @equal(%e,tMessageclick)
shell open,%%link
else
while @not(@equal(@dlgpos(,T),%%lowerT))
dialog setpos,,@succ(@dlgpos(,T))
gosub sleep
wend
end
dialog close
rem clear the "CLOSE" event from the event buffer
%x = @event()
exit
:sleep
%i = 0
repeat
%i = @succ(%i)
until @equal(%i,300)
exit
:closeMenu
rem if @ask(This will close the Check-Up program. Do you want to continue?)
internet http,destroy,1
rem exit
rem else
stop
rem end
|
_________________ Chris
Http://theblindhouse.com
Last edited by LiquidCode on Wed Aug 07, 2002 1:39 am; edited 1 time in total |
|
Back to top |
|
|
SnarlingSheep Professional Member
Joined: 13 Mar 2001 Posts: 759 Location: Michigan
|
Posted: Tue Aug 06, 2002 11:32 pm Post subject: |
|
|
Might want to repost that with Smilies disabled Chris :)
Smilie in :DL Last FileMENU _________________ -Sheep
My pockets hurt... |
|
Back to top |
|
|
Tommy Admin Team
Joined: 16 Nov 2002 Posts: 746 Location: The Netherlands
|
Posted: Mon Aug 12, 2002 5:12 am Post subject: |
|
|
A greatly improved version 2.1 has been released. It's available for download at:
http://www.vdsworld.com/index.php?page=download&file=checkup.dsc
Or precompiled including the required vdsrun40.dll and vdsipp.dll DLLs:
http://www.vdsworld.com/files/checkup.zip
It is Protected who did most of the improvements in the script, so all thanks go out
to him.
He enlarged the status window, and changed the script so that it will show the message author,
subject and initial part of the message in the status window, so that it isn't always neccesary to
open the message in a web browser. It is also possible to have the status window showing the
last post or file popup manually through the taskicon menu. |
|
Back to top |
|
|
Dr. Dread Professional Member
Joined: 03 Aug 2001 Posts: 1065 Location: Copenhagen, Denmark
|
Posted: Mon Aug 12, 2002 9:02 am Post subject: Re: VDSWORLD Forum Checkup |
|
|
Hi, Tommy
I think there's been a mixup - when downloading the .dsc file it is actually a zip file.
Greetz
Dread _________________ ~~ Alcohol and calculus don't mix... Don't drink and derive! ~~
String.DLL * advanced string processing |
|
Back to top |
|
|
Protected Valued Contributor
Joined: 02 Jan 2001 Posts: 228 Location: Portugal
|
Posted: Mon Aug 12, 2002 11:38 am Post subject: |
|
|
Code: | title VDSWORLD Check-Up
option scale,96
option decimalsep,.
directory change,@path(%0)
external vdsipp.dll
internet http,create,1
internet http,threads,1,off
internet http,protocol,1,1
internet http,useragent,1,"VDSWORLD Forum Check-Up"
%%launch = @regread(default,,launch,)
%%interval = @regread(default,,interval,5)
%%lastpost = @regread(default,,lastpost,)
%%lastfile = @regread(default,,lastfile,)
%%forumnotify = @regread(default,,forumnotify,1)
%%filenotify = @regread(default,,filenotify,1)
%%icon = %0
if @equal(@ext(%%icon),dsc)
%%icon =
end
DIALOG CREATE,VDSWORLD Check-Up,-1,0,289,192
DIALOG ADD,TASKICON,taIcon,%%icon,VDSWORLD Check-Up
DIALOG ADD,GROUP,gSettings,4,4,280,144,Settings
DIALOG ADD,CHECK,chAutoLaunch,24,16,256,16,&Launch with Windows
DIALOG ADD,CHECK,chForumNotify,48,16,256,16,Notify on &forum updates
DIALOG ADD,CHECK,chFileNotify,72,16,176,16,Notify on f&ile updates
DIALOG ADD,TEXT,tInterval,96,16,,,Update interval:
DIALOG ADD,COMBO,cInterval,116,16,56,21,cInterval,,LIST
DIALOG ADD,TEXT,tMinutes,120,88,,,minutes
DIALOG ADD,BUTTON,bOK,160,96,80,24,&OK,,DEFAULT
DIALOG ADD,BUTTON,CANCEL,160,192,80,24,&Cancel
list add,cInterval,2
list add,cInterval,5
list add,cInterval,10
list add,cInterval,30
:evloop
wait event,@fmul(%%interval,60)
goto @event()
:Latest postmenu
internet http,get,1,http://www.vdsworld.com/data.php
%%data = @trim(@internet(http,content,1))
if %%data
parse "%%topic;%%post;%%file;%%filetitle;%%fileauthor",%%data
internet http,get,1,http://www.vdsworld.com/data.php?request=text&id=%%post&count=301
list create,7
list assign,7,@internet(http,content,1)
%%lastuser = @item(7,1)
%%lasttopic = @item(7,2)
%%lastsubject = @item(7,3)
%%lastmessage = @substr(@item(7,4),1,101)
if @greater(@len(@item(7,4)),100)
%%lastmessage = %%lastmessage...
end
list close,7
if %%lasttopic
if @not(%%lastsubject)
%%lastsubject = Reply to %%lasttopic
end
end
if @greater(@len(%%lastsubject),24)
%%lastsubject = @substr(%%lastsubject,1,24)...
end
if @greater(@len(%%lastuser),26)
%%lastuser = @substr(%%lastuser,1,26)...
end
%%message = Latest post on the VDSWORLD forum:@cr()@chr(10)By: %%lastuser@cr()@chr(10)Subj: %%lastsubject@cr()@chr(10)%%lastmessage...
%%filename = @regread(root,http\shell\open\command,)
gosub parsefilename
%%run = @shortname(%%filename1)" http://www.vdsworld.com/forum/viewtopic.php?t="%%topic"#"%%post
%%link =
gosub message
end
goto evloop
:Check Nowmenu
:timer
internet http,get,1,http://www.vdsworld.com/data.php
%%data = @trim(@internet(http,content,1))
if %%data
parse "%%topic;%%post;%%file;%%filetitle;%%fileauthor",%%data
internet http,get,1,http://www.vdsworld.com/data.php?request=text&id=%%post&count=301
list create,7
list assign,7,@internet(http,content,1)
%%lastuser = @item(7,1)
%%lasttopic = @item(7,2)
%%lastsubject = @item(7,3)
%%lastmessage = @substr(@item(7,4),1,101)
if @greater(@len(@item(7,4)),100)
%%lastmessage = %%lastmessage...
end
list close,7
if %%lasttopic
if @not(%%lastsubject)
%%lastsubject = Reply to %%lasttopic
end
end
if @greater(@len(%%lastsubject),24)
%%lastsubject = @substr(%%lastsubject,1,24)...
end
if @greater(@len(%%lastuser),26)
%%lastuser = @substr(%%lastuser,1,26)...
end
%%update =
if %%lastpost
if @not(@equal(%%post,%%lastpost))
if %%forumnotify
%%message = There's a new post on the VDSWORLD forum:@cr()@chr(10)By: %%lastuser@cr()@chr(10)Subj: %%lastsubject@cr()@chr(10)%%lastmessage...
%%filename = @regread(root,http\shell\open\command,)
gosub parsefilename
%%run = @shortname(%%filename1)" http://www.vdsworld.com/forum/viewtopic.php?t="%%topic"#"%%post
%%link =
gosub message
end
%%update = 1
end
else
%%update = 1
end
if %%update
%%lastpost = %%post
registry write,default,,lastpost,%%lastpost
end
%%update =
if %%lastfile
if @not(@equal(%%file,%%lastfile))
if %%filenotify
%%message = There's a new file posted on VDSWORLD. Click here to download:@cr()@chr(10)@cr()@chr(10)%%filetitle
%%link = "http://www.vdsworld.com/index.php?page=download&fileid="%%file
%%run =
gosub message
end
%%update = 1
end
else
%%update = 1
end
if %%update
%%lastfile = %%file
registry write,default,,lastfile,%%lastfile
end
end
goto evloop
:taIconclick
if @equal(@click(B),left)
goto timer
else
dialog popup,&Check Now|&Open Forum|L&atest post|-|&VDSWorld|-|&Settings|-|C&lose
goto evloop
end
:vdsworldmenu
run http://www.vdsworld.com/
goto evloop
:Open Forummenu
%%filename = @regread(root,http\shell\open\command,)
gosub parsefilename
run @shortname(%%filename1)" http://forum.vdsworld.com/"
goto evloop
:Settingsmenu
dialog set,chAutoLaunch,%%launch
dialog set,chForumNotify,%%forumnotify
dialog set,chFileNotify,%%filenotify
%x = @match(cInterval,%%interval)
dialog showmodal
%e = @event()
if @equal(%e,bOKbutton)
goto %e
else
goto evloop
end
:bOKbutton
%%launch = @dlgtext(chAutoLaunch)
%%forumnotify = @dlgtext(chForumNotify)
%%filenotify = @dlgtext(chFileNotify)
%%interval = @dlgtext(cInterval)
registry write,default,,launch,%%launch
registry write,default,,forumnotify,%%forumnotify
registry write,default,,filenotify,%%filenotify
registry write,default,,interval,%%interval
if %%launch
if @not(@equal(@ext(%0),dsc))
registry write,local,SOFTWARE\Microsoft\Windows\CurrentVersion\Run,VCheckUp,%0
end
else
registry delete,local,SOFTWARE\Microsoft\Windows\CurrentVersion\Run,VCheckUp
end
goto evloop
:parsefilename
%i = 0
%q =
repeat
%i = @succ(%i)
%c = @substr(%%filename,%i)
if @equal(%c,@chr(34))
if %q
%q = 2
else
%q = 1
end
else
if @not(%q)
if @equal(%c," ")
%q = 3
end
end
end
until @equal(%i,@len(%%filename))@equal(%q,2)@equal(%q,3)
if @equal(%q,3)
%%filename1 = @substr(%%filename,1,@pred(%i))
else
if @equal(%q,2)
%%filename1 = @substr(%%filename,2,@pred(%i))
else
%%filename1 = %%filename
end
end
exit
:message
DIALOG CREATE,Check-Up Message Window,300,300,200,130,CLASS VDSMESSAGE,NOTITLE,ONTOP
DIALOG ADD,STYLE,sMessage,,8,BL,,0000A0
DIALOG ADD,SHAPE,sBackground,0,0,200,130,E1FFFF,0000A0,,RECTANGLE
DIALOG ADD,TEXT,tMessage,8,8,190,120,%%message,,TRANSPARENT,sMessage,CLICK,HAND
%T = @winpos(#Shell_TrayWnd,T)
%L = @winpos(#Shell_TrayWnd,L)
%H = @winpos(#Shell_TrayWnd,H)
%W = @winpos(#Shell_TrayWnd,W)
%%screenheight = @sysinfo(screenheight)
%%upperT = @diff(%%screenheight,@dlgpos(,H))
%L = @diff(@sysinfo(screenwidth),@dlgpos(,W))
if @equal(%T,0)
rem taskbar is positioned at top, left or right
if @equal(%L,0)
rem taskbar is positioned at left; no problem
else
rem taskbar is positioned at top or right
if @equal(%H,%%screenheight)
rem taskbar is positioned at right
%L = @diff(%L,%W)
else
rem taskbar is positioned at top; no problem
end
end
else
rem taskbar is positioned at bottom
%%upperT = @diff(%%upperT,%H)
end
%%lowerT = %%screenheight
DIALOG SETPOS,,%%lowerT,%L
DIALOG SHOW
while @not(@equal(@dlgpos(,T),%%upperT))
dialog setpos,,@pred(@dlgpos(,T))
gosub sleep
wend
repeat
wait event,5.5
%e = @event()
until @equal(%e,timer)@equal(%e,tMessageclick)
if @equal(%e,tMessageclick)
if %%run
run %%run
else
shell open,%%link
end
else
while @not(@equal(@dlgpos(,T),%%lowerT))
dialog setpos,,@succ(@dlgpos(,T))
gosub sleep
wend
end
dialog close
rem clear the "CLOSE" event from the event buffer
%x = @event()
exit
:sleep
%i = 0
repeat
%i = @succ(%i)
until @equal(%i,10)
exit
:Closemenu
:close
internet http,destroy,1
exit |
Here you have the source.
Quote: | It is Protected who did most of the improvements in the script, so all thanks go out
to him.
|
No way! I only had to do a few changes in the program, it was Tommy who did the whole php thingy!
The syntax to return the post content is:
http://www.vdsworld.com/data.php?request=text&id=<post id>&count=<maximum number of message characters to return>
The file will have, nothing in line 0, the poster name in line 1, the topic subject in line 2, the post subject in line 3, and in the others the post content, but only the specified number of characters, so if you only want the subjects and posters tell it to return a single character (that should make the download faster). |
|
Back to top |
|
|
Tommy Admin Team
Joined: 16 Nov 2002 Posts: 746 Location: The Netherlands
|
Posted: Mon Aug 12, 2002 5:12 pm Post subject: |
|
|
Thanks for letting me know. I think the file should be ok now. The file I uploaded is a
slightly optimized version of Protected's code. |
|
Back to top |
|
|
FreezingFire Admin Team
Joined: 23 Jun 2002 Posts: 3508
|
Posted: Fri Aug 16, 2002 3:16 pm Post subject: |
|
|
Another thing that could be added to the Forum Checker would be to add an option to read which users are online... _________________ FreezingFire
VDSWORLD.com
Site Admin Team |
|
Back to top |
|
|
Tommy Admin Team
Joined: 16 Nov 2002 Posts: 746 Location: The Netherlands
|
Posted: Sat Aug 17, 2002 1:42 am Post subject: |
|
|
I think this would be an idea for the Open Instant Messenger project that we started.
Prakash and I will be working on some online PHP scripts, together with a freeware internet
DLL with special easy to use Instant Messenger commands. The DLL will take care of
all interfacing with the server. Maybe eventually, we will be able to link the messenger
script/DLL to the forum, or even integrate the Checkup program in the instant messenger
program. |
|
Back to top |
|
|
marty Professional Member
Joined: 10 May 2001 Posts: 789
|
Posted: Sat Aug 17, 2002 2:02 am Post subject: |
|
|
Ahhhh!! Thats great news Tommy... !
That would make the open source project more interesting... I will wait before releasing the online chat system I wanted to make.
Im in for it!
Once its in good progress I will make a nice interface for it.
Thanks Tommy and Prakash. Combining Instant messanging and the Forum checker will be a great project. I may even included it in the VDSWORLD Media Player ... |
|
Back to top |
|
|
LOBO Valued Contributor
Joined: 14 Mar 2002 Posts: 241 Location: Wilmington, Delaware, USA
|
Posted: Sat Aug 17, 2002 5:18 am Post subject: |
|
|
Wrap everything up in one nice little package. Really great project idea
We get to check the forum for new posts, chat with others who are browsing the forum and listen to music all at the same time. |
|
Back to top |
|
|
marty Professional Member
Joined: 10 May 2001 Posts: 789
|
Posted: Mon Nov 11, 2002 1:06 am Post subject: Whats up with this project |
|
|
Tommy wrote: Quote: | I think this would be an idea for the Open Instant Messenger project that we started.
Prakash and I will be working on some online PHP scripts, together with a freeware internet
DLL with special easy to use Instant Messenger commands. The DLL will take care of
all interfacing with the server. Maybe eventually, we will be able to link the messenger
script/DLL to the forum, or even integrate the Checkup program in the instant messenger
program. |
Tommy or Prakash,
Has this project been cancelled? Maybe I can help with the DLL?
I know Tommy you have been very busy.
Just curious...
Thanks... |
|
Back to top |
|
|
ShinobiSoft Professional Member
Joined: 06 Nov 2002 Posts: 790 Location: Knoxville, Tn
|
Posted: Sun Dec 15, 2002 6:33 pm Post subject: |
|
|
Added code to allow for customization of the message window. Settings include background color, border color, and font color. Could easily be expanded for other settings. Also added 1 to the cInterval string list for checking the forums @ every 60 seconds.
Code: |
rem version 2.2
rem big thanks to Protected Programs for plenty of help
rem works in VDS 4.
title VDSWORLD Check-Up
option scale,96
option decimalsep,.
directory change,@path(%0)
external vdsipp.dll
internet http,create,1
internet http,threads,1,off
internet http,protocol,1,1
internet http,useragent,1,"VDSWORLD Forum Check-Up"
%%maxmessage = 150
%%maxmessagelines = 4
%%maxsubject = 24
%%maxuser = 26
%%launch = @regread(default,,launch,)
%%interval = @regread(default,,interval,5)
%%lastpost = @regread(default,,lastpost,)
%%lastfile = @regread(default,,lastfile,)
%%lastdevpost = @regread(default,,lastdevpost,)
%%forumnotify = @regread(default,,forumnotify,1)
%%filenotify = @regread(default,,filenotify,1)
%%devforumnotify = @regread(default,,devforumnotify,1)
%%borderColor = @regread(default,,borderColor,FFFFD0)
%%backColor = @regread(default,,backColor,FFFFD0)
%%fontColor = @regread(default,,fontColor,A00000)
%%icon = %0
if @equal(@ext(%%icon),dsc)
%%icon =
end
DIALOG CREATE,VDSWORLD Check-Up,-1,0,313,209,CLASS VdsCheckUp
REM *** Modified by Dialog Designer on 12/15/02 - 12:22 ***
DIALOG ADD,TASKICON,taIcon,%%icon,VDSWorld CheckUp
DIALOG ADD,GROUP,gSettings,4,0,304,160,Settings
DIALOG ADD,CHECK,chAutoLaunch,24,16,280,16,&Launch with Windows
DIALOG ADD,CHECK,chForumNotify,48,16,280,16,Notify on &forum updates
DIALOG ADD,CHECK,chFileNotify,72,16,280,16,Notify on f&ile updates
DIALOG ADD,CHECK,chDevForumNotify,96,16,280,16,Notify on DLL &developer forum updates
DIALOG ADD,TEXT,tInterval,120,16,,,Update interval:
DIALOG ADD,COMBO,cInterval,136,16,56,21,cInterval,,LIST
DIALOG ADD,TEXT,tMinutes,140,88,,,minutes
DIALOG ADD,BUTTON,bView,130,230,65,25,&Display
DIALOG ADD,BUTTON,bOK,175,120,80,25,&OK,,DEFAULT
DIALOG ADD,BUTTON,CANCEL,176,216,80,24,&Cancel
dialog show
window hide,#VdsCheckUp
list add,cInterval,1
list add,cInterval,2
list add,cInterval,5
list add,cInterval,10
list add,cInterval,30
:evloop
wait event,@fmul(%%interval,60)
%e = @event()
goto %e
:View Last Postmenu
%%index =
gosub getdata
if %%topic
%%new =
gosub getpost
end
goto evloop
:View Last Filemenu
%%index =
gosub getdata
if %%topic
%%new =
gosub getfile
end
goto evloop
:View Last Developer Postmenu
%%index = 1
gosub getdata
if %%topic
%%new =
gosub getpost
end
goto evloop
:Check Nowmenu
:timer
%%index =
gosub getdata
if %%topic
%%update =
if %%lastpost
if @not(@equal(%%post,%%lastpost))
if %%forumnotify
%%new = 1
gosub getpost
end
%%update = 1
end
else
%%update = 1
end
if %%update
%%lastpost = %%post
registry write,default,,lastpost,%%lastpost
end
%%update =
if %%lastfile
if @not(@equal(%%file,%%lastfile))
if %%filenotify
%%new = 1
gosub getfile
end
%%update = 1
end
else
%%update = 1
end
if %%update
%%lastfile = %%file
registry write,default,,lastfile,%%lastfile
end
%%index = 1
gosub getdata
if %%topic
%%update =
if %%lastdevpost
if @not(@equal(%%post,%%lastdevpost))
if %%devforumnotify
%%new = 1
gosub getpost
end
%%update = 1
end
else
%%update = 1
end
if %%update
%%lastdevpost = %%post
registry write,default,,lastdevpost,%%lastdevpost
end
end
end
goto evloop
:taIconclick
if @equal(@click(B),left)
goto timer
else
dialog popup,&Check Now|-|View Last &Post|View Last &Developer Post|View Last &File|-|Open &Forum|Open &Developer Forum|Open &VDSWORLD|-|&Settings|-|C&lose
goto evloop
end
:Open Forummenu
%%link = http://forum.vdsworld.com/
gosub newbrowserwindow
goto evloop
:Open Developer Forummenu
%%link = http://www.vdsworld.com/developer/
gosub newbrowserwindow
goto evloop
:Open VDSWORLDmenu
%%link = http://www.vdsworld.com/
gosub newbrowserwindow
goto evloop
:Settingsmenu
dialog set,chAutoLaunch,%%launch
dialog set,chForumNotify,%%forumnotify
dialog set,chFileNotify,%%filenotify
dialog set,chDevForumNotify,%%devforumnotify
%x = @match(cInterval,%%interval)
window normal,#vdsCheckUp
goto Evloop
:bOKbutton
%%launch = @dlgtext(chAutoLaunch)
%%forumnotify = @dlgtext(chForumNotify)
%%filenotify = @dlgtext(chFileNotify)
%%devforumnotify = @dlgtext(chDevForumNotify)
%%interval = @dlgtext(cInterval)
registry write,default,,launch,%%launch
registry write,default,,forumnotify,%%forumnotify
registry write,default,,filenotify,%%filenotify
registry write,default,,devforumnotify,%%devforumnotify
registry write,default,,interval,%%interval
if %%launch
if @not(@equal(@ext(%0),dsc))
registry write,local,SOFTWARE\Microsoft\Windows\CurrentVersion\Run,VCheckUp,%0
end
else
registry delete,local,SOFTWARE\Microsoft\Windows\CurrentVersion\Run,VCheckUp
end
:CancelBUTTON
window hide,#VdsCheckUp
goto evloop
:getdata
if @equal(%%index,1)
internet http,get,1,http://www.vdsworld.com/developer/data.php
parse "%%topic;%%post",@trim(@internet(http,content,1))
else
internet http,get,1,http://www.vdsworld.com/data.php
parse "%%topic;%%post;%%file;%%filetitle;%%fileauthor",@trim(@internet(http,content,1))
end
exit
:getpost
if @equal(%%index,1)
%%parturl = http://www.vdsworld.com/developer/data.php
%%developer = "developer "
else
%%parturl = http://www.vdsworld.com/data.php
%%developer =
end
internet http,get,1,%%parturl?request=text&id=%%post&count=%%maxmessage
list create,7
list assign,7,@internet(http,content,1)
list delete,7
%%lastuser = @item(7,0)
list delete,7
%%lasttopic = @item(7,0)
list delete,7
%%lastsubject = @item(7,0)
list delete,7
if @greater(@count(7),%%maxmessagelines)
list seek,7,%%maxmessagelines
repeat
list delete,7
until @greater(@succ(%%maxmessagelines),@count(7))
end
%%lastmessage = @text(7)
if @greater(@len(%%lastmessage),%%maxmessage)
%%lastmessage = @substr(%%lastmessage,1,%%maxmessage)...
end
list close,7
if @not(%%lastsubject)
%%lastsubject = Reply to %%lasttopic
end
if @greater(@len(%%lastsubject),%%maxsubject)
%%lastsubject = @substr(%%lastsubject,1,%%maxsubject)...
end
if @greater(@len(%%lastuser),%%maxuser)
%%lastuser = @substr(%%lastuser,1,%%maxuser)...
end
if %%new
%%message = There's a new post on the VDSWORLD %%developer""forum:
else
%%message = This is the last post on the VDSWORLD %%developer""forum:
end
%%message = %%message@cr()@chr(10)@cr()@chr(10)By: %%lastuser@cr()@chr(10)Subj: %%lastsubject@cr()@chr(10)@cr()@chr(10)%%lastmessage
if @equal(%%index,1)
%%link = "http://www.vdsworld.com/developer/viewtopic.php?t="%%topic"#"%%post
else
%%link = "http://www.vdsworld.com/forum/viewtopic.php?t="%%topic"#"%%post
end
%%download =
gosub message
exit
:getfile
if %%new
%%message = There's a new file posted at VDSWORLD.
else
%%message = This is the last file posted at VDSWORLD.
end
%%message = %%message Click here to download:@cr()@chr(10)@cr()@chr(10)%%filetitle@cr()@chr(10)@cr()@chr(10)by %%fileauthor
%%download = "http://www.vdsworld.com/index.php?page=download&fileid="%%file
%%link =
gosub message
exit
:parsefilename
%i = 0
%q =
repeat
%i = @succ(%i)
%c = @substr(%%filename,%i)
if @equal(%c,@chr(34))
if %q
%q = 2
else
%q = 1
end
else
if @not(%q)
if @equal(%c," ")
%q = 3
end
end
end
until @equal(%i,@len(%%filename))@equal(%q,2)@equal(%q,3)
if @equal(%q,3)
%%filename1 = @substr(%%filename,1,@pred(%i))
else
if @equal(%q,2)
%%filename1 = @substr(%%filename,2,@pred(%i))
else
%%filename1 = %%filename
end
end
exit
:message
DIALOG CREATE,Check-Up Message Window,300,300,220,148,CLASS VDSMESSAGE,NOTITLE,ONTOP
DIALOG ADD,STYLE,sMessage,,8,BL,,%%fontColor
dialog add,Shape,sBackground,0,0,216,148,%%backColor,%%borderColor,,Rectangle
DIALOG ADD,TEXT,tMessage,8,8,208,132,%%message,,TRANSPARENT,sMessage,CLICK,HAND
%T = @winpos(#Shell_TrayWnd,T)
%L = @winpos(#Shell_TrayWnd,L)
%H = @winpos(#Shell_TrayWnd,H)
%W = @winpos(#Shell_TrayWnd,W)
%%screenheight = @sysinfo(screenheight)
%%upperT = @diff(%%screenheight,@dlgpos(,H))
%L = @diff(@sysinfo(screenwidth),@dlgpos(,W))
if @equal(%T,0)
rem taskbar is positioned at top, left or right
if @equal(%L,0)
rem taskbar is positioned at left; no problem
else
rem taskbar is positioned at top or right
if @equal(%H,%%screenheight)
rem taskbar is positioned at right
%L = @diff(%L,%W)
else
rem taskbar is positioned at top; no problem
end
end
else
rem taskbar is positioned at bottom
%%upperT = @diff(%%upperT,%H)
end
%%lowerT = %%screenheight
DIALOG SETPOS,,%%lowerT,%L
DIALOG SHOW
while @not(@equal(@dlgpos(,T),200))
rem while @not(@equal(@dlgpos(,T),%%upperT))
dialog setpos,,@pred(@dlgpos(,T))
gosub sleep
wend
repeat
wait event,10
%e = @event()
until @equal(%e,timer)@equal(%e,tMessageclick)@equal(%e,taIconclick)
if @equal(%e,tMessageclick)
if %%link
gosub newbrowserwindow
else
shell open,%%download
end
else
while @not(@equal(@dlgpos(,T),%%lowerT))
dialog setpos,,@succ(@dlgpos(,T))
gosub sleep
wend
end
dialog close
rem clear the "CLOSE" event from the event buffer
%x = @event()
exit
:sleep
%i = 0
repeat
%i = @succ(%i)
until @equal(%i,10)
exit
:newbrowserwindow
%%filename = @regread(root,http\shell\open\command,)
if %%filename
gosub parsefilename
run @shortname(%%filename1) %%link
end
exit
:Closemenu
:close
internet http,destroy,1
exit
:bViewBUTTON
DIALOG CREATE,Display Settings,-1,0,135,170,SMALLCAP
REM *** Modified by Dialog Designer on 12/15/02 - 12:37 ***
DIALOG ADD,TEXT,TEXT1,5,5,85,15,Background color:
DIALOG ADD,EDIT,EDIT1,20,5,80,20,%%backColor
DIALOG ADD,BUTTON,Set1,20,100,30,20,Set
DIALOG ADD,TEXT,TEXT2,45,5,60,15,Border color:
DIALOG ADD,EDIT,EDIT2,60,5,80,20,%%borderColor
DIALOG ADD,BUTTON,Set2,60,100,30,20,Set
DIALOG ADD,TEXT,TEXT3,85,5,50,15,Font color:
DIALOG ADD,EDIT,EDIT3,100,5,80,20,%%fontColor
DIALOG ADD,BUTTON,Set3,100,100,30,20,Set
DIALOG ADD,GROUP,gSep1,130,5,125,2
DIALOG ADD,BUTTON,DSApply,140,5,60,25,Apply
DIALOG ADD,BUTTON,DSCancel,140,70,60,25,Cancel
DIALOG SHOW
dialog disable,DSApply
goto Evloop
:Set1BUTTON
%%colordlg = %%borderColor
:Set2BUTTON
%%colordlg = %%backColor
:Set3BUTTON
%%colordlg = %%fontColor
%%setNum = @substr(%e,4)
%%colordlg = @colordlg(%%colordlg)
if @not(@null(%%colordlg))
dialog select,1
dialog set,EDIT%%setNum,%%colordlg
dialog enable,DSApply
end
goto Evloop
:DSApplyBUTTON
dialog select,1
%%backColor = @dlgtext(EDIT1)
%%borderColor = @dlgtext(EDIT2)
%%fontColor = @dlgtext(EDIT3)
registry write,default,,borderColor,%%borderColor
registry write,default,backColor,%%backColor
registry write,default,fontColor,%%fontColor
:DSCancelBUTTON
dialog select,1
dialog close
wait event
%E = @event()
goto Evloop
|
_________________ Bill Weckel
ShinobiSoft Software
"The way is known to all, but not all know it." |
|
Back to top |
|
|
ShinobiSoft Professional Member
Joined: 06 Nov 2002 Posts: 790 Location: Knoxville, Tn
|
Posted: Mon Dec 16, 2002 2:29 am Post subject: |
|
|
Is there any way when using the check up tool to automatically log you in to the forum with your user name and password if you selected the 'Open Forum' MENU? _________________ Bill Weckel
ShinobiSoft Software
"The way is known to all, but not all know it." |
|
Back to top |
|
|
FreezingFire Admin Team
Joined: 23 Jun 2002 Posts: 3508
|
Posted: Mon Dec 16, 2002 11:40 am Post subject: |
|
|
You could login and check the "log me in automatically" box when logging in.
I'm not sure, but I think you might be able to use the following:
http://USERNAME:PASSWORD@www.vdsworld.com/forum/ _________________ FreezingFire
VDSWORLD.com
Site Admin Team |
|
Back to top |
|
|
|
|
You cannot post new topics in this forum You cannot reply to topics in this forum You cannot edit your posts in this forum You cannot delete your posts in this forum You cannot vote in polls in this forum You can attach files in this forum You can download files in this forum
|
|