forum.vdsworld.com

[Tdk161]

Hi,
It's possible retrieve a file list with all files and all subfolder contents? How?

Thamk you

[wolfsoft]

Hi,
this is a small subroutine that creates 2 filelists from a given (%1) directory or drive (ie.: C:\).
List 1 contains all files with relative path.
List 2 contains all files with full path.
%1 is set to the total number of files.

:CreateFilelists
if @null(@file(%1,D))
%1 = 0
exit
end
if @equal(@len(%1),3)
%1 = @substr(%1,1,2)
end
list create,1
list add,1,%1
list filelist,1,%1,*
if @zero(@count(1))
%1 = 0
exit
end
list create,2
%2 = 0
repeat
list seek,1,%2
list filelist,2,@item(1)\*.*
list filelist,2,@item(1)\*.*,SH
%2 = @succ(%2)
until @equal(@count(1),%2)
list clear,1
%2 = 0
%%root = @sum(@len(%1),2)
while @unequal(%2,@count(2))
%%path = @item(2,%2)
%%name = @substr(%%path,%%root,@len(%%path))
list add,1,%%name
%2 = @succ(%2)
wend
%1 = @count(1)
list savefile,1,RelativePath.txt
list savefile,2,FullPath.txt
exit

[Tdk161]

Thank you wolfsoft,

I will try your idea

[Hooligan]

The flist function in vdsdll works well....

Hooligan

[Tdk161]

I solved using the wolfsoft's code

I preferred it because I don't want use an external dll

Thank you to all