forum.vdsworld.com Forum Index forum.vdsworld.com
Visit VDSWORLD.com
 
 FAQFAQ   SearchSearch   MemberlistMemberlist   UsergroupsUsergroups   RegisterRegister 
 ProfileProfile   Log in to check your private messagesLog in to check your private messages   Log inLog in 


[Open Source]: ProSetup Installer
Goto page Previous  1, 2, 3, 4  Next
 
Post new topic   Reply to topic    forum.vdsworld.com Forum Index -> Visual DialogScript Open Source Projects
View previous topic :: View next topic  
Author Message
marty
Professional Member
Professional Member


Joined: 10 May 2001
Posts: 789

PostPosted: Fri Sep 13, 2002 2:14 am    Post subject: Reply with quote

Sorry guys I though I had done more code a year ago for the Installer I started, I wont even post it... there's almost nothing done, license window and browser window for installation and the code is a mess too... No use of posting that.. sorry. Embarassed
Back to top
View user's profile Send private message Send e-mail Visit poster's website MSN Messenger
cnodnarb
Valued Contributor
Valued Contributor


Joined: 11 Sep 2002
Posts: 640
Location: Evansville, IN

PostPosted: Fri Sep 13, 2002 5:13 am    Post subject: Reply with quote

Ever heard of PowerArchiver?

Allows SFX with specified file run after extraction, as displayed in the self extractor found at http://members.aol.com/_ht_a/webwritepro/webwritepro.exe

It is ShareWare on there website, but I just read my license agreement for the Freeware version I have and it says "Totally FREE for Any Purpose", which I assume is what it means. I think I will probably find purpose upon request to upload the setup file so others can download it. Post a reply if interested.

Can use a resource hacker to change icon but didn't...Microangelo works very well.

WebWrite Pro is now open source BTW, but that won't be officially announced until tommorow...oh wait, it is tommorow, well after I have time today then Cool
Back to top
View user's profile Send private message AIM Address
Tommy
Admin Team


Joined: 16 Nov 2002
Posts: 737
Location: The Netherlands

PostPosted: Fri Sep 13, 2002 2:21 pm    Post subject: Reply with quote

FreezingFire wrote:
Yes...that is a good idea...however, the user may not have zip/unzip program...so self-extraction may be needed...I've yet to find an exe that just extracts to a specified directory then runs a file (in this case "setup.exe" or something...)

I noticed when I open a V-Setup file in WinZip I find there is a program named "setup.exe"...when I extract that from the archive, and run it, it runs like the normal setup program...so, in theory, the single actual "setup.exe" program that the end-user runs is extracting the files, then running an executable named "setup.exe".


I think that Easy Packets does exactly this. Unfortunately it doesn't currently offer a
command-line compiler. To simulate how it compiles, you may be able to do it like this:

- Create a .zip file with any files that are to be extracted (right in the root of the .zip file)
plus a settings.set file.

The settings.set file is in a special format indicating the extraction options which are to be
used, for an example, unzip any SFX file created by Easy Packets using regular unzip software. The format is like this:
Line 1: absolute path to optional readme file
Line 2: absolute path to optional executable file location which is run after extraction, in the following format:
<absolute filename>|{<command-line parameters>}
Line n: description for extraction of a file, in the following format:
<source filename (without any path)>|<destination directory>|<flags>

<flags> can be:
D - attempt automatic deletion after run
F - attempt automatic deletion harder after run (force)

Any of the paths (even the mentioned "absolute" ones) and filenames can include the known
variables of Easy Packets such as "<progfiles>" and "<temp>".

- Then the .zip file is simply appended to the common Easy Packets stub which can be
found in your <progfiles>\ep\unpack.exe after installing Easy Packets. This could be
done using the "COPY /B" command or some of the binary in-/output DLLs.

- The resulting .exe file will have to be adjusted, for example using InfoZip's zip.exe
and "-A" commandline option.

I hereby grant permission to anyone for use of the UNPACK.EXE stub in any freeware software.
Back to top
View user's profile Send private message Send e-mail Visit poster's website
FreezingFire
Admin Team


Joined: 23 Jun 2002
Posts: 3508

PostPosted: Sat Sep 14, 2002 2:13 pm    Post subject: List Options Reply with quote

OK...

Does anyone know how to get lists of the following?

All of the folder items in the start menu
Program files folders

_________________
FreezingFire
VDSWORLD.com
Site Admin Team
Back to top
View user's profile Send private message Visit poster's website
Skit3000
Admin Team


Joined: 11 May 2002
Posts: 2166
Location: The Netherlands

PostPosted: Sat Sep 14, 2002 2:37 pm    Post subject: Reply with quote

I haven't tried it, but maybe you can use list filelist combined with %USERPROFILE%\Menu Start...

