forum.vdsworld.com Forum Index forum.vdsworld.com
Visit VDSWORLD.com
 
 FAQFAQ   SearchSearch   MemberlistMemberlist   UsergroupsUsergroups   RegisterRegister 
 ProfileProfile   Log in to check your private messagesLog in to check your private messages   Log inLog in 


[Open Source]: ProSetup Installer
Goto page Previous  1, 2, 3, 4  Next
 
Post new topic   Reply to topic    forum.vdsworld.com Forum Index -> Visual DialogScript Open Source Projects
View previous topic :: View next topic  
Author Message
Dr. Dread
Professional Member
Professional Member


Joined: 03 Aug 2001
Posts: 1065
Location: Copenhagen, Denmark

PostPosted: Sun Sep 22, 2002 6:11 pm    Post subject: Reply with quote

Right. Here is a piece of code for a SFX creator using Info-Zip's zip.exe plus the SFX stub from Tommy's EasyPackets.

Yup, it's a bit rough, but I'll elaborate on it. So far it does not allow to specify different extraction directories for individual files - VDS
really misses a better list element here. If anyone has a great idea for setting and showing properties for individual files in a list, then
let me know.

Greetz
Dread

PS: To test it you'll need zip.exe from here: http://www.info-zip.org/Zip.html#Win32
and the unpack.exe sfx stub from Tommy's Easy Packets - here: http://www.vdsworld.com/index.php?page=download&fileid=141


Code:

  title Resource compiler

  dialog CREATE,SFX-Creator   .. by Dr. Dread,-1,0,594,318,SAVEPOS,DRAGDROP
  dialog ADD,TEXT,T1,7,10,,,Output EXE file name:
  dialog ADD,EDIT,Outfile,5,150,150,
  dialog ADD,TEXT,T2,36,10,,,Files:
  dialog ADD,TEXT,T3,36,270,,,(drag&&drop files here)   (doubleclick file to set as README)
  dialog ADD,LIST,LB,55,10,566,160,DBLCLICK
  dialog ADD,COMBO,xdir,245,390,125,,"<temp>\<rand1>
  dialog ADD,TEXT,T6,230,390,,,Extraction directory:
  dialog ADD,BUTTON,Reprieve,228,10,100,,Remove from list
  dialog ADD,BUTTON,Compile,228,150,100,,Compile now
  dialog ADD,BUTTON,Quit,228,300,,,Close
  dialog ADD,STATUS,SP
  dialog ADD,TEXT,T4,270,10,,,Status:
  dialog ADD,PROGRESS,PROGRESS1,268,50,267,18,0
  dialog ADD,TEXT,T5,270,320,,,100%
  option DECIMALSEP,.
  %h = @sendmsg(@winexists(~LB),1045,1000,0)
  %%readme = ""
  dialog SHOW
  list loadtext,xdir
"<desktop>
"<doc>
"<fav>
"<font>
"<pic>
"<prog>
"<progfiles>
"<rand0>
"<sendto>
"<start>
"<startup>
"<sys>
"<temp>
"<win>

:evloop
  wait event
  goto @event()

:dragdrop
  list DROPFILES,LB
  dialog set,SP,@count(LB) files in project
  goto evloop

:ReprieveBUTTON
  dialog CLEARSEL,LB
  dialog set,SP,@count(LB) files in project
  goto evloop

:LBdblclick
 %%readme = @item(LB)
 info %%readme@CR()has been set as README file. It will be automatically opened upon extraction.
 goto evloop

:CompileBUTTON
  %%xdir = @dlgtext(xdir)
  %%resfile = @dlgtext(Outfile)
  %%errors = no
  if @null(%%resfile)
    warn "Enter EXE file name"
   dialog focus,Outfile
    goto evloop
  end
  if @not(@null(@ext(%%resfile)))
    warn "No file extension on the output file, please!"
    goto evloop
  end
  %a = @count(LB)
  if @equal(%a,0)
    warn "No files have been added!"
    goto evloop
  end
  %b = @div(100,%A)
  %i = 0
  list seek,LB,0
  list create,9
  if @null(%%readme)
    list add,9,""
  else
    list add,9,%%xdir\@NAME(%%readme).@EXT(%%readme)
  end
  list add,9,""
  repeat
    %f = @next(LB)
    if @not(@null(%F))
      runh zip.exe -u -j -9 tempfile.zip @CHR(34)%F@chr(34),WAIT
      wait 0.1
      rem %%app = @IO(APPND,%%resfile,%F)
      gosub logger
      rem list delete,LB
      %i = @fadd(%I,%B)
      dialog set,progress1,%I
    end
  until @null(%F)
  list savefile,9,settings.set
  list clear,9
  list add,9,COPY /B "unpack.exe+tempfile.zip" %%resfile.exe
  list savefile,9,append.bat
  list close,9
  runh zip.exe -u -j -9 tempfile.zip settings.set,WAIT
  dialog set,progress1,100
  dialog set,SP,Appending files ..
  runh append.bat,wait
  file delete,append.bat
  dialog cursor
  file delete,tempfile.zip
  runh zip.exe -A %%resfile.exe,wait
  dialog set,SP,Finished
  if @equal(%%errors,yes)
    warn Errors detected when zipping files. Please consult the file settings.set.
  end
  goto evloop

:QuitButton
:CLOSE
  exit

  rem ##### SUBS #####
:logger
  if @equal(@retcode(),0)
    list add,9,@NAME(%F).@EXT(%F)|%%xdir|
  else
    list add,9,@NAME(%F).@EXT(%F) - ERROR "(errorcode "@retcode()")"
    %%errors = yes
  end
  exit

_________________
~~ Alcohol and calculus don't mix... Don't drink and derive! ~~

String.DLL * advanced string processing
Back to top
View user's profile Send private message
FreezingFire
Admin Team


Joined: 23 Jun 2002
Posts: 3508

PostPosted: Sun Sep 22, 2002 6:29 pm    Post subject: Reply with quote

VERY nice, Dread! Very Happy

Your code can be inegrated into a full customization interface like V-Setup...

Nice piece of code...

_________________
FreezingFire
VDSWORLD.com
Site Admin Team
Back to top
View user's profile Send private message Visit poster's website
FreezingFire
Admin Team


Joined: 23 Jun 2002
Posts: 3508

PostPosted: Sun Sep 22, 2002 8:01 pm    Post subject: Reply with quote

Here's an updated version...the actual SFX code was written by Dr. Dread.

There's a few things that I couldn't figure out, for example, I don't know where the resulting EXE went, and the DIALOG CLOSE,#TPSCompilerWin didn't seem to take effect. Confused Hopefully, it can be improved on even more from here. Smile

