forum.vdsworld.com :: View topic

forum.vdsworld.com
Visit VDSWORLD.com

FAQ

Memberlist

Usergroups

Profile

Tab Management
Goto page 1, 2 Next

forum.vdsworld.com Forum Index -> General Help

View previous topic :: View next topic

Author

Message

FreezingFire
Admin Team

Joined: 23 Jun 2002
Posts: 3508

Posted: Fri Feb 28, 2003 8:57 pm Post subject: Tab Management

Does anyone have any tips on managing tabs in VDS? I've tried putting the elements in groups in using DIALOG HIDE/SHOW to manage them. That didn't work so I tried using GOSUBs with adding and removing the elements. I've only got a few tabs, but it doesn't seem to work well. Thanks... _________________ FreezingFire VDSWORLD.com Site Admin Team

ShinobiSoft
Professional Member

Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn

Posted: Fri Feb 28, 2003 9:00 pm Post subject:

I usually use the GROUP element as the first element on the TAB page because when it comes time to change tabs, I only have to remove the GROUP element instead of all the elements for that particular tab. I could probably dig up an example if needed or wanted. _________________ Bill Weckel ShinobiSoft Software "The way is known to all, but not all know it."

GeoTrail
Valued Contributor

Joined: 18 Feb 2003
Posts: 572
Location: Bergen, Norway

Posted: Sat Mar 01, 2003 12:57 am Post subject:

I use Gosub to manage my TABS and it is working very nicely.

Code:

:ABOUTCLICK
DIALOG SHOW,DateUpdate1
DIALOG SHOW,DateUpdate2
DIALOG SHOW,FREEMEM
DIALOG SHOW,FREEMEM1
DIALOG SHOW,VERSION
DIALOG SHOW,FILEVER
DIALOG HIDE,UNDRDEVELOP
DIALOG HIDE,CREDITSTEXT
DIALOG HIDE,CREDITSHEAD
DIALOG HIDE,HISTORY
Goto Evloop

_________________

ShinobiSoft
Professional Member

Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn

Posted: Sat Mar 01, 2003 2:02 am Post subject:

Here is a really good example of a Setup Creator interface that uses TABS
and even has a TAB inside of a TAB.

It uses the FREEWARE Mtzip.dll.

Code:

TITLE SS Setup Manager
external mtzip.dll
Option scale,96
Option colordlg,webonly
%%space = 0
%%rootKeys = HKEY_ROOT@cr()HKEY_CURUSER@cr()HKEY_LOCAL_MACHINE@cr()HKEY_USERS
%%st = 1
%%title = Untitled
%%ver = 1.0
%%grStart = #0000FF
%%grEnd = #000000
%%grStyle = TopToBottom
%%fFace = Times New Roman
%%fSize = 28
%%fAttr = BL
%%pkgDest = @path(%0)Projects\%%title
%%company = Your Company Name
%%copyright = Copyright © @datetime(yyyy) %%company

directory change,@path(%0)

DIALOG CREATE,SS Setup Manager,-1,0,450,350
REM *** Modified by Dialog Designer on 11/24/02 - 19:27 ***
dialog add,Style,St1,Courier New,8,,White,Foreground
dialog add,MENU,&File,&New|Ctrl+N,&Open|Ctrl+O,&Save|Ctrl+S,Save &As...,-,E&xit|Alt+X
dialog add,MENU,&Project,&Publish|Alt+P,-,P&roperties|Ctrl+P
DIALOG ADD,MENU,&Help,&Contents|F1,Help on...|Ctrl+F1,-,&About SS Setup Manager
DIALOG ADD,GROUP,TBar1,5,5,440,30
DIALOG ADD,BITBTN,New,10,10,20,20,Newfile.bmp,,New project
DIALOG ADD,BitBtn,Open,10,30,20,20,OpenFile.bmp,,Open project
DIALOG ADD,BitBtn,Save,10,50,20,20,SaveFile.bmp,,Save project
DIALOG ADD,Group,TBSep1,5,75,2,30
DIALOG ADD,BitBtn,Compile,10,80,20,20,Compile.bmp,,Publish project
DIALOG ADD,BITBTN,MainHelp,10,420,20,20,Help.bmp,,Help contents
DIALOG ADD,TAB,TAB1,40,0,450,310,General|Appearance|Files|Registry|Inifile|Shortcuts|Package

DIALOG SHOW

%1 = General
gosub %1OPEN

:Evloop
wait 0.1,event
parse "%E;%D",@event(D)
goto %E