For so far I know this only works in Windows XP, but maybe also on other versions...
Back to top
View user's profile Send private message
FreezingFire
Admin Team


Joined: 23 Jun 2002
Posts: 3508

PostPosted: Sat Sep 14, 2002 2:55 pm    Post subject: Reply with quote

__________________________________________________________________________________________________________________________
Here's something using one of the reg. entries Dr. Dread wrote...

Code:
list create,1
rem %%startmenu reg. entry from Dr. Dread
%%StartMenu = @REGREAD(CURUSER,Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders,Start Menu)
list filelist,1,%%startmenu,*
info @text(1)

_________________
FreezingFire
VDSWORLD.com
Site Admin Team


Last edited by FreezingFire on Sun Dec 08, 2002 5:37 pm; edited 2 times in total
Back to top
View user's profile Send private message Visit poster's website
FreezingFire
Admin Team


Joined: 23 Jun 2002
Posts: 3508

PostPosted: Sat Sep 14, 2002 4:12 pm    Post subject: Reply with quote

I can't get this page-change code to work...I don't see what I'm doing wrong...although it does not work well ever...
maybe someone knows of a better way to do it?

I'm good at designing the pages, just can't get them to change...
Code:
Title Setup
%%appname = Test Application
  DIALOG CREATE,Setup - %%appname,-1,0,493,356
  DIALOG ADD,STYLE,Heading,MS Sans Serif,12,B,,
  DIALOG ADD,STYLE,BOLD,,,B,,
  DIALOG ADD,STYLE,WHITE-WHITE,,,,WHITE,WHITE
  DIALOG ADD,GROUP,sep1,313,0,494,2
  DIALOG ADD,BITMAP,BITMAP_LARGE,0,0,0,0,WizModernImage.bmp
  DIALOG ADD,TEXT,FLOODFILL,0,164,330,314,,,WHITE-WHITE
  DIALOG ADD,BUTTON,Cancel,324,408,74,24,Cancel
  DIALOG ADD,BUTTON,Next,324,322,74,24,Next >
  DIALOG ADD,BUTTON,Back,324,246,74,24,< Back
  DIALOG ADD,TEXT,TWelcome,20,175,318,42,Welcome to the %%appname@cr()Setup Wizard,,Heading,TRANSPARENT
  DIALOG ADD,TEXT,TM1,63,175,320,13,This will install %%appname on your computer.,,TRANSPARENT
  DIALOG ADD,TEXT,TM2,90,175,318,13,It is strongly recommended that you close all other applications,,TRANSPARENT
  DIALOG ADD,TEXT,TM3,103,175,292,13,you have running before continuing. This will help prevent any,,TRANSPARENT
  DIALOG ADD,TEXT,TM4,116,175,184,13,conflicts during the installation process.,,TRANSPARENT
  DIALOG ADD,TEXT,TM5,152,175,318,13,Click Next to continue","or Cancel to exit Setup.,,TRANSPARENT
  DIALOG ADD,TEXT,FLOODFILL2,0,0,494,60,,,WHITE-WHITE
  DIALOG ADD,TEXT,WizHeader,14,24,356,13,License Agreement,,TRANSPARENT,BOLD
  DIALOG ADD,TEXT,WizSubHeader,30,40,344,13,Please read the following important information before continuing.,,TRANSPARENT
  DIALOG ADD,BITMAP,BITMAP_SMALL,2,436,55,55,WizModernSmallImage.bmp
  DIALOG ADD,GROUP,sep2,60,0,494,2
  DIALOG ADD,TEXT,LT1,80,40,405,13,Please read the following License Agreement. Use the scroll bar to view the rest of the
  DIALOG ADD,TEXT,LT2,92,40,53,13,agreement.
  DIALOG ADD,EDIT,ELICENSE,113,40,406,150,,,SCROLL,MULTI,WRAP
  DIALOG ADD,TEXT,LT4,272,40,376,13,Do you accept the terms if the preceding License Agreement? If you choose No
  DIALOG ADD,TEXT,LT5,286,40,343,13,Setup will close. To install %%appname"," you must accept this agreement.
  %%page = 1
  if @equal(%%page,1)
  dialog hide,back
  dialog hide,FLOODFILL2
  dialog hide,WizHeader
  dialog hide,WizSubHeader
  dialog hide,BITMAP_SMALL
  dialog hide,sep2
  dialog hide,LT1
  dialog hide,LT2
  dialog hide,ELICENSE
  dialog hide,LT4
  dialog hide,LT5
  end
  DIALOG SHOW
:Evloop
  wait event
  goto @event()
:CancelBUTTON
  goto close