Code:
title Resource compiler
  OPTION DECIMALSEP,"."
  DIALOG CREATE,ProSetup Compressor,-1,0,594,371,,DRAGDROP
  DIALOG ADD,TEXT,T1,294,10,82,13,Output file name:
  DIALOG ADD,EDIT,Outfile,308,10,544,22,,,READONLY
  DIALOG ADD,LIST,LB,66,10,574,160,,DBLCLICK
  DIALOG ADD,COMBO,xdir,252,10,574,21,<temp>\<rand1>
  DIALOG ADD,TEXT,T6,238,10,140,13,Extract files to this directory:
  DIALOG ADD,STATUS,SP
  %h = @sendmsg(@winexists(~LB),1045,1000,0)
  %%readme = ""
  DIALOG ADD,MENU,File
  DIALOG ADD,MENU,Build
  DIALOG ADD,MENU,Help
  DIALOG ADD,GROUP,Toolbar,0,1,594,40
  DIALOG ADD,BITBTN,New,4,5,32,32,prosetupc.dsr|6252,
  DIALOG ADD,BITBTN,Add,4,39,32,32,prosetupc.dsr|0,
  DIALOG ADD,BITBTN,Reprieve,4,73,32,32,prosetupc.dsr|7963,
  DIALOG ADD,BITBTN,Compile,4,107,32,32,prosetupc.dsr|3334,
  DIALOG ADD,BITBTN,Help,4,141,32,32,prosetupc.dsr|4829,
  DIALOG ADD,BITBTN,Browse,308,560,26,23,prosetupc.dsr|991,
  DIALOG ADD,TEXT,TFILE,50,11,,,Files to be extracted:
  DIALOG SHOW
  list loadtext,xdir
"<desktop>
"<doc>
"<fav>
"<font>
"<pic>
"<prog>
"<progfiles>
"<rand0>
"<sendto>
"<start>
"<startup>
"<sys>
"<temp>
"<win>

:evloop
if @greater(@count(LB),0)
if @dlgtext(outfile)
dialog enable,compile
end
else
dialog disable,compile
end
  dialog set,SP,@count(LB) files selected
  wait event
  goto @event()

:dragdrop
  list DROPFILES,LB
  goto evloop
 
:newBUTTON
  if @ask(Clear all entered data?)
  dialog clear,outfile
  dialog clear,LB
  dialog set,xdir,<temp>\<rand1>
  end
  goto evloop

:helpBUTTON
  %%helpmsg = @msgbox("1) Drag and Drop files or use the plus sign in the toolbar to add a file."@cr()"2) Select Extraction Directory"@cr()"3) Select destination executable file"@cr()"4) Compile",Help,$000)
  goto evloop

:addBUTTON
  %%addfile = @filedlg(,,,SAVE)
  if @ok()
  list add,LB,%%addfile
  end
  goto evloop

:browseBUTTON
  %%outfileb = @filedlg("Executable Files (*.exe)"|*.exe,,,SAVE)
  if @ok()
  if @not(@file(%%outfileb))
  if @not(@ext(%%outfileb))
  %%outfileb = %%outfileb".exe"
  dialog set,outfile,%%outfileb
  goto evloop
  end
  end
  if @ask(The file you selected already exists. If you continue"," you may overwrite the file. Do you want to select this file?)
  if @not(@ext(%%outfileb))
  %%outfileb = %%outfile".exe"
  end
  dialog set,outfile,%%outfileb
  end
  end
  goto evloop
:ReprieveBUTTON
  dialog CLEARSEL,LB
  goto evloop

:LBdblclick
%%readme = @item(LB)
info %%readme@CR()has been set as README file. It will be automatically opened upon extraction.
goto evloop

:CompileBUTTON
  %%xdir = @dlgtext(xdir)
  %%resfile = @dlgtext(Outfile)
  %%errors = no
  if @null(%%resfile)
    warn "Enter EXE file name"
   dialog focus,Outfile
    goto evloop
  end
  if @not(@ext(%%resfile))
    warn "Please add an extension on to the output file"
    goto evloop
  end
  %a = @count(LB)
  if @equal(%a,0)
    warn "No files have been added!"
    goto evloop
  end
  %b = @div(100,%A)
  %i = 0
  list seek,LB,0
  list create,9
  if @null(%%readme)
    list add,9,""
  else
    list add,9,%%xdir\@NAME(%%readme).@EXT(%%readme)
  end
  list add,9,""
  DIALOG CREATE,ProSetup Compiler,-1,0,345,64,CLASS TPSCompilerWin
  DIALOG ADD,STYLE,Compiler,Courier New,8,,BLACK,LIME
  DIALOG ADD,PROGRESS,PROGRESS1,12,11,322,24,0
  DIALOG ADD,TEXT,TSTAT,42,11,322,13,"Compiling: 0%"
  DIALOG SHOW
  repeat
  dialog select,0
  directory change,@path(%0)
    %f = @next(LB)
    if @not(@null(%F))
      runh zip.exe -u -j -9 tempfile.zip @CHR(34)%F@chr(34),WAIT
      wait 0.1
      rem %%app = @IO(APPND,%%resfile,%F)
      gosub logger
      rem list delete,LB
      %i = @fadd(%I,%B)
     dialog select,1
      dialog set,progress1,%I
     dialog set,TSTAT,"Compiling: "%i"%"
     dialog select,0
    end
  until @null(%F)
  list savefile,9,settings.set
  list clear,9
  list add,9,COPY /B "unpack.exe+tempfile.zip" %%resfile
  list savefile,9,append.bat
  list close,9
  runh zip.exe -u -j -9 tempfile.zip settings.set,WAIT
  dialog select,1
  dialog set,progress1,100
  dialog select,0
  dialog set,SP,Appending files ..
  runh append.bat,wait
  file delete,append.bat
  dialog cursor
  file delete,tempfile.zip
  runh zip.exe -A %%resfile,wait
  dialog set,SP,Finished
  if @equal(%%errors,yes)
    warn Errors detected when zipping files. Please consult the file @chr(34)settings.set@chr(34).
  end
  dialog close,#TPSCompilerWin
  %x = @event()
  goto evloop

:QuitButton
:CLOSE
  exit

  rem ##### SUBS #####
:logger
  if @equal(@retcode(),0)
    list add,9,@NAME(%F).@EXT(%F)|%%xdir|
  else
    list add,9,@NAME(%F).@EXT(%F) - ERROR "(errorcode "@retcode()")"
    %%errors = yes
  end
  exit

_________________
FreezingFire
VDSWORLD.com
Site Admin Team
Back to top
View user's profile Send private message Visit poster's website
FreezingFire
Admin Team


Joined: 23 Jun 2002
Posts: 3508

PostPosted: Sun Sep 22, 2002 8:18 pm    Post subject: Reply with quote

The main installer is almost done and will be released soon. Smile
_________________
FreezingFire
VDSWORLD.com
Site Admin Team
Back to top
View user's profile Send private message Visit poster's website
Dr. Dread
Professional Member
Professional Member


Joined: 03 Aug 2001
Posts: 1065
Location: Copenhagen, Denmark

