| View previous topic :: View next topic |
| Author |
Message |
Mac
Professional Member
Joined: 08 Jul 2000
Posts: 1585
Location: Oklahoma USA
|
 Posted: Tue Apr 23, 2002 11:24 am Post subject: For you DOS dinosaurs... |
 |
|
__________________________________________________________________________________________________________________________
Here's a DOS batch file Tic Tac Toe game I wrote a few
years ago. For the newbies, this is NOT VDS code.
The code doesn't copy/paste correctly here, so you can
download two versions of the game if ya want.
- This one uses the ESCAPE key symbol to exit (view it
with DOS EDIT.COM):
http://www.trinex.net./users/mac/dos/tictac.bat
- This one uses the Q key to exit (it can be viewed with
notepad):
http://www.trinex.net./users/mac/dos/tictac2.bat
You can run them from a DOS box, link to them, or open
them in Windows Explorer.
| Code: |
REM By MacFromOK. Cool tech site! http://forums.techguy.org/
@ECHO OFF
:BEGIN
REM Skill level
set sl=
cls
echo Tic Tac Toe by Mac (Q to quit)
echo.
echo.
echo Pick your skill level (press a number)
echo.
echo (1) Children under 6
echo (2) Average Mental Case
echo (3) Oversized Ego
CHOICE /c:123q /n > nul
if errorlevel 4 goto end
if errorlevel 3 set sl=3
if errorlevel 3 goto layout
if errorlevel 2 set sl=2
if errorlevel 2 goto layout
set sl=1
:LAYOUT
REM Player turn ("x" or "o")
set pt=
REM Game winner ("x" or "o")
set gw=
REM No moves
set nm=
REM Set to one blank space after equal sign (check with cursor end)
set t1=
set t2=
set t3=
set t4=
set t5=
set t6=
set t7=
set t8=
set t9=
:UPDATE
cls
echo (S to set skill level) Tic Tac Toe by Mac (Q to quit)
echo.
echo You are the X player.
echo Press the number where you want to put an X.
echo.
echo Skill level %sl% 7 8 9
echo 4 5 6
echo 1 2 3
echo.
echo : :
echo %t1% : %t2% : %t3%
echo ....:...:....
echo %t4% : %t5% : %t6%
echo ....:...:....
echo %t7% : %t8% : %t9%
echo : :
if "%gw%"=="x" goto winx2
if "%gw%"=="o" goto wino2
if "%nm%"=="0" goto nomoves
:PLAYER
set pt=x
REM Layout is for keypad. Change CHOICE to "/c:123456789sq /n > nul"
REM for numbers to start at top left (also change user layout above).
CHOICE /c:789456123sq /n > nul
if errorlevel 11 goto end
if errorlevel 10 goto begin
if errorlevel 9 goto 9
if errorlevel 8 goto 8
if errorlevel 7 goto 7
if errorlevel 6 goto 6
if errorlevel 5 goto 5
if errorlevel 4 goto 4
if errorlevel 3 goto 3
if errorlevel 2 goto 2
goto 1
:1
REM Check if "x" or "o" already in square.
if "%t1%"=="x" goto player
if "%t1%"=="o" goto player
set t1=x
goto check
:2
if "%t2%"=="x" goto player
if "%t2%"=="o" goto player
set t2=x
goto check
:3
if "%t3%"=="x" goto player
if "%t3%"=="o" goto player
set t3=x
goto check
:4
if "%t4%"=="x" goto player
if "%t4%"=="o" goto player
set t4=x
goto check
:5
if "%t5%"=="x" goto player
if "%t5%"=="o" goto player
set t5=x
goto check
:6
if "%t6%"=="x" goto player
if "%t6%"=="o" goto player
set t6=x
goto check
:7
if "%t7%"=="x" goto player
if "%t7%"=="o" goto player
set t7=x
goto check
:8
if "%t8%"=="x" goto player
if "%t8%"=="o" goto player
set t8=x
goto check
:9
if "%t9%"=="x" goto player
if "%t9%"=="o" goto player
set t9=x
goto check
:COMPUTER
set pt=o
if "%sl%"=="1" goto skill1
REM (win corner to corner)
if "%t1%"=="o" if "%t3%"=="o" if not "%t2%"=="x" if not "%t2%"=="o" goto c2
if "%t1%"=="o" if "%t9%"=="o" if not "%t5%"=="x" if not "%t5%"=="o" goto c5
if "%t1%"=="o" if "%t7%"=="o" if not "%t4%"=="x" if not "%t4%"=="o" goto c4
if "%t3%"=="o" if "%t7%"=="o" if not "%t5%"=="x" if not "%t5%"=="o" goto c5
if "%t3%"=="o" if "%t9%"=="o" if not "%t6%"=="x" if not "%t6%"=="o" goto c6
if "%t9%"=="o" if "%t7%"=="o" if not "%t8%"=="x" if not "%t8%"=="o" goto c8
REM (win outside middle to outside middle)
if "%t2%"=="o" if "%t8%"=="o" if not "%t5%"=="x" if not "%t5%"=="o" goto c5
if "%t4%"=="o" if "%t6%"=="o" if not "%t5%"=="x" if not "%t5%"=="o" goto c5
REM (win all others)
if "%t1%"=="o" if "%t2%"=="o" if not "%t3%"=="x" if not "%t3%"=="o" goto c3
if "%t1%"=="o" if "%t5%"=="o" if not "%t9%"=="x" if not "%t9%"=="o" goto c9
if "%t1%"=="o" if "%t4%"=="o" if not "%t7%"=="x" if not "%t7%"=="o" goto c7
if "%t2%"=="o" if "%t5%"=="o" if not "%t8%"=="x" if not "%t8%"=="o" goto c8
if "%t3%"=="o" if "%t2%"=="o" if not "%t1%"=="x" if not "%t1%"=="o" goto c1
if "%t3%"=="o" if "%t5%"=="o" if not "%t7%"=="x" if not "%t7%"=="o" goto c7
if "%t3%"=="o" if "%t6%"=="o" if not "%t9%"=="x" if not "%t9%"=="o" goto c9
if "%t4%"=="o" if "%t5%"=="o" if not "%t6%"=="x" if not "%t6%"=="o" goto c6
if "%t6%"=="o" if "%t5%"=="o" if not "%t4%"=="x" if not "%t4%"=="o" goto c4
if "%t7%"=="o" if "%t4%"=="o" if not "%t1%"=="x" if not "%t1%"=="o" goto c1
if "%t7%"=="o" if "%t5%"=="o" if not "%t3%"=="x" if not "%t3%"=="o" goto c3
if "%t7%"=="o" if "%t8%"=="o" if not "%t9%"=="x" if not "%t9%"=="o" goto c9
if "%t8%"=="o" if "%t5%"=="o" if not "%t2%"=="x" if not "%t2%"=="o" goto c2
if "%t9%"=="o" if "%t8%"=="o" if not "%t7%"=="x" if not "%t7%"=="o" goto c7
if "%t9%"=="o" if "%t5%"=="o" if not "%t1%"=="x" if not "%t1%"=="o" goto c1
if "%t9%"=="o" if "%t6%"=="o" if not "%t3%"=="x" if not "%t3%"=="o" goto c3
REM (block general attempts) -----------------------------------------------
if "%t1%"=="x" if "%t2%"=="x" if not "%t3%"=="x" if not "%t3%"=="o" goto c3
if "%t1%"=="x" if "%t5%"=="x" if not "%t9%"=="x" if not "%t9%"=="o" goto c9
if "%t1%"=="x" if "%t4%"=="x" if not "%t7%"=="x" if not "%t7%"=="o" goto c7
if "%t2%"=="x" if "%t5%"=="x" if not "%t8%"=="x" if not "%t8%"=="o" goto c8
if "%t3%"=="x" if "%t2%"=="x" if not "%t1%"=="x" if not "%t1%"=="o" goto c1
if "%t3%"=="x" if "%t5%"=="x" if not "%t7%"=="x" if not "%t7%"=="o" goto c7
if "%t3%"=="x" if "%t6%"=="x" if not "%t9%"=="x" if not "%t9%"=="o" goto c9
if "%t4%"=="x" if "%t5%"=="x" if not "%t6%"=="x" if not "%t6%"=="o" goto c6
if "%t6%"=="x" if "%t5%"=="x" if not "%t4%"=="x" if not "%t4%"=="o" goto c4
if "%t7%"=="x" if "%t4%"=="x" if not "%t1%"=="x" if not "%t1%"=="o" goto c1
if "%t7%"=="x" if "%t5%"=="x" if not "%t3%"=="x" if not "%t3%"=="o" goto c3
if "%t7%"=="x" if "%t8%"=="x" if not "%t9%"=="x" if not "%t9%"=="o" goto c9
if "%t8%"=="x" if "%t5%"=="x" if not "%t2%"=="x" if not "%t2%"=="o" goto c2
if "%t9%"=="x" if "%t8%"=="x" if not "%t7%"=="x" if not "%t7%"=="o" goto c7
if "%t9%"=="x" if "%t5%"=="x" if not "%t1%"=="x" if not "%t1%"=="o" goto c1
if "%t9%"=="x" if "%t6%"=="x" if not "%t3%"=="x" if not "%t3%"=="o" goto c3
REM (block obvious corner to corner)
if "%t1%"=="x" if "%t3%"=="x" if not "%t2%"=="x" if not "%t2%"=="o" goto c2
if "%t1%"=="x" if "%t9%"=="x" if not "%t5%"=="x" if not "%t5%"=="o" goto c5
if "%t1%"=="x" if "%t7%"=="x" if not "%t4%"=="x" if not "%t4%"=="o" goto c4
if "%t3%"=="x" if "%t7%"=="x" if not "%t5%"=="x" if not "%t5%"=="o" goto c5
if "%t3%"=="x" if "%t9%"=="x" if not "%t6%"=="x" if not "%t6%"=="o" goto c6
if "%t9%"=="x" if "%t7%"=="x" if not "%t8%"=="x" if not "%t8%"=="o" goto c8
if "%sl%"=="2" goto skill2
REM (block sneaky corner to corner 2-4, 2-6, etc.)
if "%t2%"=="x" if "%t4%"=="x" if not "%t1%"=="x" if not "%t1%"=="o" goto c1
if "%t2%"=="x" if "%t6%"=="x" if not "%t3%"=="x" if not "%t3%"=="o" goto c3
if "%t8%"=="x" if "%t4%"=="x" if not "%t7%"=="x" if not "%t7%"=="o" goto c7
if "%t8%"=="x" if "%t6%"=="x" if not "%t9%"=="x" if not "%t9%"=="o" goto c9
REM (block offset corner trap 1-8, 1-6, etc.)
if "%t1%"=="x" if "%t6%"=="x" if not "%t8%"=="x" if not "%t8%"=="o" goto c8
if "%t1%"=="x" if "%t8%"=="x" if not "%t6%"=="x" if not "%t6%"=="o" goto c6
if "%t3%"=="x" if "%t8%"=="x" if not "%t4%"=="x" if not "%t4%"=="o" goto c4
if "%t3%"=="x" if "%t4%"=="x" if not "%t8%"=="x" if not "%t8%"=="o" goto c8
if "%t9%"=="x" if "%t4%"=="x" if not "%t2%"=="x" if not "%t2%"=="o" goto c2
if "%t9%"=="x" if "%t2%"=="x" if not "%t4%"=="x" if not "%t4%"=="o" goto c4
if "%t7%"=="x" if "%t2%"=="x" if not "%t6%"=="x" if not "%t6%"=="o" goto c6
if "%t7%"=="x" if "%t6%"=="x" if not "%t2%"=="x" if not "%t2%"=="o" goto c2
:SKILL2
REM (block outside middle to outside middle)
if "%t2%"=="x" if "%t8%"=="x" if not "%t5%"=="x" if not "%t5%"=="o" goto c5
if "%t4%"=="x" if "%t6%"=="x" if not "%t5%"=="x" if not "%t5%"=="o" goto c5
REM (block 3 corner trap)
if "%t1%"=="x" if "%t9%"=="x" if not "%t2%"=="x" if not "%t2%"=="o" goto c2
if "%t3%"=="x" if "%t7%"=="x" if not "%t2%"=="x" if not "%t2%"=="o" goto c2
if "%t1%"=="x" if "%t9%"=="x" if not "%t4%"=="x" if not "%t4%"=="o" goto c4
if "%t3%"=="x" if "%t7%"=="x" if not "%t4%"=="x" if not "%t4%"=="o" goto c4
if "%t1%"=="x" if "%t9%"=="x" if not "%t6%"=="x" if not "%t6%"=="o" goto c6
if "%t3%"=="x" if "%t7%"=="x" if not "%t6%"=="x" if not "%t6%"=="o" goto c6
if "%t1%"=="x" if "%t9%"=="x" if not "%t8%"=="x" if not "%t8%"=="o" goto c8
if "%t3%"=="x" if "%t7%"=="x" if not "%t8%"=="x" if not "%t8%"=="o" goto c8
:SKILL1
REM (just take a turn)
if not "%t5%"=="x" if not "%t5%"=="o" goto c5
if not "%t1%"=="x" if not "%t1%"=="o" goto c1
if not "%t3%"=="x" if not "%t3%"=="o" goto c3
if not "%t7%"=="x" if not "%t7%"=="o" goto c7
if not "%t9%"=="x" if not "%t9%"=="o" goto c9
if not "%t2%"=="x" if not "%t2%"=="o" goto c2
if not "%t4%"=="x" if not "%t4%"=="o" goto c4
if not "%t6%"=="x" if not "%t6%"=="o" goto c6
if not "%t8%"=="x" if not "%t8%"=="o" goto c8
set nm=0
goto update
:C1
set t1=o
goto check
:C2
set t2=o
goto check
:C3
set t3=o
goto check
:C4
set t4=o
goto check
:C5
set t5=o
goto check
:C6
set t6=o
goto check
:C7
set t7=o
goto check
:C8
set t8=o
goto check
:C9
set t9=o
goto check
:CHECK
if "%t1%"=="x" if "%t2%"=="x" if "%t3%"=="x" goto winx
if "%t4%"=="x" if "%t5%"=="x" if "%t6%"=="x" goto winx
if "%t7%"=="x" if "%t8%"=="x" if "%t9%"=="x" goto winx
if "%t1%"=="x" if "%t4%"=="x" if "%t7%"=="x" goto winx
if "%t2%"=="x" if "%t5%"=="x" if "%t8%"=="x" goto winx
if "%t3%"=="x" if "%t6%"=="x" if "%t9%"=="x" goto winx
if "%t1%"=="x" if "%t5%"=="x" if "%t9%"=="x" goto winx
if "%t3%"=="x" if "%t5%"=="x" if "%t7%"=="x" goto winx
if "%t1%"=="o" if "%t2%"=="o" if "%t3%"=="o" goto wino
if "%t4%"=="o" if "%t5%"=="o" if "%t6%"=="o" goto wino
if "%t7%"=="o" if "%t8%"=="o" if "%t9%"=="o" goto wino
if "%t1%"=="o" if "%t4%"=="o" if "%t7%"=="o" goto wino
if "%t2%"=="o" if "%t5%"=="o" if "%t8%"=="o" goto wino
if "%t3%"=="o" if "%t6%"=="o" if "%t9%"=="o" goto wino
if "%t1%"=="o" if "%t5%"=="o" if "%t9%"=="o" goto wino
if "%t3%"=="o" if "%t5%"=="o" if "%t7%"=="o" goto wino
if "%pt%"=="x" goto computer
if "%pt%"=="o" goto update
:WINX
set gw=x
goto update
:WINX2
echo You win!
echo Play again (Y,N)?
CHOICE /c:ynsq /n > nul
if errorlevel 4 goto end
if errorlevel 3 goto begin
if errorlevel 2 goto end
goto layout
:WINO
set gw=o
goto update
:WINO2
echo Sorry, You lose.
echo Play again (Y,N)?
CHOICE /c:ynsq /n > nul
if errorlevel 4 goto end
if errorlevel 3 goto begin
if errorlevel 2 goto end
goto layout
:NOMOVES
echo There are no more moves left!
echo Play again (Y,N)?
CHOICE /c:ynsq /n > nul
if errorlevel 4 goto end
if errorlevel 3 goto begin
if errorlevel 2 goto end
goto layout
:END
cls
echo Tic Tac Toe by Mac
echo.
REM Clear all variables (no spaces after equal sign).
set gw=
set nm=
set sl=
set pt=
set t1=
set t2=
set t3=
set t4=
set t5=
set t6=
set t7=
set t8=
set t9=
|
[EDIT]
Skimming over the code I noticed a couple of var checks
that were missing quotes. It worked OK because they're
on a line by themselves, but I added quotes anyway.
[EDIT]
Fixed a bug that allowed a certain sequence of moves to
always win in skill level 3.
_________________
VDSug.dll does file IO, check/disable menu items,
non-VDS dlls, draw functions and more...
Free download (30k dll size) at:
http://www.vdsworld.com/download.php?id=361
Last edited by Mac on Wed May 01, 2002 9:41 am; edited 5 times in total |
|
| Back to top |
|
 |