:NextBUTTON
  if @equal(%%page,1)
  dialog hide,BITMAP_LARGE
  dialog hide,FLOODFILL
  dialog hide,TWELCOME
  dialog hide,TM1
  dialog hide,TM2
  dialog hide,TM3
  dialog hide,TM4
  dialog hide,TM5
  dialog show,back
  dialog show,FLOODFILL2
  dialog show,WizHeader
  dialog show,WizSubHeader
  dialog show,BITMAP_SMALL
  dialog show,sep2
  dialog show,LT1
  dialog show,LT2
  dialog show,ELICENSE
  dialog show,LT4
  dialog show,LT5
  %%page = 2
  end
  goto evloop
:BackBUTTON
  if @equal(%%page,2)
  dialog show,BITMAP_LARGE
  dialog show,FLOODFILL
  dialog show,TWELCOME
  dialog show,TM1
  dialog show,TM2
  dialog show,TM3
  dialog show,TM4
  dialog show,TM5
  dialog hide,back
  dialog hide,FLOODFILL2
  dialog hide,WizHeader
  dialog hide,WizSubHeader
  dialog hide,BITMAP_SMALL
  dialog hide,sep2
  dialog hide,LT1
  dialog hide,LT2
  dialog hide,ELICENSE
  dialog hide,LT4
  dialog hide,LT5
  end
  goto evloop
:Close
  if @equal(@msgbox(Setup is not complete.@cr()If you quit now"," %%appname will not be installed on your computer.@cr()You can run setup at a later time to complete the installation.@cr()Are you sure you want to exit setup?,Setup,$034),6)
  exit
  end
  goto evloop

_________________
FreezingFire
VDSWORLD.com
Site Admin Team
Back to top
View user's profile Send private message Visit poster's website
Tommy
Admin Team


Joined: 16 Nov 2002
Posts: 737
Location: The Netherlands

PostPosted: Sat Sep 14, 2002 4:42 pm    Post subject: Reply with quote

This is really very odd, almost seems like a bug in VDS... It doesn't hide some of the
elements after using DIALOG HIDE while it is supposed to...
Back to top
View user's profile Send private message Send e-mail Visit poster's website
FreezingFire
Admin Team


Joined: 23 Jun 2002
Posts: 3508

PostPosted: Sat Sep 14, 2002 4:54 pm    Post subject: Reply with quote

Yes...but take a look at how the example WIZARD.DSC by S.A.D.E. does this... (it seems rather compilcated...)

Code:
REM ****************************************************
REM wizard.dsc v. 4.0
REM This example script shows how to create a Wizard using VDS
REM (c) 1995 - 2002 S.A.D.E.
   TITLE Wizard Example      
   REM %%last specifies last page
   %%last = 3
   REM set any data variables to initial values
   %%filename =
   OPTION SCALE,96
  DIALOG CREATE,Visual DialogScript Wizard Example,-1,0,468,282,NOSYS,NOMIN
  DIALOG ADD,BITMAP,BITMAP1,16,16,160,200,wiz.dsr|0,STRETCH
  DIALOG ADD,GROUP,GROUP1,232,14,440,2
  DIALOG ADD,BUTTON,Back,248,180,64,24,< &Back
  DIALOG ADD,BUTTON,Next,248,244,64,24,&Next >
  DIALOG ADD,BUTTON,Cancel,248,324,64,24,Cancel
  DIALOG ADD,BUTTON,Help,248,388,64,24,Help
  DIALOG SHOW
   %%page = 1
   %%act = ADD
   gosub page
:evloop
   wait event
   %E = @event()
   goto %E
:BackBUTTON
   %%act = REMOVE
   gosub page
   %%page = @pred(%%page)
   %%act = ADD
   gosub page
   goto evloop
:NextBUTTON
   REM check for application-specific error conditions here
   if @equal(%%page,2)
      if @not(@file(@dlgtext(edFileName)))
         warn You must select a file!
         goto evloop
      end
   end
   %%act = REMOVE
   gosub page
   %%page = @succ(%%page)
   %%act = ADD
   gosub page
   goto evloop
:HelpBUTTON
   info Call the help file here!
   goto evloop
:CancelBUTTON
   if @equal(%%page,%%last)
      REM This code will be executed when user clicks Finish
      shell open,%%filename
      exit
   else
      exit
   end
   exit