PostPosted: Sun Sep 22, 2002 10:57 pm    Post subject: Reply with quote

Hey FF!

Nice job there! Grabbed your code and went through it. A couple of things popped up, so I made a few corrections and now the EXE file
should be compiled OK.

Basically I only touched the CompileBUTTON section, I think.

Greetz
Dr. Dread

Code:

  title Resource compiler
  option DECIMALSEP,"."
  dialog CREATE,ProSetup Compressor,-1,0,594,371,,DRAGDROP
  dialog ADD,TEXT,T1,294,10,82,13,Output file name:
  dialog ADD,EDIT,Outfile,308,10,544,22,,,READONLY
  dialog ADD,LIST,LB,66,10,574,160,,DBLCLICK
  dialog ADD,COMBO,xdir,252,10,574,21,<temp>\<rand1>
  dialog ADD,TEXT,T6,238,10,140,13,Extract files to this directory:
  dialog ADD,STATUS,SP
  %h = @sendmsg(@winexists(~LB),1045,1000,0)
  %%readme = ""
  dialog ADD,MENU,File
  dialog ADD,MENU,Build
  dialog ADD,MENU,Help
  dialog ADD,GROUP,Toolbar,0,1,594,40
  dialog ADD,BITBTN,New,4,5,32,32,prosetupc.dsr|6252,
  dialog ADD,BITBTN,Add,4,39,32,32,prosetupc.dsr|0,
  dialog ADD,BITBTN,Reprieve,4,73,32,32,prosetupc.dsr|7963,
  dialog ADD,BITBTN,Compile,4,107,32,32,prosetupc.dsr|3334,
  dialog ADD,BITBTN,Help,4,141,32,32,prosetupc.dsr|4829,
  dialog ADD,BITBTN,Browse,308,560,26,23,prosetupc.dsr|991,
  dialog ADD,TEXT,TFILE,50,11,,,Files to be extracted:
  dialog SHOW
  list loadtext,xdir
"<desktop>
"<doc>
"<fav>
"<font>
"<pic>
"<prog>
"<progfiles>
"<rand0>
"<sendto>
"<start>
"<startup>
"<sys>
"<temp>
"<win>

:evloop
  if @greater(@count(LB),0)
    if @dlgtext(outfile)
      dialog enable,compile
    end
  else
    dialog disable,compile
  end
  dialog set,SP,@count(LB) files selected
  wait event
  goto @event()

:dragdrop
  list DROPFILES,LB
  goto evloop

:newBUTTON
  if @ask(Clear all entered data?)
    dialog clear,outfile
    dialog clear,LB
    dialog set,xdir,<temp>\<rand1>
  end
  goto evloop

:helpBUTTON
  %%helpmsg = @msgbox("1) Drag and Drop files or use the plus sign in the toolbar to add a file."@cr()"2) Select Extraction Directory"@cr()"3) Select destination executable file"@cr()"4) Compile",Help,$000)
  goto evloop

:addBUTTON
  %%addfile = @filedlg(,,,SAVE)
  if @ok()
    list add,LB,%%addfile
  end
  goto evloop

:browseBUTTON
  %%outfileb = @filedlg("Executable Files (*.exe)"|*.exe,,,SAVE)
  if @ok()
    if @not(@file(%%outfileb))
      if @not(@ext(%%outfileb))
        %%outfileb = %%outfileb".exe"
        dialog set,outfile,%%outfileb
        goto evloop
      end
    end
    if @ask("The file you selected already exists. If you continue, you may overwrite the file. Do you want to select this file?")
      if @not(@ext(%%outfileb))
        %%outfileb = %%outfile".exe"
      end
      dialog set,outfile,%%outfileb
    end
  end
  goto evloop
:ReprieveBUTTON
  dialog CLEARSEL,LB
  goto evloop

:LBdblclick
 %%readme = @item(LB)
 info %%readme@CR()has been set as README file. It will be automatically opened upon extraction.
 goto evloop

:CompileBUTTON
  %%xdir = @dlgtext(xdir)
  rem  %%resfile = @dlgtext(Outfile)
  %%resfile = @NAME(%%outfileb).@EXT(%%outfileb)
  %%errors = no
  %a = @count(LB)
  %b = @div(100,%A)
  %i = 0
  list seek,LB,0
  list create,9
  if @null(%%readme)
    list add,9,""
  else
    list add,9,%%xdir\@NAME(%%readme).@EXT(%%readme)
  end
  list add,9,""
  dialog CREATE,ProSetup Compiler,-1,0,345,64,CLASS TPSCompilerWin
  dialog ADD,STYLE,Compiler,Courier New,8,,BLACK,LIME
  dialog ADD,PROGRESS,PROGRESS1,12,11,322,24,0
  dialog ADD,TEXT,TSTAT,42,11,322,13,"Compiling: 0%"
  dialog SHOW
  repeat
    dialog select,0
    directory change,@path(%0)
    %F = @next(LB)
    if @not(@null(%F))
      runh zip.exe -u -j -9 tempfile.zip @CHR(34)%F@chr(34),WAIT
      wait 0.1
      gosub logger
      %i = @fadd(%I,%B)
      dialog select,1
      dialog set,progress1,%I
      dialog set,TSTAT,"Compiling: "%i"%"
      dialog select,0
    end
  until @null(%F)
  list savefile,9,settings.set
  list clear,9
  list add,9,COPY /B unpack.exe+tempfile.zip @NAME(%%resfile).@EXT(%%resfile)
  list savefile,9,@path(%0)append.bat
  list close,9
  runh zip.exe -u -j -9 tempfile.zip settings.set,WAIT
  dialog select,1
  dialog set,progress1,100
  dialog set,TSTAT,"Compiling: 100%"
  dialog select,0
  dialog set,SP,Appending files ..
  runh append.bat,wait
  file delete,append.bat
  WAIT
  dialog cursor
  file delete,tempfile.zip
  runh zip.exe -A %%resfile,wait
  dialog set,SP,Finished
  if @equal(%%errors,yes)
    warn Errors detected when zipping files. Please consult the file @chr(34)settings.set@chr(34).
  end
  dialog select,1
  dialog close
  %x = @event()
  goto evloop

:QuitButton
:CLOSE
  exit

  rem ##### SUBS #####
:logger
  if @equal(@retcode(),0)
    list add,9,@NAME(%F).@EXT(%F)|%%xdir|
  else
    list add,9,@NAME(%F).@EXT(%F) - ERROR "(errorcode "@retcode()")"
    %%errors = yes
  end
  exit

_________________
~~ Alcohol and calculus don't mix... Don't drink and derive! ~~

String.DLL * advanced string processing


Last edited by Dr. Dread on Mon Sep 23, 2002 8:06 am; edited 1 time in total
Back to top
View user's profile Send private message
Dr. Dread
Professional Member
Professional Member


Joined: 03 Aug 2001
Posts: 1065
Location: Copenhagen, Denmark