:Timer
if @equal(%1,General)
if @not(@equal(@dlgtext(Ed1),Untitled))
%%status = Modified
%%title = @dlgtext(Ed1)
dialog enable,Save
else
%%status =
%%title = Untitled
dialog disable,Save
end
end
if @equal(%1,Files)
%%sel = @trim(@item(List1))
if @null(%%sel)
dialog disable,DelFile
dialog disable,DelDir
dialog disable,AddFile
dialog disable,MoveUp
dialog disable,MoveDown
else
parse "%%type;%%path",%%sel
if @equal(%%type,#F#)
dialog enable,DelFile
dialog enable,MoveUp
dialog enable,MoveDown
else
dialog disable,DelFile
dialog disable,MoveUp
dialog disable,MoveDown
end
if @equal(%%type,#D#)
if @equal(%%path,"%InstDir%")@equal(%%path,"%WinDir%")@equal(%%path,"%WinSysDir%")
dialog disable,DelDir
dialog enable,AddFile
else
dialog enable,DelDir
dialog enable,AddFile
end
else
dialog disable,AddFile
dialog disable,DelDir
end
end
end
if @equal(%1,Registry)
dialog select,0
if @null(@item(L1))
dialog disable,DelReg
dialog disable,EditReg
else
dialog enable,DelReg
dialog enable,EditReg
end
end
if @equal(%1,Inifile)
dialog select,0
if @null(@dlgtext(Ed1))@null(@dlgtext(Ed2))@null(@dlgtext(Ed3))@null(@dlgtext(Ed4))
dialog disable,AddIni
else
dialog enable,AddIni
end
if @null(@item(L1))
dialog disable,DelIni
dialog disable,EditIni
else
dialog enable,DelIni
dialog enable,EditIni
end
end
if @equal(%1,Shortcuts)
dialog select,0
if @item(L1)
dialog enable,EditScut
dialog enable,DelScut
else
dialog disable,DelScut
dialog disable,EditScut
end
end
goto Evloop

:NewMENU
:NewBUTTON
:OpenMENU
:OpenBUTTON
:SaveMENU
:SaveBUTTON
:Save As...MENU
goto Evloop

:PropertiesMENU
goto Evloop

:PublishMENU
:CompileBUTTON
gosub %1CLOSE
if @not(@null(%%bmp))
%%bmp = @name(%%bmp).@ext(%%bmp)
end
if @null(%%pkgDest)@greater(@pos(Untitled,%%pkgDest),0)
warn You must provide a destination folder for this installation package.
gosub %1OPEN
goto Evloop
end
list create,1
list add,1,%%title|%%ver
list add,1,%%sh1c|%%sh2c|%%tc|%%fFace|%%fSize|%%fAttr
list add,1,%%usebmp|%%grStart|%%grEnd|%%grStyle|%%bmp
list add,1,%%company|%%copyright|%%instDir|%%space
list add,1,%%license
list add,1,%%readMe
list add,1,%%welcome
rem *** Loop thru list and add only name and extension but also copy
rem source files to the package destination folder for processing
rem with zip.exe ***

list create,2
list assign,2,%%files
%%zipList =
if @greater(@count(2),0)
%%curDir = @curdir()
directory change,%%pkgDest
mtzip create,zipfile,%%pkgDest\Setup.zip
%x = 0
repeat
list seek,2,%x
%I = @trim(@item(2))
parse "%%type;%%file",%I
if @equal(%%type,#F#)
list add,1,#F#|@name(%I).@ext(%I)
file copy,%%file,%%pkgDest
mtzip add,buffer,@name(%%file).@ext(%%file)
else
list add,1,%I
end
%x = @succ(%x)
until @equal(%x,@count(2))
if @not(@file(%%pkgDest,D))
directory create,%%pkgDest
end
mtzip process,add
if @greater(@mtzip(errorcode),0)
warn Zip Error:@cr()@tab()@mtzip(errorcode)
end
end
list close,2
rem list add,1,%%files
list add,1,%%regEntries
list add,1,%%iniEntries
list add,1,%%shortcuts
rem gosub encrypt
list savefile,1,%%pkgDest\Setup.dat
list close,1
rem file copy,@path(%0)Data\SSSetup01.dat,%%pkgDest\Setup.exe
rem file copy,@path(%0)Data\SSSetup.dsr,%%pkgDest\Setup.dsr
rem file copy,@path(%0)Data\SSSetup02.dat,%%pkgDest\Uninst.exe
mtzip add,buffer,Setup.dat
rem mtzip add,buffer,Setup.exe
rem mtzip add,buffer,Setup.dsr
rem mtzip add,buffer,Uninst.exe
mtzip process,add
if @greater(@mtzip(errorcode),0)
warn Zip Error:@cr()@tab()@mtzip(errorcode)
end
directory change,%%curDir
gosub %1OPEN
goto Evloop

:GeneralCLICK
:FilesCLICK
:AppearanceCLICK
:RegistryCLICK
:InifileCLICK
:ShortcutsCLICK
:PackageCLICK
%2 = @substr(%E,1,-5)
gosub %1CLOSE
shift
gosub %1OPEN
goto Evloop

:GeneralOPEN
dialog select,0
DIALOG ADD,GROUP,GROUP1,65,5,440,280
DIALOG ADD,TEXT,TEXT1,70,15,75,15,Application title:
DIALOG ADD,EDIT,Ed1,85,15,180,20,%%title
DIALOG ADD,TEXT,TEXT2,70,200,40,15,Version:
DIALOG ADD,EDIT,Ed2,85,200,50,20,%%ver
DIALOG ADD,TEXT,TEXT7,70,255,75,15,Company name:
DIALOG ADD,EDIT,Ed7,85,255,180,20,%%company,,EXIT
DIALOG ADD,TEXT,TEXT8,110,15,45,15,Copyright:
DIALOG ADD,EDIT,Ed8,125,15,205,20,%%copyright
DIALOG ADD,TEXT,TEXT3,110,225,85,15,Installation folder:
DIALOG ADD,EDIT,Ed3,125,225,210,20,%%instDir
DIALOG ADD,TEXT,TEXT4,150,15,95,15,License agreement:
DIALOG ADD,EDIT,Ed4,165,15,385,20,%%license
DIALOG ADD,BITBTN,SeekLicense,165,405,30,20,Browse.bmp,,Browse for License text file
DIALOG ADD,TEXT,TEXT5,190,15,65,15,Read Me file:
DIALOG ADD,EDIT,Ed5,205,15,385,20,%%readMe
DIALOG ADD,BITBTN,SeekReadMe,205,405,30,20,Browse.bmp,,Browse for Read Me text file
DIALOG ADD,TEXT,TEXT6,230,15,70,15,Welcome text:
DIALOG ADD,EDIT,Ed6,245,15,420,90,%%welcome,,MULTI,SCROLL,WRAP
exit

:Ed7EXIT
if @equal(%1,General)
dialog set,Ed8,Copyright © @datetime(yyyy) @dlgtext(Ed7)
end
goto Evloop

:SeekLicenseBUTTON
%%license = @filedlg("All files (*.*)|*.*|Text files (*.txt)|*.txt",Select file,,OPEN)
if @not(@null(%%license))
dialog set,Ed4,%%license
end
goto Evloop

:SeekReadMeBUTTON
%%readMe = @filedlg("All files (*.*)|*.*|Text files (*.txt)|*.txt",Select file,,OPEN)
if @not(@null(%%readMe))
dialog set,Ed5,%%readMe
end
goto Evloop

:GeneralCLOSE
dialog select,0
%%title = @dlgtext(Ed1)
%%ver = @dlgtext(Ed2)
%%instDir = @dlgtext(Ed3)
%%license = @dlgtext(Ed4)
%%readMe = @dlgtext(Ed5)
%%welcome = @dlgtext(Ed6)
%%company = @dlgtext(Ed7)
%%copyright = @dlgtext(Ed8)
dialog remove,Group1
exit

:FilesOPEN
dialog select,0
DIALOG ADD,GROUP,GROUP1,65,5,440,280
DIALOG ADD,GROUP,GROUP2,70,10,430,30
DIALOG ADD,BITBTN,AddFile,75,15,20,20,Addfile.bmp,,Add file
DIALOG ADD,BITBTN,DelFile,75,35,20,20,Delfile.bmp,,Delete file
DIALOG ADD,GROUP,Sep1,70,60,2,30
DIALOG ADD,BITBTN,AddDir,75,65,20,20,AddDir.bmp,,Add folder
DIALOG ADD,BITBTN,DelDir,75,85,20,20,DelDir.bmp,,Delete folder
DIALOG ADD,GROUP,Sep2,70,110,2,30
dialog add,BITBTN,MoveUp,75,115,20,20,Arw08up.bmp,,Move up
dialog add,BitBtn,MoveDown,75,135,20,20,Arw08dn.bmp,,Move down
dialog add,GROUP,Sep3,70,160,2,30
DIALOG ADD,TEXT,TEXT1,80,250,75,15,Space needed:
DIALOG ADD,EDIT,Ed1,75,325,80,20,%%space
DIALOG ADD,TEXT,TEXT2,80,405,25,15,bytes
DIALOG ADD,LIST,LIST1,105,10,430,235,,St1

if %%files
list assign,LIST1,%%files
else
list add,List1,#D#|"%InstDir%"
list add,List1,#D#|"%WinDir%"
list add,List1,#D#|"%WinSysDir%"
end
exit

:AddFileBUTTON
%%idx = @index(List1)
%%addFile = @filedlg("All files (*.*)|*.*","Select File(s)",,MULTI)
if @not(@null(%%addFile))
list create,2
list assign,2,%%addFile
if @not(@equal(@index(List1),@pred(@count(List1))))
list seek,List1,@succ(@index(List1))
end
%x = 0
repeat
list seek,2,%x
%%I = @item(2)
list put,2," "#F#|%%I
%%space = @sum(%%space,@file(%%I,Z))
if @equal(%%idx,@pred(@count(List1)))
list add,List1,@item(2)
list seek,List1,@succ(@index(List1))
else
list insert,List1,@item(2)
end
%x = @succ(%x)
until @equal(%x,@count(2))
%%addFile = @text(2)
dialog set,Ed1,%%space
list close,2
list seek,List1,%%idx
end
goto Evloop

:DelFileBUTTON
%%delfile = @item(List1)
if @equal(@msgbox(Are you sure to remove this project file?,Confirm delete,$024),6)
list delete,List1
end
goto Evloop

:AddDirBUTTON
%%addDir = @dirdlg()
if @not(@null(%%addDir))
list add,List1,#D#|%%addDir
end
goto Evloop

:DelDirBUTTON
%%delDir = @item(List1)
parse "%T;%%path",%%delDir
if @not(@equal(%%path,"%InstDir%"))@not(@equal(%%path,"%WinDir%"))@not(@equal(%%path,"%WinSysDir%"))
if @equal(@msgbox(Are you sure to delete this folder?@cr()All files that were to be installed into this folder will also be deleted.@cr()Do you wish to continue?,Confirm Delete,$024),6)
repeat
list delete,List1
%I = @item(List1)
until @equal(@substr(%I,1,4),#D#|)
end
end
goto Evloop

:MoveUpBUTTON
:Move UpMENU
%I = @item(List1)
%%idx = @index(List1)
if @greater(%%idx,1)
list delete,List1
list seek,List1,@pred(@index(List1))
list insert,List1,%I
%M = @match(List1,%I)
end
goto Evloop

:MoveDownBUTTON
:Move DownMENU
%I = @item(List1)
%%idx = @index(List1)
if @not(@equal(%%idx,@pred(@count(List1))))
list delete,List1
list seek,List1,@succ(@index(List1))
list insert,List1,%I
%M = @match(List1,%I)
else
list add,List1,%I
%M = @match(List1,%I)
end
goto Evloop

:FilesCLOSE
dialog select,0
%%files = @text(LIST1)
dialog remove,Group1
exit

:AppearanceOPEN
dialog select,0
DIALOG ADD,GROUP,GROUP1,65,5,440,280
DIALOG ADD,Tab,Tab2,70,10,430,270,Title|Background

%G = Title
gosub %GOPEN
exit

:TitleCLICK
:BackgroundCLICK
gosub %GCLOSE
%G = @substr(%E,1,-5)
gosub %GOPEN
goto Evloop

:TitleOPEN
if @null(%%fFace)
%%fFace = Arial
end
if @null(%%fSize)
%%fSize = 28
end
if @null(%%sh1c)
%%sh1c = #000000
end
if @null(%%sh2c)
%%sh2c = #008F00
end
if @null(%%tc)
%%tc = #00FFFF
end

dialog select,0
dialog add,Style,StTitle%%st,%%fFace,%%fSize,%%fAttr,,%%tc
dialog add,Style,StShadow1%%st,%%fFace,%%fSize,%%fAttr,,%%sh1c
dialog add,Style,StShadow2%%st,%%fFace,%%fSize,%%fAttr,,%%sh2c
DIALOG ADD,GROUP,GROUP2,95,15,420,240
DIALOG ADD,TEXT,TEXT1,105,30,75,15,Shadow1 color:
DIALOG ADD,EDIT,Ed1,100,110,80,20,%%sh1c,,EXIT
DIALOG ADD,BITBTN,Sh1Color,100,200,25,20,FontColor.bmp,,Select the color for the first shadow
DIALOG ADD,TEXT,TEXT2,130,30,75,15,Shadow2 color:
DIALOG ADD,EDIT,Ed2,125,110,80,20,%%sh2c,,EXIT
DIALOG ADD,BITBTN,Sh2Color,125,200,25,20,FontColor.bmp,,Select the color for the second shadow
DIALOG ADD,TEXT,TEXT3,155,30,50,15,Title color:
DIALOG ADD,EDIT,Ed3,150,110,80,20,%%tc,,EXIT
DIALOG ADD,BITBTN,TitleColor,150,200,25,20,FontColor.bmp,,Select the color for the title
DIALOG ADD,TEXT,TEXT7,105,235,25,15,Font:
DIALOG ADD,EDIT,Ed6,100,265,165,20,%%fFace,,EXIT
DIALOG ADD,BITBTN,Font,125,400,30,20,Font.bmp,,Select the font face and size
DIALOG ADD,TEXT,TEXT8,130,235,25,15,Size:
DIALOG ADD,EDIT,Ed7,125,265,50,20,%%fSize,,EXIT
DIALOG ADD,CHECK,Bold,150,250,50,15,Bold,%%bold,,CLICK
DIALOG ADD,CHECK,Italic,150,305,50,15,Italic,%%italic,,CLICK
DIALOG ADD,CHECK,Underline,150,360,70,15,Underline,%%underline,,CLICK
DIALOG ADD,CHECK,Left,165,250,50,15,Left,%%left,,CLICK
DIALOG ADD,CHECK,Center,165,305,50,15,Center,%%center,,CLICK
DIALOG ADD,CHECK,Right,165,360,50,15,Right,%%right,,CLICK
DIALOG ADD,GROUP,GROUP3,185,20,410,145,Preview
if %%bmp
dialog add,BitMap,Bmp1,200,25,400,125,%%bmp,,Stretch
else
dialog add,Gradient,Grad1,200,25,400,125,%%grStart,%%grEnd,,%%grStyle
end
DIALOG ADD,TEXT,Shadow1,215,35,380,50,%%title %%ver,,StShadow1%%st,TRANSPARENT
DIALOG ADD,Text,Shadow2,214,34,380,50,%%title %%ver,,StShadow2%%st,Transparent
DIALOG ADD,Text,SampleTitle,213,33,380,50,%%title %%ver,,StTitle%%st,Transparent

if %%fAttr
%%P = @pos(B,%%fAttr)
if @greater(%%P,0)
dialog set,Bold,1
end
%%P = @pos(I,%%fAttr)
if @greater(%%P,0)
dialog set,Italic,1
end
%%P = @pos(U,%%fAttr)
if @greater(%%P,0)
dialog set,Underline,1
end
%%P = @pos(L,%%fAttr)
if @greater(%%P,0)
dialog set,Left,1
dialog disable,Center
dialog disable,Right
end
%%P = @pos(C,%%fAttr)
if @greater(%%P,0)
dialog set,Center,1
dialog disable,Left
dialog disable,Right
end
%%P = @pos(R,%%fAttr)
if @greater(%%P,0)
dialog set,Right,1
dialog disable,Left
dialog disable,Center
end
else
dialog set,Bold,1
dialog set,Left,1
dialog disable,Center
dialog disable,Right
end
%%st = @succ(%%st)
exit

:LeftCLICK
:CenterCLICK
:RightCLICK
%%element = @substr(%E,1,-5)
%%align = @substr(%%element,1,)
if @dlgtext(%%element)
if @equal(%%align,L)
dialog disable,Center
dialog disable,Right
end
if @equal(%%align,C)
dialog disable,Left
dialog disable,Right
end
if @equal(%%align,R)
dialog disable,Left
dialog disable,Center
end
else
if @equal(%%align,L)
dialog enable,Center
dialog enable,Right
end
if @equal(%%align,C)
dialog enable,Left
dialog enable,Right
end
if @equal(%%align,R)
dialog enable,Left
dialog enable,Center
end
else
goto Evloop
end
rem goto Evloop

:Ed1EXIT
:Ed2EXIT
:Ed3EXIT
:Ed6EXIT
:Ed7EXIT
:BoldCLICK
:ItalicCLICK
:UnderlineCLICK
if @equal(%1,Appearance)
dialog remove,Shadow1
dialog remove,Shadow2
dialog remove,SampleTitle

%%st = @succ(%%st)
%%fFace = @dlgtext(Ed6)
%%fSize = @dlgtext(Ed7)
%%sh1c = @dlgtext(Ed1)
%%sh2c = @dlgtext(Ed2)
%%tc = @dlgtext(Ed3)
%%fAttr =
if @dlgtext(Bold)
%%fAttr = %%fAttr"B"
end
if @dlgtext(Italic)
%%fAttr = %%fAttr"I"
end
if @dlgtext(Underline)
%%fAttr = %%fAttr"U"
end
if @dlgtext(Left)
%%fAttr = %%fAttr"L"
end
if @dlgtext(Center)
%%fAttr = %%fAttr"C"
end
if @dlgtext(Right)
%%fAttr = %%fAttr"R"
end

dialog add,Style,StTitle%%st,%%fFace,%%fSize,%%fAttr,,%%tc
dialog add,Style,StShadow1%%st,%%fFace,%%fSize,%%fAttr,,%%sh1c
dialog add,Style,StShadow2%%st,%%fFace,%%fSize,%%fAttr,,%%sh2c
DIALOG ADD,TEXT,Shadow1,215,35,380,50,%%title %%ver,,StShadow1%%st,TRANSPARENT
DIALOG ADD,Text,Shadow2,214,34,380,50,%%title %%ver,,StShadow2%%st,Transparent
DIALOG ADD,Text,SampleTitle,213,33,380,50,%%title %%ver,,StTitle%%st,Transparent
end
goto Evloop

:TitleCLOSE
dialog select,0
%%sh1c = @dlgtext(Ed1)
%%sh2c = @dlgtext(Ed2)
%%tc = @dlgtext(Ed3)
%%fFace = @dlgtext(Ed6)
%%fSize = @dlgtext(Ed7)
%%fAttr =
if @dlgtext(Bold)
%%fAttr = %%fAttr"B"
end
if @dlgtext(Italic)
%%fAttr = %%fAttr"I"
end
if @dlgtext(Underline)
%%fAttr = %%fAttr"U"
end
if @dlgtext(Left)
%%fAttr = %%fAttr"L"
end
if @dlgtext(Center)
%%fAttr = %%fAttr"C"
end
if @dlgtext(Right)
%%fAttr = %%fAttr"R"
end
%%bold = @dlgtext(Bold)
%%italic = @dlgtext(Italic)
%%underline = @dlgtext(Underline)
%%left = @dlgtext(Left)
%%center = @dlgtext(Center)
%%right = @dlgtext(Right)

%%st = @succ(%%st)
dialog remove,Group2
exit

:BackgroundOPEN
%%grStyles = BottomLeft@cr()BottomRight@cr()BottomToTop@cr()CenterToEdges@cr()EdgesToCenter@cr()EdgesToHCenter@cr()EdgesToVCenter@cr()EllipticIn@cr()EllipticOut@cr()HCenterToEdges@cr()LeftToRight@cr()RightToLeft@cr()TopLeft@cr()TopRight@cr()TopToBottom@cr()VCenterToEdges
dialog select,0
DIALOG ADD,GROUP,GROUP2,95,15,420,240
DIALOG ADD,TEXT,TEXT4,110,25,65,15,Starting color:
DIALOG ADD,EDIT,Ed4,105,105,80,20,%%grStart
DIALOG ADD,BITBTN,GrStartColor,105,195,30,20,FontColor.bmp,,Select the gradient start color
DIALOG ADD,TEXT,TEXT5,135,25,65,15,Ending color:
DIALOG ADD,EDIT,Ed5,130,105,80,20,%%grEnd
DIALOG ADD,BITBTN,GrEndColor,130,195,30,20,FontColor.bmp,,Select the gradient end color
DIALOG ADD,TEXT,TEXT6,155,25,25,15,Style:
DIALOG ADD,COMBO,GrStyles,170,25,180,21,%%grStyle,,LIST,EXIT,CLICK
DIALOG ADD,GROUP,GROUP4,195,240,190,130,Preview
DIALOG ADD,GRADIENT,Grad1,210,245,180,110,%%grStart,%%grEnd,,%%grStyle
dialog add,BITMAP,Bmp1,210,245,180,110,%%bmp,,STRETCH
DIALOG ADD,CHECK,UseBmp,105,230,120,15,Background image,%%bmp,,CLICK
DIALOG ADD,EDIT,Ed8,125,235,160,20,%%bmp
DIALOG ADD,BITBTN,SeekBmp,125,400,25,20,Browse.bmp,,Browse for background image

if @null(%%grStart)
%%grStart = #0000FF
dialog set,Ed4,%%grStart
end
if @null(%%grEnd)
%%grEnd = #000000
dialog set,Ed5,%%grEnd
end
list assign,GrStyles,%%grStyles
if @null(%%grStyle)
%M = @match(GrStyles,TopToBottom)
else
%M = @match(GrStyles,%%grStyle)
end

if %%bmp
goto UseBmpCLICK
else
dialog disable,Ed8
dialog disable,SeekBmp
dialog hide,Bmp1
end
exit

:UseBmpCLICK
dialog select,0
if @dlgtext(Usebmp)
dialog enable,Ed8
dialog enable,SeekBmp
dialog disable,Text4
dialog disable,Ed4
dialog disable,GrStartColor
dialog disable,Text5
dialog disable,Ed5
dialog disable,GrEndColor
dialog disable,Text6
dialog disable,GrStyles
dialog hide,Grad1
dialog show,BMP1
else
dialog disable,Ed8
dialog disable,SeekBmp
dialog enable,Text4
dialog enable,Ed4
dialog enable,GrStartColor
dialog enable,Text5
dialog enable,Ed5
dialog enable,GrEndColor
dialog enable,Text6
dialog enable,GrStyles
dialog hide,Bmp1
dialog show,Grad1
end
goto Evloop

:SeekBmpBUTTON
%%bmp = @filedlg("Image files (*.bmp)|*.bmp",Choose background picture,,OPEN)
if @not(@null(%%bmp))
dialog set,Ed8,%%bmp
dialog set,Bmp1,%%bmp
end
goto Evloop

:Sh1ColorBUTTON
%%sh1c = @colordlg(%%sh1c)
if @not(@null(%%sh1c))
dialog set,Ed1,%%sh1c
end
goto Ed1EXIT

:Sh2ColorBUTTON
%%sh2c = @colordlg(%%sh2c)
if @not(@null(%%sh2c))
dialog set,Ed2,%%sh2c
end
goto Ed2EXIT

:TitleColorBUTTON
%%tc = @colordlg(%%tc)
if @not(@null(%%tc))
dialog set,Ed3,%%tc
end
goto Ed3EXIT

:GrStartColorBUTTON
%%grStart = @colordlg(%%grStart)
if @not(@null(%%grStart))
dialog set,Ed4,%%grStart
end
goto GrStylesCLICK

:GrEndColorBUTTON
%%grEnd = @colordlg(%%grEnd)
if @not(@null(%%grEnd))
dialog set,Ed5,%%grEnd
end
goto GrStylesCLICK

:FontBUTTON
%%fontInfo = @fontdlg()
if @not(@null(%%fontInfo))
parse "%%fFace;%%fSize",%%fontInfo
dialog set,Ed6,%%fFace
dialog set,Ed7,%%fSize
end
goto Ed6EXIT

:GrStylesCLICK
dialog select,0
dialog remove,Grad1
dialog add,Gradient,Grad1,210,245,180,110,@dlgtext(Ed4),@dlgtext(Ed5),,@item(GrStyles)
goto Evloop

:BackgroundCLOSE
dialog select,0
%%useBmp = @dlgtext(UseBmp)
if %%useBmp
%%bmp = @dlgtext(Ed8)
%%grStart =
%%grEnd =
%%grStyle =
else
%%bmp =
%%grStart = @dlgtext(Ed4)
%%grEnd = @dlgtext(Ed5)
%%grStyle = @item(GrStyles)
end
dialog remove,Group2
exit

:AppearanceCLOSE
dialog select,0
gosub %GCLOSE
dialog remove,Group1
exit

:RegistryOPEN
dialog select,0
DIALOG ADD,GROUP,GROUP1,65,5,440,280
DIALOG ADD,GROUP,GROUP2,70,10,430,30
DIALOG ADD,BITBTN,AddReg,75,15,20,20,Add003.bmp,,Add registry entry
DIALOG ADD,BITBTN,DelReg,75,35,20,20,Del003.bmp,,Delete registry entry
DIALOG ADD,GROUP,Sep1,70,60,2,30
DIALOG ADD,BITBTN,EditReg,75,65,20,20,Edit003.bmp,,Edit registry entry
DIALOG ADD,GROUP,Sep2,70,90,2,30
DIALOG ADD,BITBTN,AddAssoc,75,95,20,20,Add001.bmp,,Add file association
DIALOG ADD,LIST,L1,105,10,430,235,,St1

if %%regEntries
list assign,L1,%%regEntries
end
exit

:AddRegBUTTON
:EditRegBUTTON
%%act = @substr(%E,1,-9)
if @equal(%%act,Edit)
%%act = @lower(%%act)
%%act = E@substr(%%act,2,1024)
%%editReg = @item(L1)
else
%%act = @lower(%%act)
%%act = A@substr(%%act,2,1024)
end

DIALOG CREATE,%%act Registry Entry,-1,0,300,175,SMALLCAP
REM *** Modified by Dialog Designer on 11/20/02 - 18:06 ***
DIALOG ADD,TEXT,TEXT1,5,5,45,15,Root key:
DIALOG ADD,COMBO,Cb1,20,5,220,21,,,LIST
DIALOG ADD,TEXT,TEXT2,50,5,40,15,Subkey:
DIALOG ADD,EDIT,Ed1,65,5,220,20
DIALOG ADD,TEXT,TEXT3,90,5,70,15,Subkey name:
DIALOG ADD,EDIT,Ed2,105,5,220,20
DIALOG ADD,TEXT,TEXT4,130,5,65,15,Subkey data:
DIALOG ADD,EDIT,Ed3,145,5,220,20
DIALOG ADD,BUTTON,RegOk,20,230,65,25,Ok
DIALOG ADD,BUTTON,Cancel,50,230,65,25,Cancel
DIALOG ADD,BUTTON,RegHelp2,140,230,65,25,Help
DIALOG SHOW

list assign,Cb1,%%rootKeys

if @equal(%%act,Edit)
parse "%%type;%%rKey";Ed1;Ed2;Ed3,%%editReg
%M = @match(Cb1,%%rKey)
end
goto Evloop

:RegOkBUTTON
dialog select,1
%%regEntry = @item(Cb1)|@dlgtext(Ed1)|@dlgtext(Ed2)|@dlgtext(Ed3)
dialog select,0
if @equal(%%act,Add)
list add,L1,#R#|%%regEntry
else
list put,L1,#R#|%%regEntry
end
goto CancelBUTTON

:DelRegBUTTON
if @equal(@msgbox(Are you sure to delete this registry entry?,Confirm Delete,$024),6)
dialog select,0
list delete,L1
end
goto Evloop

:AddAssocBUTTON
DIALOG CREATE,File Association,-1,0,290,165,SMALLCAP
REM *** Modified by Dialog Designer on 11/20/02 - 23:12 ***
dialog add,Text,Text1,10,5,90,15,Extension:
dialog add,Edit,Ed1,5,100,180,20
dialog add,Text,Text2,35,5,90,15,Short description:
dialog add,Edit,Ed2,30,100,180,20
dialog add,Text,Text3,60,5,90,15,Long description:
dialog add,Edit,Ed3,55,100,180,20
dialog add,Text,Text4,85,5,90,15,Opens with:
dialog add,Edit,Ed4,80,100,180,20
dialog add,Text,Text5,110,5,90,15,Default icon:
dialog add,Edit,Ed5,105,100,180,20
DIALOG ADD,BUTTON,Cancel,135,220,65,25,Cancel
DIALOG ADD,BUTTON,FileAssocOk,135,150,65,25,Ok
DIALOG SHOW

goto Evloop

:FileAssocOkBUTTON
dialog select,1
%%extKey = HKEY_ROOT|@dlgtext(Ed1)||@dlgtext(Ed2)
%%extShortDesc = HKEY_ROOT|@dlgtext(Ed2)||@dlgtext(Ed3)
%%extOpensWith = HKEY_ROOT|@dlgtext(Ed2)|Opens With|@dlgtext(Ed4)
%%extDefaultIcon = HKEY_ROOT|@dlgtext(Ed2)DefaultIcon|@dlgtext(Ed5)
dialog select,0
list add,L1,#R#|%%extKey
list add,L1,#R#|%%extShortDesc
list add,L1,#R#|%%extOpensWith
list add,L1,#R#|%%extDefaultIcon
goto CLOSE

:RegHelp2BUTTON
rem This is from the Add/Edit Registry Entry dialog
goto Evloop

:RegistryCLOSE
dialog select,0
%%regEntries = @text(L1)
dialog remove,Group1
exit

:InifileOPEN
dialog select,0
DIALOG ADD,GROUP,GROUP1,65,5,440,280
DIALOG ADD,TEXT,TEXT1,110,15,30,15,Ini file:
DIALOG ADD,EDIT,Ed1,110,55,160,20
DIALOG ADD,TEXT,TEXT2,115,230,40,15,Section:
DIALOG ADD,EDIT,Ed2,110,275,160,20
DIALOG ADD,TEXT,TEXT3,140,15,30,15,Name:
DIALOG ADD,EDIT,Ed3,135,55,160,20
DIALOG ADD,TEXT,TEXT4,140,240,25,15,Data:
DIALOG ADD,EDIT,Ed4,135,275,160,20
DIALOG ADD,GROUP,Sep1,70,10,430,30
DIALOG ADD,BITBTN,AddIni,75,15,20,20,Add002.bmp,,Add entry
DIALOG ADD,BITBTN,DelIni,75,35,20,20,Del002.bmp,,Delete entry
DIALOG ADD,GROUP,Sep2,70,60,2,30
DIALOG ADD,BITBTN,EditIni,75,65,20,20,Edit002.bmp,,Edit entry
DIALOG ADD,LIST,L1,165,15,420,175,,St1

if %%iniEntries
list assign,L1,%%iniEntries
end
exit

:AddIniBUTTON
List add,L1,#I#|@dlgtext(Ed1)|@dlgtext(Ed2)|@dlgtext(Ed3)|@dlgtext(Ed4)
parse Ed1;Ed2;Ed3;Ed4,||||
goto Evloop

:DelIniBUTTON
%%del = @item(L1)
if @equal(@msgbox(Are you sure to delete this ini entry?,Confirm Delete,$024),6)
list delete,L1
end
goto Evloop

:IniHelpBUTTON
goto Evloop

:EditIniBUTTON
%%editIni = @item(L1)

DIALOG CREATE,Edit Ini Entry,-1,0,260,175,SMALLCAP
REM *** Modified by Dialog Designer on 11/20/02 - 13:53 ***
DIALOG ADD,TEXT,TEXT1,5,5,30,15,Ini file:
DIALOG ADD,EDIT,Ed1,20,5,180,20
DIALOG ADD,TEXT,TEXT2,45,5,70,15,Section name:
DIALOG ADD,EDIT,Ed2,60,5,180,20
DIALOG ADD,TEXT,TEXT3,85,5,60,15,Value name:
DIALOG ADD,EDIT,Ed3,100,5,180,20
DIALOG ADD,TEXT,TEXT4,125,5,55,15,Value data:
DIALOG ADD,EDIT,Ed4,140,5,180,20
DIALOG ADD,BUTTON,EditIniApply,20,190,65,25,Apply
DIALOG ADD,BUTTON,Cancel,50,190,65,25,Cancel
DIALOG SHOW

parse "%%type";Ed1;Ed2;Ed3;Ed4,%%editIni
goto Evloop

:EditIniApplyBUTTON
dialog select,1
%%edit = @dlgtext(Ed1)|@dlgtext(Ed2)|@dlgtext(Ed3)|@dlgtext(Ed4)
dialog select,0
list put,L1,#I#|%%edit
%D = 1
goto CancelBUTTON

:InifileCLOSE
dialog select,0
%%iniEntries = @text(l1)
dialog remove,Group1
exit

:ShortcutsOPEN
dialog select,0
DIALOG ADD,GROUP,GROUP1,65,5,440,280
DIALOG ADD,GROUP,GROUP2,70,10,430,30
DIALOG ADD,BITBTN,AddScut,75,15,20,20,Add004.bmp,,Add shortcut
DIALOG ADD,BITBTN,DelScut,75,35,20,20,Del004.bmp,,Delete shortcut
DIALOG ADD,GROUP,Sep1,70,60,2,30
DIALOG ADD,BITBTN,EditScut,75,65,20,20,Edit004.bmp,,Edit shortcut
DIALOG ADD,LIST,L1,105,10,430,235,,St1

if %%shortcuts
list assign,L1,%%shortcuts
end
exit

:AddScutBUTTON
:EditScutBUTTON
%%act = @substr(%E,1,-10)
if @equal(%%act,Edit)
%%act = @lower(%%act)
%%act = E@substr(%%act,2,1024)
%%editScut = @item(L1)
else
%%act = @lower(%%act)
%%act = A@substr(%%act,2,1024)
end

DIALOG CREATE,%%act Shortcut,-1,0,340,155,SMALLCAP
REM *** Modified by Dialog Designer on 11/23/02 - 09:55 ***
DIALOG ADD,TEXT,TEXT1,10,5,45,15,Filename:
DIALOG ADD,EDIT,Ed1,5,80,180,20
DIALOG ADD,TEXT,TEXT2,35,5,70,15,Shortcut path:
DIALOG ADD,EDIT,Ed2,30,80,180,20
DIALOG ADD,TEXT,TEXT3,60,5,75,15,Shortcut name:
DIALOG ADD,EDIT,Ed3,55,80,180,20
DIALOG ADD,TEXT,TEXT4,85,5,50,15,Icon path:
DIALOG ADD,EDIT,Ed4,80,80,180,20
DIALOG ADD,TEXT,TEXT5,110,5,70,15,Start directory:
DIALOG ADD,EDIT,Ed5,105,80,180,20
DIALOG ADD,TEXT,TEXT6,135,5,60,15,Parameters:
DIALOG ADD,EDIT,Ed6,130,80,180,20
DIALOG ADD,BUTTON,ScutOk,5,270,65,25,Ok
DIALOG ADD,BUTTON,Cancel,35,270,65,25,Cancel
DIALOG ADD,BUTTON,AddEditScutHelp,125,270,65,25,Help
DIALOG SHOW

if @equal(%%act,Edit)
parse "%%type";Ed1;Ed2;Ed3;Ed4;Ed5;Ed6,%%editScut
end
goto Evloop

:ScutOkBUTTON
dialog select,1
%%scutAdd = #S#|@dlgtext(Ed1)|@dlgtext(Ed2)|@dlgtext(Ed3)|@dlgtext(Ed4)|@dlgtext(Ed5)|@dlgtext(Ed6)
dialog select,0
if @equal(%%act,Edit)
list put,L1,%%scutAdd
else
list add,L1,%%scutAdd
end
goto CLOSE

:DelScutBUTTON
if @equal(@msgbox(Are you sure to delete this shortcut?,Confirm delete,$024),6)
list delete,L1
end
goto Evloop

:AddEditScutHelpBUTTON
goto Evloop

:ShortcutsCLOSE
dialog select,0
%%shortcuts = @text(L1)
dialog remove,Group1
exit

:PackageOPEN
dialog select,0
DIALOG ADD,GROUP,GROUP1,65,5,440,280
DIALOG ADD,TEXT,TEXT1,75,15,100,15,Package destination:
DIALOG ADD,EDIT,Ed1,90,15,390,20,%%pkgDest
DIALOG ADD,BITBTN,SeekPkgDest,90,410,25,20,Browse.bmp,,Browse for package destination folder
DIALOG ADD,GROUP,GROUP2,115,15,140,95,Time stamp files
DIALOG ADD,CHECK,Stamp,135,25,100,15,Time stamp,%%stamp,Set the same time and date for all files,CLICK
DIALOG ADD,TEXT,TEXT2,160,35,30,15,Date:
DIALOG ADD,EDIT,Ed2,155,65,80,20,%%stampDate
DIALOG ADD,TEXT,TEXT3,185,35,30,15,Time:
DIALOG ADD,EDIT,Ed3,180,65,80,20,%%stampTime
DIALOG ADD,GROUP,GROUP3,115,165,270,95,After installation:
DIALOG ADD,CHECK,Reboot,135,180,100,15,Reboot machine
DIALOG ADD,CHECK,ViewReadMe,150,180,100,15,Open ReadMe
DIALOG ADD,CHECK,Run,165,180,100,15,Run program
DIALOG ADD,COMBO,Programs,180,200,220,21,,,LIST
DIALOG ADD,CHECK,Uninstall,220,20,180,20,Generate uninstall info,1

if @null(%%stamp)
dialog disable,Text2
dialog disable,Ed2
dialog disable,Text3
dialog disable,Ed3
end

exit

:StampCLICK
dialog select,0
if @dlgtext(Stamp)
dialog enable,Text2
dialog enable,Ed2
dialog enable,Text3
dialog enable,Ed3
dialog set,Ed2,@datetime(mm/dd/yy)
dialog set,Ed3,@datetime(t)
else
dialog set,Ed2,
dialog set,Ed3,
dialog disable,Text2
dialog disable,Ed2
dialog disable,Text3
dialog disable,Ed3
end
goto Evloop

:SeekPkgDestBUTTON
%%pkgDest = @dirdlg(,%%pkgDest)
if @not(@null(%%pkgDest))
dialog set,Ed1,%%pkgDest
end
goto Evloop

:PackageCLOSE
dialog select,0
%%pkgDest = @dlgtext(Ed1)
%%stamp = @dlgtext(Stamp)
if %%stamp
%%stampDate = @dlgtext(Ed2)
%%stampTime = @dlgtext(Ed3)
end
dialog remove,Group1
exit

:ContentsMENU
:MainHelpBUTTON
goto Evloop

:Help on...MENU
goto Evloop

:About SS Setup ManagerMENU
goto Evloop

:CancelBUTTON
:ExitMENU
:CLOSE
if @greater(%D,0)
dialog select,%D
dialog close
wait event
%E = @event()
goto Evloop
end
gosub %1CLOSE
stop

_________________
Bill Weckel
ShinobiSoft Software

"The way is known to all, but not all know it."

ShinobiSoft
Professional Member

Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn

Posted: Sat Mar 01, 2003 2:05 am Post subject:

BTW, the above script is written in VDS 4.5. _________________ Bill Weckel ShinobiSoft Software "The way is known to all, but not all know it."

Serge
Professional Member

Joined: 04 Mar 2002
Posts: 1480
Location: Australia

Posted: Sat Mar 01, 2003 5:09 am Post subject:

nice work on the interface - any reason why it flickers when you click on the tab inside the tab? Serge _________________ Cattle Ramp SEO Resources Meta Keywords Advice SEO Analysis Mental Workout Download eStore

ShinobiSoft
Professional Member

Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn

Posted: Sat Mar 01, 2003 5:36 am Post subject:

My guess is that it flickers because the controls are being added and removed instead of hidden and shown. _________________ Bill Weckel ShinobiSoft Software "The way is known to all, but not all know it."

Serge
Professional Member

Joined: 04 Mar 2002
Posts: 1480
Location: Australia

Posted: Sat Mar 01, 2003 5:45 am Post subject:

fair enough Serge _________________ Cattle Ramp SEO Resources Meta Keywords Advice SEO Analysis Mental Workout Download eStore

GeoTrail
Valued Contributor

Joined: 18 Feb 2003
Posts: 572
Location: Bergen, Norway

Posted: Sat Mar 01, 2003 3:18 pm Post subject:

Wow, pretty cool code Hi Serge _________________

ShinobiSoft
Professional Member

Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn

Posted: Sat Mar 01, 2003 3:46 pm Post subject:

Thanks for the compliments guys. This isn't a finished product though. This project has actually been put on the back burner. _________________ Bill Weckel ShinobiSoft Software "The way is known to all, but not all know it."

FreezingFire
Admin Team

Joined: 23 Jun 2002
Posts: 3508

Posted: Sat Mar 01, 2003 5:01 pm Post subject:

Nice example. Thanks a lot. This will help me. But: I downloaded the mtzip.dll package from VDSWORLD and when I run the code it gives two message boxes that say things such as "ZIPDLL.DLL" could not be found and "UNZDLL.DLL" could not be found. _________________ FreezingFire VDSWORLD.com Site Admin Team

ShinobiSoft
Professional Member

Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn

Posted: Sat Mar 01, 2003 5:17 pm Post subject:

Download the two missing dll's HERE. I thought they were a part of the original distribution. _________________ Bill Weckel ShinobiSoft Software "The way is known to all, but not all know it."

FreezingFire
Admin Team

Joined: 23 Jun 2002
Posts: 3508

Posted: Sat Mar 01, 2003 5:24 pm Post subject:

The DLLs that were contained in your ZIP package are the same ones (I think) that were contained in the mtzip051.zip package at VDSWORLD. Try Downloading MTZIP051 from VDSWORLD then run your script. _________________ FreezingFire VDSWORLD.com Site Admin Team

FreezingFire
Admin Team

Joined: 23 Jun 2002
Posts: 3508

Posted: Sat Mar 01, 2003 5:26 pm Post subject:

And another thing: When I renamed the zip32.dll etc. to zipdll.dll it said it couldn't find a fuction which I don't remember the name of in the DLL. _________________ FreezingFire VDSWORLD.com Site Admin Team

ShinobiSoft
Professional Member

Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn

Posted: Sat Mar 01, 2003 5:31 pm Post subject:

Yes they are the same ones that were/are contained in the MtZip051.zip package. That's why I thought it was strange that you didn't have them. Mtzip.dll is based on Info-Zips zip utility. Try visiting their site for the missing dll's. _________________ Bill Weckel ShinobiSoft Software "The way is known to all, but not all know it."

Display posts from previous:

	forum.vdsworld.com Forum Index -> General Help	All times are GMT Goto page 1, 2 Next
Page 1 of 2

You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You can attach files in this forum
You can download files in this forum

@vdsworld