:Page
   REM Handle the standard wizard controls
   if @equal(%%page,1)
      DIALOG DISABLE,Back
   end
   if @greater(%%page,1)
      DIALOG ENABLE,Back
   end
   if @greater(%%last,%%page)
      DIALOG ENABLE,Next
      DIALOG SET,Cancel,Cancel
   end
   if @equal(%%page,%%last)
      DIALOG DISABLE,Next
      DIALOG SET,Cancel,Finish
   end
   REM Page-specific code starts here
   if @equal(%%page,1)
      if @equal(%%act,ADD)
        DIALOG ADD,TEXT,TEXT1,18,196,252,116,"This example demonstrates how to create a Wizard using Visual DialogScript."@cr()@cr()"In the example, you are asked on the second page of the Wizard to select a file. The file is opened if you close the Wizard by clicking Finish."
      else
         DIALOG REMOVE,TEXT1
      end
   end
   if @equal(%%page,2)
      if @equal(%%act,ADD)
        DIALOG ADD,TEXT,TEXT1,18,196,,,Select a file:
         REM set values from data variables in case they go back ...
        DIALOG ADD,EDIT,edFileName,40,196,220,20,%%filename
         REM Choose unique names for elements that generate events
         REM then you don't have to worry which page they come from
        DIALOG ADD,BUTTON,Brwse,40,424,24,21,...
      else
         REM save the values in any elements before deleting them
         %%filename = @dlgtext(edFileName)
         DIALOG REMOVE,Brwse
         DIALOG REMOVE,edFileName
         DIALOG REMOVE,TEXT1
      end
   end
   if @equal(%%page,3)
      if @equal(%%act,ADD)
        DIALOG ADD,TEXT,TEXT1,18,196,252,116,You have selected the file %%filename@cr()@cr()"If you click Finish, the Wizard will open this file."
      else
         DIALOG REMOVE,TEXT1
      end
   end
   exit
   REM Application-specific events
:BrwseBUTTON
   %F = @filedlg(*.*,Select a file)
   if @ok()
      DIALOG SET,edFileName,%F
   end
   goto evloop

_________________
FreezingFire
VDSWORLD.com
Site Admin Team


Last edited by FreezingFire on Sun Dec 08, 2002 5:38 pm; edited 1 time in total
Back to top
View user's profile Send private message Visit poster's website
Tommy
Admin Team


Joined: 16 Nov 2002
Posts: 737
Location: The Netherlands

PostPosted: Sat Sep 14, 2002 4:55 pm    Post subject: Reply with quote

What you could do is use DIALOG ADD and DIALOG REMOVE each time like this:

Code:

Title Setup
%%appname = Test Application
  DIALOG CREATE,Setup - %%appname,-1,0,493,356
  DIALOG ADD,STYLE,Heading,MS Sans Serif,12,B,,
  DIALOG ADD,STYLE,BOLD,,,B,,
  DIALOG ADD,STYLE,WHITEWHITE,,,,WHITE,WHITE
  DIALOG ADD,GROUP,sep1,313,0,494,2
  DIALOG ADD,BUTTON,Back,324,246,74,24,< Back
  DIALOG ADD,BUTTON,Next,324,322,74,24,Next >
  DIALOG ADD,BUTTON,Cancel,324,408,74,24,Cancel
  DIALOG SHOW
  %%previouspage =
  %%newpage = 1
  gosub show
:Evloop
  wait event
  goto @event()
:BackBUTTON
  %%newpage = @pred(%%newpage)
  gosub show
  goto evloop
:NextBUTTON
  %%newpage = @succ(%%newpage)
  gosub show
  goto evloop
:show
  if %%previouspage
    gosub hide%%previouspage
  end
  %%previouspage = %%newpage
  gosub show%%newpage
  exit
:show1
  DIALOG ADD,BITMAP,BITMAP_LARGE,0,0,0,0,WizModernImage.bmp
  DIALOG ADD,TEXT,FLOODFILL,0,164,330,314,,,WHITEWHITE
  DIALOG ADD,TEXT,TWelcome,20,175,318,42,Welcome to the %%appname@cr()Setup Wizard,,Heading,TRANSPARENT
  DIALOG ADD,TEXT,TM1,63,175,320,13,This will install %%appname on your computer.,,TRANSPARENT
  DIALOG ADD,TEXT,TM2,90,175,318,13,It is strongly recommended that you close all other applications,,TRANSPARENT
  DIALOG ADD,TEXT,TM3,103,175,292,13,you have running before continuing. This will help prevent any,,TRANSPARENT
  DIALOG ADD,TEXT,TM4,116,175,184,13,conflicts during the installation process.,,TRANSPARENT
  DIALOG ADD,TEXT,TM5,152,175,318,13,Click Next to continue","or Cancel to exit Setup.,,TRANSPARENT
  dialog hide,Back
  exit
:hide1
  dialog remove,BITMAP_LARGE
  dialog remove,FLOODFILL
  dialog remove,TWelcome
  dialog remove,TM1
  dialog remove,TM2
  dialog remove,TM3
  dialog remove,TM4
  dialog remove,TM5
  dialog show,Back
  exit