PostPosted: Mon Sep 23, 2002 9:54 pm    Post subject: Reply with quote

Expansion. This code now features the possibility of setting individual extract dirs. Done with a set of list boxes which are manipulated
to stay in sync emulating a column mode list box (VDS should really have that!).

Greetz
Dr. Dread

Code:
  title Resource compiler
  option DECIMALSEP,"."
  dialog CREATE,ProSetup Compressor,-1,0,694,371,,DRAGDROP
  dialog ADD,TEXT,T1,294,10,82,13,Output file name:
  dialog ADD,EDIT,Outfile,308,10,544,22,,,READONLY
  dialog ADD,LIST,LB,66,10,524,160,,DBLCLICK,CLICK
  dialog ADD,LIST,LB2,66,534,150,160,,DBLCLICK,CLICK
  dialog ADD,COMBO,xdir,252,10,574,21,<temp>\<rand1>
  dialog ADD,TEXT,T2,238,10,140,13,Extract files to this directory:
  dialog ADD,STATUS,SP
  dialog ADD,MENU,File,Exit
  dialog ADD,MENU,Build
  dialog ADD,MENU,Help,Help
  dialog ADD,GROUP,Toolbar,0,1,500,40
  dialog ADD,BITBTN,New,4,5,32,32,prosetupc.dsr|6252,
  dialog ADD,BITBTN,Add,4,39,32,32,prosetupc.dsr|0,
  dialog ADD,BITBTN,Reprieve,4,73,32,32,prosetupc.dsr|7963,
  dialog ADD,BITBTN,Compile,4,107,32,32,prosetupc.dsr|3334,
  dialog ADD,BITBTN,Help,4,141,32,32,prosetupc.dsr|4829,
  dialog ADD,BITBTN,Browse,308,560,26,23,prosetupc.dsr|991,
  dialog ADD,TEXT,T3,50,11,,,"Files to be extracted:     (double-click to set as project README file)"
  dialog ADD,TEXT,T4,35,536,,,Extraction directory:@CR()(double-click to edit)
  dialog SHOW
  list loadtext,xdir
"<desktop>
"<doc>
"<fav>
"<font>
"<pic>
"<prog>
"<progfiles>
"<rand0>
"<sendto>
"<start>
"<startup>
"<sys>
"<temp>
"<win>
  %%readme = ""
  %h = @sendmsg(@winexists(~LB),1045,1000,0)

:evloop
  if @greater(@count(LB),0)
    if @dlgtext(outfile)
      dialog enable,compile
    end
  else
    dialog disable,compile
  end
  dialog set,SP,@count(LB) files selected
  wait event
  goto @event()

:dragdrop
  list DROPFILES,LB
  %%countLB = @count(LB)
  %%diff = @diff(@count(LB),@count(LB2))
  %%inc = 0
  repeat
  list add,LB2,@dlgtext(xdir)
  %%inc = @succ(%%inc)
  until @equal(%%diff,%%inc)
  goto evloop

:newBUTTON
  if @ask(Clear all entered data?)
    dialog clear,outfile
    dialog clear,LB
    dialog set,xdir,<temp>\<rand1>
  end
  goto evloop

:HelpMENU
:helpBUTTON
  %%helpmsg = @msgbox("1) Drag&drop files or use the plus sign in the toolbar to add a file."@cr()"2) Select Extraction Directory. You may choose a value from the list or type your own, e.g. <progfiles>\MyProgram"@cr()"3) Select destination executable file"@cr()"4) Compile",Help,$000)
  goto evloop

:addBUTTON
  %%addfile = @filedlg(,,,SAVE)
  if @ok()
    list add,LB,%%addfile
  end
  goto evloop

:browseBUTTON
  %%outfileb = @filedlg("Executable Files (*.exe)"|*.exe,,,SAVE)
  if @ok()
    if @not(@file(%%outfileb))
      if @not(@ext(%%outfileb))
        %%outfileb = %%outfileb".exe"
        dialog set,outfile,%%outfileb
        goto evloop
      end
    end
    if @ask("The file you selected already exists. If you continue, you may overwrite the file. Do you want to select this file?")
      if @not(@ext(%%outfileb))
        %%outfileb = %%outfile".exe"
      end
      dialog set,outfile,%%outfileb
    end
  end
  goto evloop
:ReprieveBUTTON
  dialog CLEARSEL,LB
  goto evloop

:LBdblclick
 %%readme = @item(LB)
 info %%readme@CR()has been set as README file. It will be automatically opened upon extraction.
 goto evloop

:LBclick
 %%dummy = @sendmsg(@win(~LB),$018E,0,0)
 %%dummy = @sendmsg(@win(~LB2),$0197,%%dummy,0)
 %%indexLB = @index(LB)
 list seek,LB2,%%indexLB
 goto evloop

:LB2dblclick
 %%dummy = @sendmsg(@win(~LB2),$018E,0,0)
 %%dummy = @sendmsg(@win(~LB),$0197,%%dummy,0)
 %%indexLB2 = @index(LB2)
 %%valueLB2 = @item(LB2)
  dialog CREATE,Set extraction directory,-1,0,345,340,NOSYS
  dialog ADD,TEXT,TT1,50,10,300,,<desktop>: User's desktop directory
  dialog ADD,TEXT,TT2,65,10,300,,<doc>: User's My Documents directory
  dialog ADD,TEXT,TT3,80,10,300,,<fav>: The Favorites menu
  dialog ADD,TEXT,TT4,95,10,300,,<font>: The Fonts directory
  dialog ADD,TEXT,TT5,110,10,300,,<pic>: User's My Pictures directory
  dialog ADD,TEXT,TT6,125,10,300,,<prog>: The Programs folder in the Start menu
  dialog ADD,TEXT,TT7,140,10,300,,<progfiles>: User's Program Files directory
  dialog ADD,TEXT,TT8,155,10,300,,<rand0>: A new directory named with a random number. You may use <rand0> .. <rand9> to generate directories.
  dialog ADD,TEXT,TT9,170,10,300,,<sendto>: The Sendto menu
  dialog ADD,TEXT,TT10,185,10,300,,<start>: The Start menu on the user's computer
  dialog ADD,TEXT,TT11,200,10,300,,<startup>: The Startup folder in the Start menu on the user's computer. Program shortcuts placed here are auto-run at start-up
  dialog ADD,TEXT,TT12,215,10,300,,<sys>: The Windows System directory
  dialog ADD,TEXT,TT13,230,10,300,,<temp>: The Windows Temp directory
  dialog ADD,TEXT,TT14,245,10,300,,<win>: The Windows directory itself
  dialog ADD,COMBO,xdir2,25,10,335,21,%%valueLB2
  dialog ADD,BUTTON,okay,280,150,50,,OK
  list loadtext,xdir2