Sylvester
Valued Newbie
Joined: 31 Jul 2000
Posts: 43
Location: Boston, MA USA
|
| Posted: Tue Apr 23, 2002 12:22 pm Post subject: |
|
|
Hey Mac,
Ever thought about converting all that to VDS? 'coz many of us have only heard of DOS in Ancient History class. 
And it doesn't work on XP. I haven't gone in to check syntax yet, and I'm sure I prolly have to make some changes to make it work with NT syntax. If I have time later in the day, I'll take a look. 
_________________
Sylvester
In the immortal words of the great philosopher, Homer ... "D'OH!!!" 8O |
|
| Back to top |
|
|
Mac
Professional Member
Joined: 08 Jul 2000
Posts: 1585
Location: Oklahoma USA
|
| Posted: Tue Apr 23, 2002 9:43 pm Post subject: |
|
|
Hi Sylvester,
Actually I did convert it to VDS, and it was posted on
the old board (VDS3 Source) along with a few other
games - blackjack, anti-aircraft, and a checkers game
that was never completely finished (allows you to cheat).
I made some of them VDS4 compatible (maybe all of
them, I really don't remember). Check the archive at:
http://www.vdsworld.com/archive/
Hey Tommy, how about putting a link to the VDS archives
on the main forum index? It looks great BTW.
Cheers, Mac
_________________
VDSug.dll does file IO, check/disable menu items,
non-VDS dlls, draw functions and more...
Free download (30k dll size) at:
http://www.vdsworld.com/download.php?id=361
Last edited by Mac on Tue Apr 23, 2002 10:06 pm; edited 2 times in total |
|
| Back to top |
|
|
Tommy
Admin Team
Joined: 16 Nov 2002
Posts: 746
Location: The Netherlands
|
| Posted: Tue Apr 23, 2002 10:03 pm Post subject: |
|
|
Hi Mac,
Thanks for your comments. I considered putting a link at this board, but I'm not sure yet how to do that other than changing the source code directly. Probably there's a "hack" for this board already which allows for this, I'll look into this.
Best regards,
Tommy |
|
| Back to top |
|
|
Mac
Professional Member
Joined: 08 Jul 2000
Posts: 1585
Location: Oklahoma USA
|
| Posted: Tue Apr 23, 2002 10:15 pm Post subject: |
|
|
Tommy, You know way more about this stuff than I do,
but can you add an image or a button in the html code?
Or is the html generated by the board software...
Cheers, Mac
_________________
VDSug.dll does file IO, check/disable menu items,
non-VDS dlls, draw functions and more...
Free download (30k dll size) at:
http://www.vdsworld.com/download.php?id=361
|
|
| Back to top |
|
|
Sylvester
Valued Newbie
Joined: 31 Jul 2000
Posts: 43
Location: Boston, MA USA
|
| Posted: Wed Apr 24, 2002 1:18 am Post subject: |
|
|
weird
I remember the other games you mentioned, played with them and liked them a lot. I don't know why I don't remember this one. I think I'm getting old and turning into one of them dinosaurs you mentioned! 
_________________
Sylvester
In the immortal words of the great philosopher, Homer ... "D'OH!!!" 8O |
|
| Back to top |
|
|
Protected
Valued Contributor
Joined: 02 Jan 2001
Posts: 228
Location: Portugal
|
| Posted: Wed Apr 24, 2002 2:34 pm Post subject: |
|
|
| I had never realized that there were so much similarities between batch files and vds scripts |
|
| Back to top |
|
|
Mac
Professional Member
Joined: 08 Jul 2000
Posts: 1585
Location: Oklahoma USA
|
| Posted: Sun Apr 28, 2002 1:31 am Post subject: |
|
|
Fixed a bug that allowed a certain sequence of moves
to win in skill level 3. The procedure was OK, just had
it in the wrong place...
Sylvester, do you have access to CHOICE.COM? It's the
only external DOS batch utility used in the game. It came
with later verisons of MS DOS, so I assumed any OS that
emulates DOS could emulate that as well.
Cheers, Mac
_________________
VDSug.dll does file IO, check/disable menu items,
non-VDS dlls, draw functions and more...
Free download (30k dll size) at:
http://www.vdsworld.com/download.php?id=361
|
|
| Back to top |
|
|
Dr. Dread
Professional Member
Joined: 03 Aug 2001
Posts: 1065
Location: Copenhagen, Denmark
|
| Posted: Sun Apr 28, 2002 11:18 am Post subject: |
|
|
| Mac wrote: | Sylvester, do you have access to CHOICE.COM? It's the
only external DOS batch utility used in the game. It came
with later verisons of MS DOS, so I assumed any OS that
emulates DOS could emulate that as well. |
Hi, Mac!
CHOICE.COM is not part of the WinNT OS family, so NT, 2K, and XP won't have that
handy littly DOS util. But the ASK command still works, so that probably could make it
work.
Greetz
Dr. Dread
_________________
~~ Alcohol and calculus don't mix... Don't drink and derive! ~~
String.DLL * advanced string processing |
|
| Back to top |
|
|
Mac
Professional Member
Joined: 08 Jul 2000
Posts: 1585
Location: Oklahoma USA
|
| Posted: Sun Apr 28, 2002 5:53 pm Post subject: |
|
|
Hey Dread,
I don't have an "ASK" command, so I'm not familiar
with it (I have a "PAUSE" command, but it doesn't
return an errorlevel. It just pauses until a key is
pressed).
Is "ASK" an external utility (like CHOICE)? And how
do ya use it? Just curious.
BTW, here's a site ya can download CHOICE.COM
from, and it has some info about using it with NT.
The site is mostly French, but this topic's in English.
http://www.geko.ch/tech-tips.htm#Batch
Cheers, Mac
_________________
VDSug.dll does file IO, check/disable menu items,
non-VDS dlls, draw functions and more...
Free download (30k dll size) at:
http://www.vdsworld.com/download.php?id=361
|
|
| Back to top |
|
|
Dr. Dread
Professional Member
Joined: 03 Aug 2001
Posts: 1065
Location: Copenhagen, Denmark
|
| Posted: Sun Apr 28, 2002 7:18 pm Post subject: |
|
|
Hi again, Mac!
Man, I'm such a DOS dinosaur that I'm practically fossilized  In my feebled mind I just
remembered an ASK command that I've been using in lots of DOS batch scripts and then I
assumed that it was a DOS native. But now I've checked and it's actually a 1987 Norton utility
that performs almost as CHOICE - "ASK [prompt], keylist".
Hmmmm, perhaps I should just get myself stuffed and exhibited - this Dososaurus should
perhaps be retired 8O
Greetz
Dr. Dread
_________________
~~ Alcohol and calculus don't mix... Don't drink and derive! ~~
String.DLL * advanced string processing |
|
| Back to top |
|
|
Mac
Professional Member
Joined: 08 Jul 2000
Posts: 1585
Location: Oklahoma USA
|
| Posted: Sun Apr 28, 2002 7:24 pm Post subject: |
|
|
Lol Dread, maybe we'll get adjacent rooms at the asylum...
Cheers, Mac
_________________
VDSug.dll does file IO, check/disable menu items,
non-VDS dlls, draw functions and more...
Free download (30k dll size) at:
http://www.vdsworld.com/download.php?id=361
|
|
| Back to top |
|
|
Tommy
Admin Team
Joined: 16 Nov 2002
Posts: 746
Location: The Netherlands
|
| Posted: Sun Apr 28, 2002 8:47 pm Post subject: |
|
|
The following DOS tool will allow user input and output it to an environment variable:
http://www.vdsworld.com/files/ASKENV.EXE
It'll require the user to press ENTER to finalize the input though.
Best regards,
Tommy |
|
| Back to top |
|
|
Newspaz
Newbie
Joined: 12 Apr 2001
Posts: 10
|
| Posted: Mon Apr 29, 2002 8:12 pm Post subject: |
|
|
Wow, great. Although, I have no opponent for some reason.
This makes me think of my old days a few years back when I was 9 or 10. I tried to write my own OS in batch. It looked hillarious and didn't work at all. To bad I lost it, would have got you a good laugh. |
|
| Back to top |
|
|
moke
Contributor
Joined: 02 Jan 2002
Posts: 162
|
| Posted: Mon Apr 29, 2002 8:47 pm Post subject: |
|
|
DOS?
Last edited by moke on Mon Apr 29, 2002 8:49 pm; edited 1 time in total |
|
| Back to top |
|
|
|
FAQ
Search
Memberlist
Usergroups
Register
Profile
Log in to check your private messages
Log in
@vdsworld