:show2
  DIALOG ADD,TEXT,FLOODFILL2,0,0,494,60,,,WHITEWHITE
  DIALOG ADD,TEXT,WizHeader,14,24,356,13,License Agreement,,TRANSPARENT,BOLD
  DIALOG ADD,TEXT,WizSubHeader,30,40,344,13,Please read the following important information before continuing.,,TRANSPARENT
  DIALOG ADD,GROUP,sep2,60,0,494,2
  DIALOG ADD,BITMAP,BITMAP_SMALL,2,436,55,55,WizModernSmallImage.bmp
  DIALOG ADD,TEXT,LT1,80,40,405,13,Please read the following License Agreement. Use the scroll bar to view the rest of the
  DIALOG ADD,TEXT,LT2,92,40,53,13,agreement.
  DIALOG ADD,EDIT,ELICENSE,113,40,406,150,,,SCROLL,MULTI,WRAP
  DIALOG ADD,TEXT,LT4,272,40,376,13,Do you accept the terms of the preceding License Agreement? If you choose No
  DIALOG ADD,TEXT,LT5,286,40,343,13,Setup will close. To install %%appname"," you must accept this agreement.
  exit
:hide2
  dialog remove,FLOODFILL2
  dialog remove,WizHeader
  dialog remove,WizSubHeader
  dialog remove,sep2
  dialog remove,BITMAP_SMALL
  dialog remove,LT1
  dialog remove,LT2
  dialog remove,ELICENSE
  dialog remove,LT4
  dialog remove,LT5
  exit
:CancelBUTTON
:Close
  if @equal(@msgbox(Setup is not complete.@cr()If you quit now"," %%appname will not be installed on your computer.@cr()You can run setup at a later time to complete the installation.@cr()Are you sure you want to exit setup?,Setup,$034),6)
    exit
  end
  goto evloop

Back to top
View user's profile Send private message Send e-mail Visit poster's website
FreezingFire
Admin Team


Joined: 23 Jun 2002
Posts: 3508

PostPosted: Sat Sep 14, 2002 7:58 pm    Post subject: Reply with quote

Thanks, Tommy...that is really quite simple the way you did it! Very Happy

--

I believe the VDSOBJ.DLL is written and maintained by PGWARE...so I will direct this question to PGWARE...

Would there be a possible way to compile a VDSOBJ DLL that ONLY includes the Drive List (that you can select the drive letter in) and the Directory list box (that lets you select a directory)?

This would be a really, really good thing for a setup program, since the uninstaller just needs these elements...instead of having to distribute all of the table element, richedit, etc.

Thanks...

_________________
FreezingFire
VDSWORLD.com
Site Admin Team
Back to top
View user's profile Send private message Visit poster's website
Skit3000
Admin Team


Joined: 11 May 2002
Posts: 2166
Location: The Netherlands

PostPosted: Sat Sep 14, 2002 8:29 pm    Post subject: Reply with quote

Isn't this the same as the Drivelist in vdsobj.dll???

Code:

  DIALOG CREATE,Drivelist example,-1,0,240,160
  DIALOG ADD,COMBO,DRIVELIST,18,6,180,21,,LIST,CLICK
  DIALOG ADD,TEXT,TEXT1,2,6,,,Select a drive:
  DIALOG SHOW
 
%%var1 = 65
repeat
if @greater(@len(@volinfo(@chr(%%var1),T)),0)
  list add,drivelist,@volinfo(@chr(%%var1),T) @chr(%%var1):
  end
%%var1 = @succ(%%var1)
until @equal(%%var1,91)
 
:evloop
wait event
goto @event()

:Drivelistclick
%%drive = @substr(@item(drivelist),@pred(@pos(:,@item(drivelist))),@pred(@pos(:,@item(drivelist))))
info You selected the %%drive drive...@cr()This drive is a @volinfo(%%drive,T) drive.@cr()The name is @volinfo(%%drive,N)@cr()And the total amount of free space is @div(@volinfo(%%drive,F),1024) Mb
goto evloop

:Close
exit


If you want icons, I think you should make your own font like SADE did with V-Setup...
Back to top
View user's profile Send private message
FreezingFire
Admin Team


Joined: 23 Jun 2002
Posts: 3508

PostPosted: Sat Sep 14, 2002 9:58 pm    Post subject: Reply with quote

Yes...that will be good if we can't get VDSOBJ to work...however the downside to fonts is that you can't use color glyphs... Sad
_________________
FreezingFire
VDSWORLD.com
Site Admin Team
Back to top
View user's profile Send private message Visit poster's website
FreezingFire
Admin Team


Joined: 23 Jun 2002
Posts: 3508

PostPosted: Sun Sep 15, 2002 1:05 am    Post subject: Reply with quote

Never mind about VDSOBJ...I think I can use the VDSLIST DLL that Tommy just released...in combination with Skit's Drive Letter Code...

That will work well...