"<desktop>
"<doc>
"<fav>
"<font>
"<pic>
"<prog>
"<progfiles>
"<rand0>
"<sendto>
"<start>
"<startup>
"<sys>
"<temp>
"<win>
  dialog SHOWMODAL
rem  wait event
rem  dialog select,1
  %%newexdir = @dlgtext(xdir2)
  dialog select,1
  dialog close
 list put,LB2,%%newexdir
 %%dummy = @sendmsg(@win(~LB2),$0186,%%indexLB2,0)
 goto evloop

:okayBUTTON
 goto evloop 

:LB2click
 %%dummy = @sendmsg(@win(~LB2),$018E,0,0)
 %%dummy = @sendmsg(@win(~LB),$0197,%%dummy,0)
 %%indexLB2 = @index(LB2)
 list seek,LB,%%indexLB2
 goto evloop

:CompileBUTTON
  %%xdir = @dlgtext(xdir)
  rem  %%resfile = @dlgtext(Outfile)
  %%resfile = @NAME(%%outfileb).@EXT(%%outfileb)
  %%errors = no
  %a = @count(LB)
  %b = @div(100,%A)
  %i = 0
  list seek,LB,0
  list create,9
  if @null(%%readme)
    list add,9,""
  else
    list add,9,%%xdir\@NAME(%%readme).@EXT(%%readme)
  end
  list add,9,""
  dialog CREATE,ProSetup Compiler,-1,0,345,64,CLASS TPSCompilerWin
  dialog ADD,STYLE,Compiler,Courier New,8,,BLACK,LIME
  dialog ADD,PROGRESS,PROGRESS1,12,11,322,24,0
  dialog ADD,TEXT,TSTAT,42,11,322,13,"Compiling: 0%"
  dialog SHOW
  %%inc2 = 0
  directory change,@path(%0)
  repeat
    dialog select,0
    %F = @item(LB,%%inc2)
   %%F2 = @item(LB2,%%inc2)
    if @not(@null(%F))
      runh zip.exe -u -j -9 tempfile.zip @CHR(34)%F@chr(34),WAIT
      wait 0.1
      gosub logger
      %i = @fadd(%I,%B)
      dialog select,1
      dialog set,progress1,%I
      dialog set,TSTAT,"Compiling: "%i"%"
      dialog select,0
    end
   %%inc2 = @succ(%%inc2)
  until @equal(%%inc2,@count(LB))
  list savefile,9,settings.set
  list clear,9
  list add,9,COPY /B unpack.exe+tempfile.zip @NAME(%%resfile).@EXT(%%resfile)
  list savefile,9,@path(%0)append.bat
  list close,9
  runh zip.exe -u -j -9 tempfile.zip settings.set,WAIT
  dialog select,1
  dialog set,progress1,100
  dialog set,TSTAT,"Compiling: 100%"
  dialog select,0
  dialog set,SP,Appending files ..
  runh append.bat,wait
  file delete,append.bat
  WAIT
  dialog cursor
  file delete,tempfile.zip
  runh zip.exe -A %%resfile,wait
  dialog set,SP,Finished
  if @equal(%%errors,yes)
    warn Errors detected when zipping files. Please consult the file @chr(34)settings.set@chr(34).
  end
  dialog select,1
  dialog close
  %x = @event()
  goto evloop

:ExitMENU
:QuitButton
:CLOSE
  exit

  rem ##### SUBS #####
:logger
  if @equal(@retcode(),0)
    list add,9,@NAME(%F).@EXT(%F)|%%F2|
  else
    list add,9,@NAME(%F).@EXT(%F) - ERROR "(errorcode "@retcode()")"
    %%errors = yes
  end
  exit

_________________
~~ Alcohol and calculus don't mix... Don't drink and derive! ~~

String.DLL * advanced string processing
Back to top
View user's profile Send private message
FreezingFire
Admin Team


Joined: 23 Jun 2002
Posts: 3508

PostPosted: Sun Dec 08, 2002 5:51 pm    Post subject: Reply with quote

__________________________________________________________________________________________________________________________
Here is an updated version to the setup wizard. Still not complete, but it's
almost there. I can't figure out how to copy the files and folders extracted
to the temporary directory to where the user specified.

Remember to save the file to your computer or REM out the "DIRECTORY
CHANGE" line before running, otherwise you will get an error.

Code:
Title Setup
DIRECTORY CHANGE,@PATH(%0)
OPTION ERRORTRAP,ERROR
OPTION DECIMALSEP,"."
%%appname = Test
rem == License Agreement Text Below ==
list create,1
list loadtext,1
"Thank you for trying Test Application!
"
"Before using Test Application, please read the following:
"  Test Application is free. You don't have to pay anything for it.
"  Test Application doesn't exist. You can't run it because you don't have the files.
"  There may be errors in this setup program. If you find one, post it at VDSWORLD.
"
"Thank you.
%%licensetext = @text(1)
list close,1
rem == End License ==
%%ProgramFiles = @REGREAD(LOCAL,SOFTWARE\Microsoft\Windows\CurrentVersion,ProgramFilesDir)
  DIALOG CREATE,Setup - %%appname,-1,0,493,356
  DIALOG ADD,STYLE,Heading,MS Sans Serif,12,B,,
  DIALOG ADD,STYLE,BOLD,,,B,,
  DIALOG ADD,STYLE,WHITE-WHITE,,,,WHITE,WHITE
  DIALOG ADD,GROUP,sep1,313,0,494,2
  DIALOG ADD,BUTTON,Back,324,246,74,24,< Back
  DIALOG ADD,BUTTON,Next,324,322,74,24,Next >
  DIALOG ADD,BUTTON,Cancel,324,408,74,24,Cancel
  DIALOG SHOW
  %%previouspage =
  %%newpage = 1
  gosub show
:Evloop
  wait event
  goto @event()
:BackBUTTON
  %%newpage = @pred(%%newpage)
  gosub show
  goto evloop
:NextBUTTON
  %%newpage = @succ(%%newpage)
  gosub show
  goto evloop
:show
  if %%previouspage
    gosub hide%%previouspage
  end
  %%previouspage = %%newpage
  gosub show%%newpage
  exit
:show1
  DIALOG ADD,BITMAP,BITMAP_LARGE,0,0,0,0,WizModernImage.bmp
  DIALOG ADD,TEXT,FLOODFILL,0,164,330,314,,,WHITE-WHITE
  DIALOG ADD,TEXT,TWelcome,20,175,318,42,Welcome to the %%appname Setup Wizard,,Heading,TRANSPARENT
  DIALOG ADD,TEXT,TM1,70,175,320,13,This will install %%appname on your computer.,,TRANSPARENT
  DIALOG ADD,TEXT,TM2,90,175,318,13,It is strongly recommended that you close all other applications,,TRANSPARENT
  DIALOG ADD,TEXT,TM3,103,175,292,13,you have running before continuing. This will help prevent any,,TRANSPARENT
  DIALOG ADD,TEXT,TM4,116,175,184,13,conflicts during the installation process.,,TRANSPARENT
  DIALOG ADD,TEXT,TM5,152,175,318,13,Click Next to continue"," or Cancel to exit Setup.,,TRANSPARENT
  dialog hide,Back
  exit
