| View previous topic :: View next topic |
| Author |
Message |
ShinobiSoft
Professional Member
Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn
|
 Posted: Sun Dec 01, 2002 5:26 pm Post subject: Add a toolbar to VDS IDE Editor window |
 |
|
Simple utility to add a toolbar window to the VDS IDE's Editor window(#TScriptWin). The toolbar is created to the right of the combo box that contains the script's labels.
This example was written in VDS 4.5 but I believe it will work in VDS 3 as well.
| Code: |
rem *** This example demonstrates how to create an external toolbar window and
rem positions the toolbar window on the Visual DialogScript's Editor window,
rem whose class name is #TScriptWin. ***
rem *** You must provide a valid bitmap for the BITBTN element in this example
rem plus any code necessary to make the button(s) operational. ***
rem *** I've tried this with the INVISIBLE style for the dialog, it works, but the CLICK
rem event won't be generated if you click on the dialog. ***
directory change,@path(%0)
%%vdsActive = @winexists(#TMainWin)
if %%vdsActive
%%memoActive = @winexists(#TScriptWin)
if %%memoActive
parse "%%tsTop;%%tsLeft;%%tsWidth",@winpos(#TScriptWin,TLW)
dialog create,VDS Helper,@sum(%%tsTop,25),@sum(%%tsLeft,220),@diff(%%tsWidth,225),25,NoTitle,CLICK,ONTOP
dialog add,BitBtn,Comment,0,0,20,20,AddFile.bmp,,New
dialog show
:Evloop
wait 0.1,event
%E = @event()
goto %E
:Timer
%W = @winexists(#TScriptWin)
if @not(%W)
goto CLOSE
end
goto Evloop
:CLICK
%%click = @click(B)
if @equal(%%click,RIGHT)
dialog popup,E&xit,25,0
end
goto Evloop
:CommentBUTTON
goto Evloop
:ExitMENU
:CLOSE
exit
end
end
|
I hope someone finds a use for this.
Happy coding!! 
_________________
Bill Weckel
ShinobiSoft Software
"The way is known to all, but not all know it." |
|
| Back to top |
|
 |
Skit3000
Admin Team
Joined: 11 May 2002
Posts: 2166
Location: The Netherlands
|
| Posted: Sun Dec 01, 2002 6:16 pm Post subject: |
|
|
It's a good idea, but some thing won't work:
directory change,@path(%0) -> Missing parameters to command
wait 0.1,event -> You forgot to use option decimalsep
Also, if you change the position of the window, it won't follow it. And if you open an other program, your script will stay on top, but it has to move to the background...
I don't now if knew these 'bugs', but I think it's usefull to get them out of this (very) usefull (!) script... |
|
| Back to top |
|
|
ShinobiSoft
Professional Member
Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn
|
| Posted: Sun Dec 01, 2002 6:25 pm Post subject: |
|
|
That's funny about the directory change,@path(%0) because it works on my machine.
This was just something that popped into my overworked mind and I wrote the script in about 15 minutes. I haven't done much else with it.
I'll take into consideration your ideas Skit3000 and any others that are mentioned.
Question:
Why use Option decsep? I'm not parsing the information.
_________________
Bill Weckel
ShinobiSoft Software
"The way is known to all, but not all know it." |
|
| Back to top |
|
|
Skit3000
Admin Team
Joined: 11 May 2002
Posts: 2166
Location: The Netherlands
|
| Posted: Sun Dec 01, 2002 6:32 pm Post subject: |
|
|
Well, I think the directory error I had, was caused by the fact I didn't saved the script...
And about your question: decimalsep is for a number, and fieldsep for parsing. You have to change this into a dot, otherwise VDS thinks it is part of a command. You have changed it, but you forgot to let VDS know...
| Quote: | OPTION DECIMALSEP is used to force the decimal separator to be a period, i.e. OPTION DECIMALSEP,"." This should be used if there are any floating point numeric constants in the script. If it is not, then numeric values will be interpreted according to the Windows regional settings (for example, a separator of a comma would be expected in many European countries) so a script that worked in one country would fail in another. Note that numeric values with commas as a decimal separator should have quotes round them if they are used in a script. Commas are treated by the interpreter as parameter separators, so if a value is written with a comma as a decimal separator the interpreter will treat the number as two separate integers.
Copyright ©1995 - 2000 S.A.D.E. s.a.r.l. / All rights are reserved. |
|
|
| Back to top |
|
|
ShinobiSoft
Professional Member
Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn
|
| Posted: Sun Dec 01, 2002 6:37 pm Post subject: |
|
|
The reason it works for me is the "." is the Default decimal seperator for the USA.
| Quote: |
OPTION DECIMALSEP is used to force the decimal separator to be a period, i.e. OPTION DECIMALSEP,"." This should be used if there are any floating point numeric constants in the script. If it is not, then numeric values will be interpreted according to the Windows regional settings... |
I'm glad for you pointing this out to me Skit3000. I'll keep it in mind.
_________________
Bill Weckel
ShinobiSoft Software
"The way is known to all, but not all know it." |
|
| Back to top |
|
|
Skit3000
Admin Team
Joined: 11 May 2002
Posts: 2166
Location: The Netherlands
|
| Posted: Sun Dec 01, 2002 6:46 pm Post subject: |
|
|
Here is how I would have made the code...
| Code: | option decimalsep,.
if @winexists(#TMainWin)
if @winexists(#TScriptWin)
goto Begin
end
end
exit
:Begin
DIALOG CREATE,VDS Helper,@fadd(@winpos(#TScriptWin,T),25),@fadd(@winpos(#TScriptWin,L),220),@diff(@winpos(#TScriptWin,W),225),25,notitle,ontop,class VDS Helper
dialog add,BitBtn,Comment,0,0,20,20,AddFile.bmp,,New
DIALOG SHOW
:Evloop
wait event,0.1
goto @event()
:Timer
if @equal(@winactive(C),TScriptWin)@equal(@winactive(C),TMainWin)@equal(@winactive(C),VDS Helper)
dialog setpos,,@fadd(@winpos(#TScriptWin,T),25),@fadd(@winpos(#TScriptWin,L),220),@diff(@winpos(#TScriptWin,W),225),25,
dialog show
else
dialog hide
end
goto evloop |
|
|
| Back to top |
|
|
FreezingFire
Admin Team
Joined: 23 Jun 2002
Posts: 3508
|
| Posted: Sun Dec 01, 2002 7:27 pm Post subject: |
|
|
| Skit3000 wrote: | | directory change,@path(%0) -> Missing parameters to command |
I found that error, but I realized that it was because I hadn't saved the script to my hard drive yet, and the
@path(%0) is referring to where the script is saved.
_________________
FreezingFire
VDSWORLD.com
Site Admin Team |
|
| Back to top |
|
|
ShinobiSoft
Professional Member
Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn
|
| Posted: Sun Dec 01, 2002 7:29 pm Post subject: |
|
|
I always save my scripts before running or debugging them in case VDS or Windows crashes. 
_________________
Bill Weckel
ShinobiSoft Software
"The way is known to all, but not all know it." |
|
| Back to top |
|
|
Garrett
Moderator Team
Joined: 04 Oct 2001
Posts: 2149
Location: A House
|
| Posted: Sun Dec 01, 2002 9:17 pm Post subject: |
|
|
Hey, I might as well toss in my toobar thing I've had sitting around
here collecting dust. Not sure mine would run under VDS 3.x or not,
but it's intended to be used on the IDE of either VDS 3 or 4.
And this thing could be as buggy as all heck, but it was working for me
the last time I touched it.... Can't remember when that was either, it's
been a while. Also, just grab some small bmp's for the buttons. My
buttons were just toss in's to see how the buttons looked during
development.
You're free to use this for whatever, but I ask that the names used in
this not be used, as I may still complete this and toss it on the main
site here at VDS World.
Keep in mind, this is old code and if I were to start making this again
today, I would not have written this in the manner that it is now. I've
learned a few things since I made this, so keep an eye out for odd
routines, or code that is known not to work on all versions of Windows.
-Garrett
Best run compiled! Not from IDE!
| Code: | %%Border = @regread(CURUSER,Control Panel\Desktop\WindowMetrics,BorderWidth)
%%TitleBar = @regread(CURUSER,Control Panel\Desktop\WindowMetrics,CaptionHeight)
%%Border = @div(@substr(%%Border,2,@len(%%Border)),15)
%%TitleBar = @div(@substr(%%TitleBar,2,@len(%%TitleBar)),15)
If @equal(%%Border,0)
%%Border = 1
End
%%Top = @sum(@Winpos(@Winexist(Visual DialogScript),T),4)
%%Left = @Winpos(@Winexist(Visual DialogScript),L)
%%Wide = @fsub(@Winpos(@Winexist(Visual DialogScript),W),3)
%%High = @Winpos(@Winexist(Visual DialogScript),H)
%%Showing = On
TITLE VDS Assistant
Inifile Open,@path(%0)vdsag.ini
%%Gripper = @iniread(Settings,Status)
If @equal(%%Gripper,On)
gosub WINDOWFLOAT
Else
gosub WINDOWDOCK
End
DIALOG SHOW
Option Sleeptime,25
%%Status = Showing
:EventLoop
Wait Event,0
%E = @event()
If %E
Goto %E
End
Goto EventLoop
:Timer
rem Wait 5
If @equal(%%Gripper,On)
Goto EventLoop
Else
rem ** %D = Most Left X coordinate of button plus the X coordinate window position **
rem ** %E = Most Right X coordinate of button plus the X coordinate window position **
rem ** %F = Most Top Y coordinate of button plus the Y coordinate window position **
rem ** %G = Most Bottom Y coordinate of button plus the Y coordinate window position **
gosub COORDINATESWINDOW
%D = @sum(%B,0)
%E = @sum(%B,346)
%F = @sum(%C,0)
%G = @sum(%C,19)
If @not(@greater(%D,%I)@greater(%I,%E)@greater(%F,%J)@greater(%J,%G))
If @equal(%%Showing,Off)
%%Null = @winactive(C)
%%Null2 = @winactive(N)
If @equal(%%Null,TScriptWin)@equal(%%Null2,Visual DialogScript)
Window Normal,VDS Assistant
%%Showing = On
End
End
Else
If @equal(%%Showing,On)
Window Hide,VDS Assistant
%%Showing = Off
End
End
%%Border = @regread(CURUSER,Control Panel\Desktop\WindowMetrics,BorderWidth)
%%TitleBar = @regread(CURUSER,Control Panel\Desktop\WindowMetrics,CaptionHeight)
%%Border = @div(@substr(%%Border,2,@len(%%Border)),15)
%%TitleBar = @div(@substr(%%TitleBar,2,@len(%%TitleBar)),15)
If @equal(%%Border,0)
%%Border = 1
End
%%Top = @sum(@Winpos(@Winexist(Visual DialogScript),T),4)
%%Left = @Winpos(@Winexist(Visual DialogScript),L)
%%Wide = @fsub(@Winpos(@Winexist(Visual DialogScript),W),3)
%%High = @Winpos(@Winexist(Visual DialogScript),H)
Window Position,VDS Assistant,@sum(%%Top,@sum(%%Border,%%TitleBar)),@sum(%%Left,@fsub(%%Wide,346))
If @equal(@winactive(N),VDS Assistant)
Goto EventLoop
End
rem If @equal(@winactive(N),Visual DialogScript)
rem Window Normal,VDS Assistant
rem End
rem If @not(@equal(@winactive(N),Visual DialogScript))
rem Window Hide,VDS Assistant
rem End
End
Goto EventLoop
:COORDINATESWINDOW
%A = @winpos(VDS Assistant,LT)
parse "%B;%C",%A
%H = @mousepos()
parse "%I;%J",%H
Exit
:BITEXITBUTTON
:Close
Inifile Open,@path(%0)vdsag.ini
Inifile Write,Settings,Status,%%Gripper
Exit
:WINDOWDOCK
DIALOG CREATE,VDS Assistant,@sum(%%Top,@sum(%%Border,%%TitleBar)),@sum(%%Left,@fsub(%%Wide,346)),346,19,NOTITLE,ONTOP
rem DIALOG CREATE,VDS Assistant,10,10,479,19,NOTITLE
DIALOG ADD,STYLE,STYLEGRABLOW,Symbol,9,,,GRAY
DIALOG ADD,STYLE,STYLEGRABHIGH,Symbol,9,,,WHITE
DIALOG ADD,STYLE,STYLE3,,6,,BACKGROUND,FOREGROUND
DIALOG ADD,STYLE,STYLE2,,6,,GRAY,FOREGROUND
DIALOG ADD,STYLE,STYLE1,,6,,WHITE,FOREGROUND
DIALOG ADD,TEXT,TEXT1,1,1,3,17,,STYLE1
DIALOG ADD,TEXT,TEXT2,2,2,2,16,,STYLE2
DIALOG ADD,TEXT,TEXT3,2,2,1,15,,STYLE3
DIALOG ADD,TEXT,TEXT4,1,5,3,17,,STYLE1
DIALOG ADD,TEXT,TEXT5,2,6,2,16,,STYLE2
DIALOG ADD,TEXT,TEXT6,2,6,1,15,,STYLE3
DIALOG ADD,TEXT,GRABHIGH1a,0,1,,,é,,STYLEGRABHIGH,TRANSPARENT
DIALOG ADD,TEXT,GRIBHIGH1b,5,1,,,ê,,STYLEGRABHIGH,TRANSPARENT
DIALOG ADD,TEXT,GRABLOW1a,5,2,,,û,,STYLEGRABLOW,TRANSPARENT
DIALOG ADD,TEXT,GRABLOW1b,0,2,,,ú,,STYLEGRABLOW,TRANSPARENT
DIALOG ADD,BITMAP,GRIPPER,0,0,10,19,,Undock,CLICK
DIALOG ADD,BITBTN,BITBTN1,0,9,19,19,@path(%0)images\project2.bmp,,Project Manager
DIALOG ADD,BITBTN,BITBTN2,0,28,19,19,@path(%0)images\snppetmaster.bmp,,Code Vault
DIALOG ADD,BITBTN,BITBTN3,0,47,19,19,@path(%0)images\snppetbar.bmp,,Code Bar
DIALOG ADD,BITBTN,BITBTN4,0,66,19,19,@path(%0)images\keyboard.bmp,,Keyboard Coder
DIALOG ADD,BITBTN,BITBTN5,0,85,19,19,@path(%0)images\msgboxdesign.bmp,,Msg Box Desinger
DIALOG ADD,BITBTN,BITBTN6,0,104,19,19,@path(%0)images\wingrab.bmp,,Window Grabber
DIALOG ADD,BITBTN,BITBTN7,0,123,19,19,@path(%0)images\datetimeassist.bmp,,Date-Time Wiz
DIALOG ADD,BITBTN,BITBTN8,0,142,19,19,@path(%0)images\othertools.bmp,,Other Assistant Tools
DIALOG ADD,PROGRESS,PROGRESS1,1,165,2,17
DIALOG ADD,BITBTN,BITUSER1,0,172,19,19,@path(%0)images\blank.bmp,,User 1
DIALOG ADD,BITBTN,BITUSER2,0,191,19,19,@path(%0)images\blank.bmp,,User 2
DIALOG ADD,BITBTN,BITUSER3,0,210,19,19,@path(%0)images\blank.bmp,,User 3
DIALOG ADD,BITBTN,BITUSER4,0,229,19,19,@path(%0)images\blank.bmp,,User 4
DIALOG ADD,BITBTN,BITUSER5,0,248,19,19,@path(%0)images\blank.bmp,,User 5
DIALOG ADD,PROGRESS,PROGRESS2,1,271,2,17
DIALOG ADD,BITBTN,BITOPTIONS,0,278,19,19,@path(%0)images\options.bmp,,VDS Assistant Options
DIALOG ADD,BITBTN,BITHELT,0,297,19,19,@path(%0)images\help.bmp,,VDS Assistant Help
DIALOG ADD,PROGRESS,PROGRESS3,1,321,2,17
DIALOG ADD,BITBTN,BITEXIT,0,327,19,19,@path(%0)images\exit.bmp,,Exit VDS Assistant
Exit
:WINDOWFLOAT
DIALOG CREATE,VDS Assistant,10,10,346,19,SMALLCAP
REM *** Modified by Dialog Designer on 6/3/2002 - 01:04 ***
DIALOG ADD,STYLE,STYLEGRABLOW,Symbol,9,,,GRAY
DIALOG ADD,STYLE,STYLEGRABHIGH,Symbol,9,,,WHITE
DIALOG ADD,STYLE,STYLE3,,6,,BACKGROUND,FOREGROUND
DIALOG ADD,STYLE,STYLE2,,6,,GRAY,FOREGROUND
DIALOG ADD,STYLE,STYLE1,,6,,WHITE,FOREGROUND
DIALOG ADD,TEXT,TEXT1,1,1,3,17,,STYLE1
DIALOG ADD,TEXT,TEXT2,2,2,2,16,,STYLE2
DIALOG ADD,TEXT,TEXT3,2,2,1,15,,STYLE3
DIALOG ADD,TEXT,TEXT4,1,5,3,17,,STYLE1
DIALOG ADD,TEXT,TEXT5,2,6,2,16,,STYLE2
DIALOG ADD,TEXT,TEXT6,2,6,1,15,,STYLE3
DIALOG ADD,TEXT,GRABHIGH1a,0,1,,,é,,STYLEGRABHIGH,TRANSPARENT
DIALOG ADD,TEXT,GRIBHIGH1b,5,1,,,ê,,STYLEGRABHIGH,TRANSPARENT
DIALOG ADD,TEXT,GRABLOW1a,5,2,,,û,,STYLEGRABLOW,TRANSPARENT
DIALOG ADD,TEXT,GRABLOW1b,0,2,,,ú,,STYLEGRABLOW,TRANSPARENT
DIALOG ADD,BITMAP,GRIPPER,0,0,10,19,,Dock,CLICK
DIALOG ADD,BITBTN,BITBTN1,0,9,19,19,@path(%0)images\project2.bmp,,Project Manager
DIALOG ADD,BITBTN,BITBTN2,0,28,19,19,@path(%0)images\snppetmaster.bmp,,Code Vault
DIALOG ADD,BITBTN,BITBTN3,0,47,19,19,@path(%0)images\snppetmaster.bmp,,Code Bar
DIALOG ADD,BITBTN,BITBTN4,0,66,19,19,@path(%0)images\keyboard.bmp,,Keyboard Coder
DIALOG ADD,BITBTN,BITBTN5,0,85,19,19,@path(%0)images\imagebrowse.bmp,,Msg Box Desinger
DIALOG ADD,BITBTN,BITBTN6,0,104,19,19,@path(%0)images\mapmaster.bmp,,Window Grabber
DIALOG ADD,BITBTN,BITBTN7,0,123,19,19,@path(%0)images\datetimeassist.bmp,,Date-Time Wiz
DIALOG ADD,BITBTN,BITBTN8,0,142,19,19,@path(%0)images\calc.bmp,,Other Assistant Tools
DIALOG ADD,PROGRESS,PROGRESS1,1,165,2,17
DIALOG ADD,BITBTN,BITUSER1,0,172,19,19,@path(%0)images\blank.bmp,,User 1
DIALOG ADD,BITBTN,BITUSER2,0,191,19,19,@path(%0)images\blank.bmp,,User 2
DIALOG ADD,BITBTN,BITUSER3,0,210,19,19,@path(%0)images\blank.bmp,,User 3
DIALOG ADD,BITBTN,BITUSER4,0,229,19,19,@path(%0)images\blank.bmp,,User 4
DIALOG ADD,BITBTN,BITUSER5,0,248,19,19,@path(%0)images\blank.bmp,,User 5
DIALOG ADD,PROGRESS,PROGRESS2,1,271,2,17
DIALOG ADD,BITBTN,BITOPTIONS,0,278,19,19,@path(%0)images\options.bmp,,VDS Assistant Options
DIALOG ADD,BITBTN,BITHELT,0,297,19,19,@path(%0)images\help.bmp,,VDS Assistant Help
DIALOG ADD,PROGRESS,PROGRESS3,1,321,2,17
DIALOG ADD,BITBTN,BITEXIT,0,327,19,19,@path(%0)images\exit.bmp,,Exit VDS Assistant
DIALOG SHOW
Exit
:BITBTN1BUTTON
rem -- Project Manager
Goto EventLoop
:BITBTN2BUTTON
rem -- Code Vault
Goto EventLoop
:BITBTN3BUTTON
rem -- Code Bar
Goto EventLoop
:BITBTN4BUTTON
rem -- Keyboard Coder
Goto EventLoop
:BITBTN5BUTTON
rem -- Msg Box Desinger
Goto EventLoop
:BITBTN6BUTTON
rem -- Window Grabber
Goto EventLoop
:BITBTN7BUTTON
rem -- Date-Time Wiz
Goto EventLoop
:BITBTN8BUTTON
rem -- Other Assistant Tools
DIALOG POPUP,Some program|Another Program
Goto EventLoop
:BITOPTIONSBUTTON
If @equal(%%Gripper,On)
DIALOG POPUP,Dock
Else
DIALOG POPUP,Undock
End
Goto EventLoop
:DockMENU
%%Gripper = Off
List Create,1
List Add,1,[Settings]
List Add,1,Status=Off
List Savefile,1,@path(%0)vdsag.ini
List Close,1
Run @shortname(%0)
Goto Close
:UndockMENU
%%Gripper = On
List Create,1
List Add,1,[Settings]
List Add,1,Status=On
List Savefile,1,@path(%0)vdsag.ini
List Close,1
Run @shortname(%0)
Goto Close
:GRIPPERCLICK
If @equal(%%Gripper,On)
Goto DockMENU
Else
Goto UndockMENU
End
:MAINHEADERWINDOW
TITLE REM King! - Main Header
DIALOG CREATE,REM King! - Main Header,-1,0,400,381
DIALOG ADD,STYLE,STYLE2,MS Sans Serif,8,R,BACKGROUND,FOREGROUND
DIALOG ADD,STYLE,STYLE1,MS Sans Serif,8,,BACKGROUND,FOREGROUND
DIALOG ADD,GROUP,GROUP1,8,4,390,338,[ Main Header ],STYLE1
DIALOG ADD,TEXT,TEXT1,48,10,90,13,Title:,STYLE2
DIALOG ADD,TEXT,TEXT2,68,10,90,18,Author:,STYLE2
DIALOG ADD,TEXT,TEXT3,88,10,90,18,Date:,STYLE2
DIALOG ADD,TEXT,TEXT4,106,10,90,18,Language:,STYLE2
DIALOG ADD,TEXT,TEXT5,126,10,90,18,Status:,STYLE2
DIALOG ADD,TEXT,TEXT6,146,10,90,18,Description:,STYLE2
DIALOG ADD,TEXT,TEXT7,208,10,90,18,Requirements:,STYLE2
DIALOG ADD,TEXT,TEXT8,270,10,90,18,Notes:,STYLE2
DIALOG ADD,COMBO,TITLECOMBO,44,114,264,21,
DIALOG ADD,COMBO,AUTHORCOMBO,64,114,264,21,
DIALOG ADD,EDIT,DATEEDIT,84,114,264,21,
DIALOG ADD,COMBO,LANGUAGECOMBO,104,114,264,21,
DIALOG ADD,COMBO,STATUSCOMBO,124,114,264,21,
DIALOG ADD,EDIT,DESCRIPTIONEDIT,144,114,264,63,,MULTI,WRAP,SCROLL
DIALOG ADD,EDIT,REQUIREMENTEDIT,206,114,264,63,,MULTI,WRAP,SCROLL
DIALOG ADD,EDIT,NOTESEDIT,268,114,264,63,,MULTI,WRAP,SCROLL
DIALOG ADD,BUTTON,BTNPREVIEW,352,4,78,24,Preview
DIALOG ADD,BUTTON,BTNOK,352,82,78,24,Ok
DIALOG ADD,BUTTON,BTNSETTINGS,352,160,78,24,Settings
DIALOG ADD,BUTTON,BTNHELP,352,238,78,24,Help
DIALOG ADD,BUTTON,BTNCANCEL,352,316,78,24,Cancel
DIALOG SHOW
:SECTIONHEADERWINDOW
TITLE REM King! - Section Header
DIALOG CREATE,REM King! - Section Header,-1,0,400,114
DIALOG ADD,STYLE,SSTYLE2,MS Sans Serif,8,R,BACKGROUND,FOREGROUND
DIALOG ADD,STYLE,SSTYLE1,MS Sans Serif,8,,BACKGROUND,FOREGROUND
DIALOG ADD,GROUP,SGROUP1,8,4,390,70,[ Section Header ],SSTYLE1
DIALOG ADD,TEXT,STEXT1,48,10,90,13,Section Title:,SSTYLE2
DIALOG ADD,COMBO,STITLECOMBO,44,114,264,21
DIALOG ADD,BUTTON,SBTNPREVIEW,84,4,78,24,Preview
DIALOG ADD,BUTTON,SBTNOK,84,82,78,24,Ok
DIALOG ADD,BUTTON,SBTNSETTINGS,84,160,78,24,Settings
DIALOG ADD,BUTTON,SBTNHELP,84,238,78,24,Help
DIALOG ADD,BUTTON,SBTNCANCEL,84,316,78,24,Cancel
DIALOG SHOW
:COMMENTWINDOW
TITLE REM King! - Comment
DIALOG CREATE,REM King! - Comment,-1,0,400,304
DIALOG ADD,STYLE,CSTYLE2,MS Sans Serif,8,R,BACKGROUND,FOREGROUND
DIALOG ADD,STYLE,CSTYLE1,MS Sans Serif,8,,BACKGROUND,FOREGROUND
DIALOG ADD,GROUP,CGROUP1,8,4,390,260,[ Comment ],CSTYLE1
DIALOG ADD,TEXTC,TEXT1,48,10,90,13,Comment:,STYLE2
DIALOG ADD,EDIT,CCOMMENTEDIT,44,114,264,210,,MULTI,WRAP,SCROLL
DIALOG ADD,BUTTON,CBTNPREVIEW,274,4,78,24,Preview
DIALOG ADD,BUTTON,CBTNOK,274,82,78,24,Ok
DIALOG ADD,BUTTON,CBTNSETTINGS,274,160,78,24,Settings
DIALOG ADD,BUTTON,CBTNHELP,274,238,78,24,Help
DIALOG ADD,BUTTON,CBTNCANCEL,274,316,78,24,Cancel
DIALOG SHOW
|
|
|
| Back to top |
|
|
Garrett
Moderator Team
Joined: 04 Oct 2001
Posts: 2149
Location: A House
|
| Posted: Sun Dec 01, 2002 9:25 pm Post subject: |
|
|
A little teeny tiny problem with your example. If I move the editor
window, your toolbar doesn't go with it. Just sits there screaming at
me. 
You can definitely use my code for that above.
BTW, you can do things like this for any program. I've added this
kind of bar to Notepad even, just so I can have like special characters
available right there, date/time stamp, snippets etc. Sure made
Notepad more feature rich than it was. But, if you make one yourselves
for Notepad, please don't call it "Notepad Assistant".... I've already
been using that program name since 1997 and plan to put that program
back into distribution again soon.
-Garrett
Last edited by Garrett on Sun Dec 01, 2002 9:29 pm; edited 1 time in total |
|
| Back to top |
|
|
ShinobiSoft
Professional Member
Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn
|
| Posted: Sun Dec 01, 2002 9:27 pm Post subject: |
|
|
Like I mentioned in an earlier post, this script was just a quick thought. I haven't experimented with it yet other than seeing if it worked at all.
_________________
Bill Weckel
ShinobiSoft Software
"The way is known to all, but not all know it." |
|
| Back to top |
|
|
Garrett
Moderator Team
Joined: 04 Oct 2001
Posts: 2149
Location: A House
|
| Posted: Sun Dec 01, 2002 9:31 pm Post subject: |
|
|
Well, it does work yes, and the idea is of course viable as you can see
with my code above. So now you have some more code to play with
for yours. 
-Garrett |
|
| Back to top |
|
|
ShinobiSoft
Professional Member
Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn
|
| Posted: Sun Dec 01, 2002 9:33 pm Post subject: |
|
|
Thanks for the input, Garrett. I may incorporate some of your code into mine. Not anytime soon however. Too busy!!
_________________
Bill Weckel
ShinobiSoft Software
"The way is known to all, but not all know it." |
|
| Back to top |
|
|
Garrett
Moderator Team
Joined: 04 Oct 2001
Posts: 2149
Location: A House
|
| Posted: Sun Dec 01, 2002 9:51 pm Post subject: |
|
|
Done moved on to another idea already? 
-Garrett |
|
| Back to top |
|
|
ShinobiSoft
Professional Member
Joined: 06 Nov 2002
Posts: 790
Location: Knoxville, Tn
|
| Posted: Sun Dec 01, 2002 9:53 pm Post subject: |
|
|
Something like that. I've got 5 projects I'm working on along with trying to learn Pascal, C++, and my regular job as a hardwood flooring mechanic.
_________________
Bill Weckel
ShinobiSoft Software
"The way is known to all, but not all know it." |
|
| Back to top |
|
|
|
|
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You can attach files in this forum
You can download files in this forum
|
|
FAQ
Search
Memberlist
Usergroups
Register
Profile
Log in to check your private messages
Log in
@vdsworld