_________________
FreezingFire
VDSWORLD.com
Site Admin Team
Back to top
View user's profile Send private message Visit poster's website
Eric
Newbie


Joined: 07 May 2002
Posts: 8
Location: France

PostPosted: Sun Sep 22, 2002 4:45 pm    Post subject: Reply with quote

LOOK MY CODE



Code:

REM %%SS AND %%TT adapt automaticaly the resolution of installer

%%SS = @SYSINFO(SCREENWIDTH)
%%TT = @SYSINFO(SCREENHEIGHT)

%%taillex = @FDIV(%%SS,2)
%%tailley = @FDiv(%%TT,2)
%%x = @sum(%%taillex,50)
%%y = @sum(%%tailley,250)


OPTION ERRORTRAP,yikes !
DIALOG CREATE,///,-1,0,799,600,NOTITLE
DIALOG ADD,BITMAP,BITMAP2,0,0,804,608,Setup.BMP
dialog show
DIALOG CREATE,InstallShield Wizard,%%x,%%y,375,116,NOSYS
DIALOG ADD,TEXT,TEXT1,16,62,,,INSTALL de ControlPC prpare l'assistant
DIALOG ADD,BITMAP,BITMAP1,20,10,35,40,logo.bmp

DIALOG ADD,TEXT,TEXT5,29,62,,,d'InstallShield(R)"," qui vous guidera   travers les tapes du
DIALOG ADD,TEXT,TEXT6,42,62,,,processus d'installation qui restent. Veuillez patienter...
DIALOG ADD,BUTTON,BUTTON1,83,293,74,24,Annuler
DIALOG ADD,PROGRESS,INTROPROGRESS,84,13,270,16
dialog show
:evloop
wait "0,5",event
%E = @event()
goto %E
:TIMER
%P = @sum(%P,10)
dialog set,INTROPROGRESS,%P
wait "1"
%P = @sum(%P,5)
dialog set,INTROPROGRESS,%P
%P = @sum(%P,7)
dialog set,INTROPROGRESS,%P
wait "2"
%P = @sum(%P,10)
dialog set,INTROPROGRESS,%P
wait "2"
%P = @sum(%P,25)
dialog set,INTROPROGRESS,%P
wait "1"
%P = @sum(%P,10)
dialog set,INTROPROGRESS,%P
wait "1"
%P = @sum(%P,10)
dialog set,INTROPROGRESS,%P
wait "0,1"
%P = @sum(%P,10)
dialog set,INTROPROGRESS,%P
wait "0,5",event
%P = @sum(%P,10)
dialog set,INTROPROGRESS,%P

%E = @event()
if @equal(TIMER,%E)
goto ininstall
else
goto close
end
end


:ininstall
DIALOG SELECT,0
DIALOG HIDE
DIALOG SELECT,1
DIALOG HIDE
DIALOG CREATE,Installation de ControlPC version 1.1,-1,0,986,633
DIALOG ADD,BITMAP,BITMAP1,0,0,986,650,titre1.bmp
dialog show
:ininstall2
DIALOG CREATE,Installation de ControlPC 1.1,-1,0,496,352,NOSYS,ONTOP
DIALOG ADD,STYLE,STYLE2,,6,,WHITE,FOREGROUND
DIALOG ADD,STYLE,STYLE1,,8,B,WHITE,FOREGROUND
DIALOG ADD,GROUP,GROUP1,302,2,493,2
DIALOG ADD,BITMAP,BITMAP1,0,0,496,300,clown.bmp
DIALOG ADD,TEXT,TEXT1,29,195,,,Bienvenue dans l'Installshield Wizard de,STYLE1
DIALOG ADD,TEXT,TEXT3,43,195,,,ControlPC version 1.1.,STYLE1
DIALOG ADD,TEXT,TEXT4,82,194,,,L'installshield Wizard installera ControlPC version 1.1,STYLE2
DIALOG ADD,TEXT,TEXT5,95,194,,,sur votre ordinateur. Pour continuer",",STYLE2
DIALOG ADD,TEXT,TEXT6,109,194,,,cliquez sur Suivant.,STYLE2
DIALOG ADD,BUTTON,ANNULER,316,407,75,24,Annuler
DIALOG ADD,BUTTON,SUIVANT1,316,321,75,24,Suivant >
DIALOG ADD,BUTTON,BUTTON3,316,247,75,24,< Prcedent
dialog show
DIALOG DISABLE,BUTTON3
goto evloop2
:evloop2
wait event
goto @event()

:ANNULERBUTTON
:BUTTON1BUTTON
goto close