:hide1
  dialog remove,BITMAP_LARGE
  dialog remove,FLOODFILL
  dialog remove,TWelcome
  dialog remove,TM1
  dialog remove,TM2
  dialog remove,TM3
  dialog remove,TM4
  dialog remove,TM5
  dialog show,Back
  exit
:show2
  DIALOG SET,NEXT,Yes
  DIALOG SET,CANCEL,No
  DIALOG ADD,TEXT,FLOODFILL2,0,0,494,60,,,WHITE-WHITE
  DIALOG ADD,TEXT,WizHeader,14,24,356,13,License Agreement,,TRANSPARENT,BOLD
  DIALOG ADD,TEXT,WizSubHeader,30,40,344,13,Please read the following important information before continuing.,,TRANSPARENT
  DIALOG ADD,GROUP,sep2,60,0,494,2
  DIALOG ADD,BITMAP,BITMAP_SMALL,2,436,55,55,WizModernSmallImage.bmp
  DIALOG ADD,TEXT,LT1,80,40,405,13,Please read the following License Agreement. Use the scroll bar to view the rest of the
  DIALOG ADD,TEXT,LT2,92,40,53,13,agreement.
  DIALOG ADD,EDIT,ELICENSE,113,40,406,150,%%licensetext,,SCROLL,MULTI,WRAP,READONLY
  DIALOG ADD,TEXT,LT4,272,40,493,13,Do you accept the terms of the preceding License Agreement? If you choose No"," 
  DIALOG ADD,TEXT,LT5,286,40,493,13,Setup will close. To install %%appname"," you must accept this agreement.
  exit
:hide2
  DIALOG SET,NEXT,Next >
  DIALOG SET,CANCEL,Cancel
  dialog remove,FLOODFILL2
  dialog remove,WizHeader
  dialog remove,WizSubHeader
  dialog remove,sep2
  dialog remove,BITMAP_SMALL
  dialog remove,LT1
  dialog remove,LT2
  dialog remove,ELICENSE
  dialog remove,LT4
  dialog remove,LT5
  exit
  :show3
  DIALOG ADD,TEXT,PDT1,113,23,400,13,Install %%appname into the following folder:
  if %%browse1
  DIALOG ADD,EDIT,PDE1,129,23,446,22,%%browse1
  else
  DIALOG ADD,EDIT,PDE1,129,23,446,22,%%programfiles\%%appname
  end
  DIALOG ADD,BUTTON,PDB1,156,394,76,24,Browse...
  DIALOG ADD,TEXT,FLOODFILL2,0,0,494,60,,,WHITE-WHITE
  DIALOG ADD,TEXT,WizHeader,14,24,356,13,Choose Folder,,TRANSPARENT,BOLD
  DIALOG ADD,TEXT,WizSubHeader,30,40,394,13,Choose the folder in which to install %%appname.,,TRANSPARENT
  DIALOG ADD,BITMAP,BITMAP_SMALL,2,436,55,55,WizModernSmallImage.bmp
  DIALOG ADD,GROUP,sep2,60,0,494,2
  exit
  :hide3
  %%instpath = @dlgtext(PDE1)
  DIALOG REMOVE,FLOODFILL2
  DIALOG REMOVE,WIZHEADER
  DIALOG REMOVE,WIZSUBHEADER
  DIALOG REMOVE,BITMAP_SMALL
  DIALOG REMOVE,SEP2
  DIALOG REMOVE,PDT1
  DIALOG REMOVE,PDE1
  DIALOG REMOVE,PDB1
  exit
:show4
  %%StartMenu = @REGREAD(CURUSER,Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders,Start Menu)
  list create,4
  list filelist,4,%%startmenu,*D
  list create,5
  %%idx1 = 0
  repeat
  list add,5,@name(@item(4,%%idx1))
  %%idx1 = @succ(%%idx1)
  until @equal(@count(5),@count(4))
  list close,4
  DIALOG ADD,TEXT,FLOODFILL2,0,0,494,60,,,WHITE-WHITE
  DIALOG ADD,TEXT,WizHeader,14,24,356,13,Select Start Menu Folder,,TRANSPARENT,BOLD
  DIALOG ADD,TEXT,WizSubHeader,30,40,394,13,Where should Setup place the program's shortcuts?,,TRANSPARENT
  DIALOG ADD,BITMAP,BITMAP_SMALL,2,436,55,55,WizModernSmallImage.bmp
  DIALOG ADD,GROUP,sep2,60,0,494,2
  DIALOG ADD,TEXT,SMET1,76,34,446,13,Select the Start Menu folder in which you would like Setup to create the program's
  DIALOG ADD,LIST,SMEL1,134,36,418,144,,,CLICK
  DIALOG ADD,TEXT,SMET2,90,34,446,13,shortcus"," then click Next.
  DIALOG ADD,EDIT,SME1,110,36,418,20,%%appname
  DIALOG ADD,CHECK,SMFC1,286,36,180,18,Don't create a Start Menu folder,%%check1,,CLICK
  DIALOG SET,SMEL1,@text(5)
  list close,5
  exit
  :SMEL1CLICK
  DIALOG SET,SME1,@ITEM(SMEL1)
  GOTO EVLOOP
  :SMFC1CLICK
  IF @DLGTEXT(SMFC1)
  %%CHECK1 = 1
  ELSE
  %%CHECK1 = ""
  END 
  IF @DLGTEXT(SMFC1)
  DIALOG DISABLE,SMEL1
  DIALOG DISABLE,SME1
  ELSE
  DIALOG ENABLE,SMEL1
  DIALOG ENABLE,SME1
  END
  GOTO EVLOOP
 
 
  :hide4
  dialog remove,floodfill2
  dialog remove,wizheader
  dialog remove,wizsubheader
  dialog remove,sep2
  dialog remove,bitmap_small
  DIALOG REMOVE,SMET1
  DIALOG REMOVE,SMEL1
  DIALOG REMOVE,SMET2
  DIALOG REMOVE,SME1
  DIALOG REMOVE,SMFC1
  EXIT
 
 
:SHOW5
  DIALOG ADD,TEXT,FLOODFILL2,0,0,494,60,,,WHITE-WHITE
  DIALOG ADD,TEXT,WizHeader,14,24,356,13,Installing,,TRANSPARENT,BOLD
  DIALOG ADD,TEXT,WizSubHeader,30,40,394,13,Setup is currently installing %%appname,,TRANSPARENT
  DIALOG ADD,BITMAP,BITMAP_SMALL,2,436,55,55,WizModernSmallImage.bmp
  DIALOG ADD,GROUP,sep2,60,0,494,2
  DIALOG ADD,PROGRESS,instp,101,24,444,24,0
  GOSUB INSTALL
  EXIT
:HIDE5 
  DIALOG REMOVE,FLOODFILL2
  DIALOG REMOVE,WIZHEADER
  DIALOG REMOVE,WIZSUBHEADER
  DIALOG REMOVE,BITMAP_SMALL
  DIALOG REMOVE,SEP2
  DIALOG REMOVE,INSTP
  EXIT

:Install
list create,4
list filelist,4,@path(%0)TempInstDir-PS053\*,ADHRSV
if @text(4)
info @text(4)
exit
file copy,@text(4),%%instpath
dialog set,instp,100
else
%x = @event()
end
list close,4
  file delete,@path(%0)TempInstDir-PS053\*.*
  directory delete,@path(%0)TempInstDir-PS053
  exit
 
 
:PDB1BUTTON
  %%browse1 = @dirdlg(Choose Installation Folder:,@dlgtext(PDE1))
  if @ok()
  dialog set,PDE1,%%browse1
  end
  goto evloop
 
:ERROR
warn An error has occurred. Please restart the application and try again.
stop
:CancelBUTTON
:Close
if %%finish
exit
end
  if @equal(@msgbox(Setup is not complete.@cr()If you quit now"," %%appname will not be installed on your computer.@cr()You can run setup at a later time to complete the installation.@cr()Are you sure you want to exit setup?,Setup,$034),6)
    exit
  end
  goto evloop


Template for wizard pages:
Code:
rem Template for Wizard Pages
  DIALOG CREATE,Setup - %%appname,-1,0,493,356
  DIALOG ADD,STYLE,PST1,,,,WHITE,004993
  DIALOG ADD,STYLE,Heading,MS Sans Serif,12,B,,
  DIALOG ADD,STYLE,BOLD,,,B,,
  DIALOG ADD,STYLE,WHITE-WHITE,,,,WHITE,WHITE
  DIALOG ADD,GROUP,sep1,313,0,494,2
  DIALOG ADD,BUTTON,Cancel,324,408,74,24,Cancel
  DIALOG ADD,BUTTON,Next,324,322,74,24,Next >
  DIALOG ADD,BUTTON,Back,324,246,74,24,< Back
  DIALOG ADD,TEXT,FLOODFILL2,0,0,494,60,,,WHITE-WHITE
  DIALOG ADD,TEXT,WizHeader,14,24,356,13,Installing,,TRANSPARENT,BOLD
  DIALOG ADD,TEXT,WizSubHeader,30,40,394,13,Setup is currently installing %%appname,,TRANSPARENT
  DIALOG ADD,BITMAP,BITMAP_SMALL,2,436,55,55,WizModernSmallImage.bmp
  DIALOG ADD,GROUP,sep2,60,0,494,2
  DIALOG ADD,PROGRESS,instp,101,24,444,24,0
  DIALOG SHOW


Download the Wizard Images [here]

_________________
FreezingFire
VDSWORLD.com
Site Admin Team
Back to top
View user's profile Send private message Visit poster's website
Dr. Dread
Professional Member
Professional Member


Joined: 03 Aug 2001
Posts: 1065
Location: Copenhagen, Denmark

PostPosted: Mon Dec 09, 2002 7:43 am    Post subject: Reply with quote

Hey FF

I almost forgot about this little project Embarassed BTW, nice installer interface...

As to having files installed in the right places: If you use the code above to create an SFX
file with Tommy's stub, everything will be extracted to the Dirs (Win, Temp, WinSys,
Program Dir etc) specified, when the SFX is run. No problemo.

The things is then that users must be stepped through the install process to accept license
conditions and to obtain a path to the Program Dir etc. So perhaps everything must be
done in 2 steps:

1. Have an initial SFX with the install files (install wizard, VDS DLL, and another SFX containing
the real program files - this last one should perhaps be encrypted until it is time to run it). This
SFX could just extract to a temp Dir somewhere and start the install wizard.

2. When the user has stepped through everything and provided a Program Dir, then
create that directory, copy the 2nd SFX there, and run it to have the program files
extracted in their proper. Lastly create shortcuts and clean up by removing files
no longer needed.

Greetz
Dr. Dread

_________________
~~ Alcohol and calculus don't mix... Don't drink and derive! ~~

String.DLL * advanced string processing
Back to top
View user's profile Send private message
cnodnarb
Valued Contributor
Valued Contributor


Joined: 11 Sep 2002
Posts: 641
Location: Evansville, IN

PostPosted: Thu Dec 26, 2002 2:41 am    Post subject: Reply with quote

Here's my open source setup utility to pick at. PAY SPECIAL ATTENTION TO THE DDE COMMANDS as I haven't seen them posted in quite a while, and it's a pretty good method for making shortcuts.

Also contains a very simple solution for recursive copy of the temp directory to the install directory, but unable to make a progress bar using this method.

Uses a SFX to extract to @windir(T)NodSetup...full example of it in action
http://members.aol.com/cnodnarb/nodmimicsetup.exe

Code:

inifile open,@path(%0)setup.ini
%%count = 0
title Setup
  DIALOG CREATE,Setup,-1,0,@sysinfo(SCREENWIDTH),@sysinfo(SCREENHEIGHT),nosys,smallcap,class nodsetup
  rem DIALOG CREATE,Setup,-1,0,1024,800,nosys,smallcap,class nodsetup
  DIALOG ADD,STYLE,STYLE2,Times New Roman,36,I,DKRED,BLACK
  DIALOG ADD,STYLE,STYLE1,Times New Roman,36,I,DKRED,WHITE
  DIALOG ADD,bitmap,bitmap1,0,0
  DIALOG ADD,TEXT,TEXT1,0,0,1024,800,,,,STYLE1
  DIALOG ADD,TEXT,TEXT3,15,15,,,My Setup Program,Transparent,STYLE2
  dialog set,text3,@iniread(Main,Title)
  DIALOG ADD,TEXT,TEXT2,10,10,,,My Setup Program,Transparent,STYLE1
  dialog set,text2,@iniread(Main,Title)
  dialog set,bitmap1,@iniread(Main,Bitmap)
  DIALOG SHOW