:close
title Sortez de l'assistant d'installation
Warn L'installation n'est pas termine. Si vous quittez maintenant le programme d'installation"," les composants que vous demand s@cr()d'ajouter/supprimer ne seront pas installs/d sinstalls.@cr()@cr()Vous pouvez ex cuter le programme d'installation ultrieurement afin de compl ter les oprations.
exit
:SUIVANT1BUTTON
DIALOG HIDE
DIALOG CREATE,V rification du Numro de S rie,-1,0,496,352,NOSYS
DIALOG ADD,STYLE,STYLE2,,6,,WHITE,FOREGROUND
DIALOG ADD,STYLE,STYLE1,,8,B,WHITE,FOREGROUND
DIALOG ADD,GROUP,GROUP1,302,2,493,2

DIALOG ADD,BUTTON,BUTTON1,316,407,75,24,Annuler
DIALOG ADD,BUTTON,SUIVANT2,316,321,75,24,Suivant >
DIALOG ADD,BUTTON,PRECEDENT1,316,247,75,24,< Prcedent
DIALOG ADD,BITMAP,BITMAP1,0,0,166,302,serial.bmp
DIALOG ADD,TEXT,TEXT1,42,171,,,Veuillez entrer le num ro de srie se trouvant sur votre vieux bout de
DIALOG ADD,TEXT,TEXT3,55,171,,,papier chifonn . Cliquez sur suivant pour continuer.
DIALOG ADD,EDIT,EDIT1,86,169,34,20
DIALOG ADD,EDIT,EDIT3,86,286,52,20
DIALOG ADD,EDIT,EDIT2,86,219,50,20
DIALOG ADD,EDIT,EDIT4,86,354,36,20
DIALOG ADD,TEXT,TEXT4,84,208,,,_
DIALOG ADD,TEXT,TEXT5,84,274,,,_
DIALOG ADD,TEXT,TEXT6,84,343,,,_
dialog show
goto evloop2