window settext,#nodsetup,@iniread(Main,Caption)

  DIALOG CREATE,Welcome,-1,0,453,302,class nodwelcome
  dialog add,list,list2,0,0,0,0
  DIALOG ADD,BITMAP,BITMAP1,0,0,500,400
  dialog set,bitmap1,@iniread(Sub,Bitmap)
  DIALOG ADD,TEXT,TEXT1,6,142,308,56,TEXT1
  dialog set,text1,@iniread(Sub,Welcome)
  DIALOG ADD,TEXT,TEXT2,69,142,294,144,TEXT2
  DIALOG ADD,TEXT,TEXT3,219,142,312,100,TEXT3
  DIALOG ADD,GROUP,GROUP1,246,142,308,2 
  DIALOG ADD,BUTTON,BUTTON2,266,220,64,24,&Next
  DIALOG ADD,BUTTON,BUTTON1,266,152,64,24,&Back
  DIALOG ADD,BUTTON,BUTTON3,266,363,,,&Cancel
  DIALOG ADD,EDIT,EDIT1,70,143,300,19,EDIT1
  if @null(@iniread(Sub,DefaultDirectory))
  dialog set,edit1,c:\Program Files\NodNarb Application Setup
  else
  dialog set,edit1,@iniread(Sub,DefaultDirectory)
  end
  DIALOG ADD,BUTTON,BUTTON4,94,378,64,24,Bro&wse
  DIALOG ADD,EDIT,EDIT2,70,143,304,144,EDIT2,,multi,wrap,scroll
  if @file(@path(%0)installnotes.txt)
  list loadfile,list2,@path(%0)installnotes.txt
  dialog set,edit2,@text(list2)
gosub hideshowdialogs
  DIALOG SHOW

  :evloop
  wait event
  goto @event()
 
:button3button
:close
if @equal(%%count,3)
exit
else
end
%%ask = @ask(Setup is not complete.  Are you sure you want to exit?) 
if %%ask
exit
else
end
goto evloop

:hideshowdialogs
if @equal(%%count,0)
dialog show,text1
  dialog set,text1,@iniread(Sub,Welcome)
dialog show,text2
  dialog set,text2,@iniread(Sub,Description)
dialog show,text3
  dialog set,text3,@iniread(Sub,Nextmessage)
window settext,#nodwelcome,Welcome
dialog hide,edit2
dialog hide,edit1
dialog hide,button4
dialog disable,button1
else
end

if @equal(%%count,1)
dialog set,text1,@iniread(Sub,DirectoryMsg)
dialog enable,button1
window settext,#nodwelcome,Directory
dialog hide,edit2
dialog show,edit1
dialog show,button4
dialog hide,text3
dialog hide,text2
else
end

if @equal(%%count,2)
dialog set,text1,@iniread(Sub,StartInstall)
window settext,#nodwelcome,Start Install
dialog set,button2,Install
dialog show,edit2
dialog hide,edit1
dialog hide,button4
dialog show,text3
dialog set,text3,@iniread(Sub,StartInfoMsg)
else
end

if @equal(%%count,3)
dialog set,text1,@iniread(Sub,EndMessage)

rem THE KEY ELEMENT TO THIS UTILITY - THIS LINE COPIES DIRECTORIES RECURSIVELY
file copy,@windir()\temp\NodSetup,@dlgtext(edit1)

window settext,#nodwelcome,End of Install
dialog hide,text3
dialog hide,button1
dialog hide,button2
dialog show,button3
dialog set,button3,Finish

if @iniread(Link,Group)
%%shortcutcount = 0
DDE LINK,Progman,Progman
if @ok()
DDE EXECUTE,[CreateGroup(@iniread(Link,Group))]
end
if @ok()
DDE EXECUTE,[ShowGroup(@iniread(Link,Group)",1")]
end
    
repeat
%%shortcutcount = @succ(%%shortcutcount)
if @iniread(Link,Title%%shortcutcount)
if @ok()
DDE EXECUTE,[AddItem(@shortname(@dlgtext(edit1)\@iniread(Link,exe%%shortcutcount))","@iniread(Link,title%%shortcutcount))]
end
end
until @null(@iniread(Link,Title%%shortcutcount))
DDE TERMINATE

else
end

if @file(@path(%0)reg.reg)
info Setup will now create the necessary registry entries to use this program and exit.
shell open,@path(%0)reg.reg
else
end

else
end

exit

:button2button
%%count = @succ(%%count)
gosub hideshowdialogs
goto evloop

:button1button
%%count = @pred(%%count)
gosub hideshowdialogs
goto evloop

:button4button
%%dirdlg = @dirdlg()
dialog set,edit1,%%dirdlg
goto evloop

Back to top
View user's profile Send private message AIM Address
Tommy
Admin Team


Joined: 16 Nov 2002
Posts: 737
Location: The Netherlands

PostPosted: Thu Dec 26, 2002 3:19 am    Post subject: Reply with quote

NodNarb,

It might be better to use the link command for creating the shortcuts.

Tommy
Back to top
View user's profile Send private message Send e-mail Visit poster's website
ShinobiSoft
Professional Member
Professional Member


Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn

PostPosted: Thu Dec 26, 2002 5:37 am    Post subject: Reply with quote

I was thinking about making a dll that accesses the Windows SetupAPI.

If I get enought yeahs, I might go ahead with it Razz

Let me know.

_________________
Bill Weckel
ShinobiSoft Software

"The way is known to all, but not all know it."
Back to top
View user's profile Send private message Send e-mail Visit poster's website Yahoo Messenger
cnodnarb
Valued Contributor
Valued Contributor


Joined: 11 Sep 2002
Posts: 641
Location: Evansville, IN

PostPosted: Thu Dec 26, 2002 2:16 pm    Post subject: Reply with quote

The only problem with using the link command is that it's hard to get access to the Programs menu using it. I'm not saying it's impossible, but this way already works...and I believe it works on all windows versions.

NodNarb
Back to top
View user's profile Send private message AIM Address
FreezingFire
Admin Team


Joined: 23 Jun 2002
Posts: 3508

PostPosted: Fri Aug 22, 2003 1:41 pm    Post subject: Reply with quote

Is there anybody still interested in finishing development of this
project with VDS 5? Or should this project be thrown in the trash
if nobody wants it?

_________________
FreezingFire
VDSWORLD.com
Site Admin Team
Back to top
View user's profile Send private message Visit poster's website
LiquidCode
Moderator Team


Joined: 05 Dec 2000
Posts: 1711
Location: Space and Time

PostPosted: Fri Aug 22, 2003 1:44 pm    Post subject: Reply with quote

I'm interested. I haven't really looked at it, but, seems neat. I have registered VDSZip.dll so I can use that insted of the Info Zip program.
_________________
Chris
Http://vdsfreak.com
Back to top
View user's profile Send private message Send e-mail Visit poster's website
FreezingFire
Admin Team


Joined: 23 Jun 2002
Posts: 3508

PostPosted: Fri Aug 22, 2003 1:57 pm    Post subject: Reply with quote

Good to hear you're interested. This project kind of up and died and
I think it could be a really great product with a little more work.

Well maybe a screenshot would help get more people interested.


_________________
FreezingFire
VDSWORLD.com
Site Admin Team
Back to top
View user's profile Send private message Visit poster's website
Display posts from previous:   
Post new topic   Reply to topic    forum.vdsworld.com Forum Index -> Visual DialogScript Open Source Projects All times are GMT
Goto page Previous  1, 2, 3, 4  Next
Page 3 of 4

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You can attach files in this forum
You can download files in this forum




Twitter@vdsworld       RSS

Powered by phpBB © 2001, 2005 phpBB Group