:PRECEDENT1BUTTON
dialog hide
goto ininstall2
:SUIVANT2BUTTON
%%edit1 = @dlgtext(EDIT1)
%%edit2 = @dlgtext(EDIT2)
%%edit3 = @dlgtext(EDIT3)
%%edit4 = @dlgtext(EDIT4)
if @equal(1245-198471-1548748-1257,%%edit1-%%edit2-%%edit3-%%edit4)
goto installation
exit
else
%%serial = @msgbox(Le numro de s rie n'est pas valide.,NUMERO DE SERIE NON VALIDE,$010)
goto evloop2
exit


:installation
DIALOG SELECT,4
DIALOG HIDE
DIALOG SELECT,1
DIALOG HIDE
:re-install
DIALOG CREATE,Installshield,-1,0,488,351
DIALOG ADD,STYLE,STYLE1,,6,,WHITE,FOREGROUND
DIALOG ADD,STYLE,STYLE322,,8,B,WHITE,FOREGROUND
DIALOG ADD,BITMAP,BITMAP1,0,0,500,62,install.bmp
DIALOG ADD,TEXT,TEXT1,10,24,,,Slection du dossier cible,STYLE322
DIALOG ADD,TEXT,TEXT223,28,51,,,Veuillez choisir le dossier de destination,STYLE1
DIALOG ADD,EDIT,EDIT1,86,22,180,19
DIALOG ADD,BUTTON,BUTTON12,86,217,64,20,Parcourir ....
DIALOG ADD,BUTTON,BUTTON23,320,323,72,24,Installer
DIALOG ADD,BUTTON,BUTTON51,106,217,84,20,Crer r pertoire
DIALOG ADD,BUTTON,BUTTON34,320,249,74,24,<< Prcedent
DIALOG ADD,BUTTON,BUTTON1,320,417,64,24,Annuler

dialog show
goto evloop2
:button34button
dialog hide
goto suivant1button

:button51button
title Installshield Wizard
if @ask(Voulez-Vous Cr er un nouveau Rpertoire ?)
%%dir1 = @input(Destination :,C:\Windows\Bureau\ControlPC)
%%dir = @shortname(%%dir1)
DIALOG SET,EDIT1,%%DIR1
goto evloop2
exit
else
goto evloop2
end
end
:button12button
%%dir1 = @dirdlg(Veuillez choisir un dossier d'installation :,C:\)
%%dir = @shortname(%%dir1)
DIALOG SET,EDIT1,%%dir1
goto evloop2
:BUTTON23BUTTON
DIALOG HIDE
:dialog2
DIALOG CREATE,InstallShield Wizard,-1,0,496,352
DIALOG ADD,STYLE,STYLE1,,6,B,WHITE,FOREGROUND
DIALOG ADD,GROUP,GROUP1,302,62,433,2
DIALOG ADD,TEXT,TEXT1,294,1,,,InstallShield
DIALOG ADD,TEXT,TEXT2,70,19,,,ControlPC version 1.1 est en train d' ffectuer les oprations suivantes.
DIALOG ADD,BITMAP,BITMAP1,0,0,496,60,install.bmp
DIALOG ADD,GROUP,GROUP2,62,0,494,2
DIALOG ADD,TEXT,TEXT3,124,19,,,Installation :
DIALOG ADD,TEXT,TEXT4,145,19,500,13,Copie en cours ...
DIALOG ADD,PROGRESS,PROGRESS30,172,20,448,22
DIALOG ADD,BUTTON,BUTTON1,318,407,75,24,Annuler
DIALOG ADD,TEXT,TEXT5,4,10,,,Status de l'installation,STYLE1

dialog show
DIALOG DISABLE,TEXT1
:TIMER2
%D = @sum(%D,20)
dialog set,PROGRESS30,%D
wait "1"

DIALOG SET,TEXT4,Copie en cours : %%dir1\ControlPC.exe
file copy,@curdir()\DATA\controlPC.exe,%%dir\controlPC.exe,SHOWERRORS
%%OO = @sum(%%OO,50)
dialog set,PROGRESS30,%%OO
wait "1"

%%LL = @sum(%%LL,70)
dialog set,PROGRESS30,%%LL
DIALOG SET,TEXT4,Copie en cours : %%dir1\vdsrun30.dll
file copy,@curdir()\DATA\vdsrun30.dll,%%dir\vdsrun30.dll,SHOWERRORS
wait "1"
%%DF = @sum(%%DF,80)
dialog set,PROGRESS30,%%DF
DIALOG SET,TEXT4,Copie en cours : C:\Windows\System32\vdsrun30.dll
file copy,@curdir()\DATA\vdsrun30.dll,c:\Windows\system32\vdsrun30.dll,SHOWERRORS
wait "1"
%%IL = @sum(%%IL,100)
dialog set,PROGRESS30,%%IL
DIALOG SET,TEXT4,Copie en cours : %%dir1\sledge.dll
file copy,@curdir()\data\sledge.dll,%%dir\sledge.dll,SHOWERRORS
wait "1"
DIALOG HIDE
DIALOG CREATE,Installshield Wizard,-1,0,496,352
DIALOG ADD,STYLE,STYLE100,,6,,WHITE,FOREGROUND
DIALOG ADD,STYLE,STYLE50,,6,B,WHITE,FOREGROUND
DIALOG ADD,BITMAP,BITMAP1,-1,0,500,306,fin.bmp
DIALOG ADD,BUTTON,BUTTON35,318,249,74,24,< Prcedent
DIALOG ADD,BUTTON,BUTTON25,318,322,74,24,Fin
DIALOG ADD,BUTTON,BUTTON36,317,408,74,24,Annuler
DIALOG ADD,TEXT,TEXT1,21,175,,,InstallShield Wizard Complete,STYLE50
DIALOG ADD,TEXT,TEXT2,61,172,,,Install a fini d'installer ControlPC version 1.1",",Style100
DIALOG ADD,TEXT,TEXT3,74,172,,,sur de votre ordinateur.,Style100
dialog show
DIALOG DISABLE,BUTTON36
DIALOG DISABLE,BUTTON35
goto evloop2

:yikes !
TITLE Installshield
INFO Erreur @ERROR(E) ligne @ERROR(N)@cr()@cr()N'oubliez pas de NOTER !!!!!
Warn Une erreur vient de se produire@cr()Vu la fort progr s du logiciel il faut le dboguer au fur et   mesure donc nous attribuons la possibilit de reporter une de ses commandes   la console@cr()@cr()-JUMP vers Ecran 1 = @cr()ecran1@cr()-JUMP vers Ecran 2 =@cr()ecran2@cr()-Jump vers Ecran 3=@cr()ecran3@cr()-Jump vers Exit@cr()exit@cr()@cr()En cas de bug mme sous l'effet de d boguage annuler les oprations !.
%%ecran = @input(Quel  cran ?,ecran1","2 ou 3)
if @equal(%%ecran,ecran1)
goto ininstall2
else
if @equal(%%ecran,ecran2)
goto suivant1button
else
if @equal(%%ecran,ecran3)
goto re-install
else
if @equal(%%ecran,exit)
exit
else
WARN Erreur de commande ! :@cr()il faut tapez o ecran1 ecran2 ecran3 ou exit
goto yikes !
end
end
end

_________________
-----------------------------------

Eric11
Back to top
View user's profile Send private message Send e-mail MSN Messenger
Display posts from previous:   
Post new topic   Reply to topic    forum.vdsworld.com Forum Index -> Visual DialogScript Open Source Projects All times are GMT
Goto page Previous  1, 2, 3, 4  Next
Page 2 of 4

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You can attach files in this forum
You can download files in this forum




Twitter@vdsworld       RSS

Powered by phpBB © 2001, 2005 phpBB Group